* [gentoo-commits] gentoo-x86 commit in app-text/calibre: ChangeLog calibre-0.6.14-r1.ebuild calibre-0.6.14.ebuild
@ 2009-10-01 3:14 Zac Medico (zmedico)
0 siblings, 0 replies; only message in thread
From: Zac Medico (zmedico) @ 2009-10-01 3:14 UTC (permalink / raw
To: gentoo-commits
zmedico 09/10/01 03:14:01
Modified: ChangeLog
Added: calibre-0.6.14-r1.ebuild
Removed: calibre-0.6.14.ebuild
Log:
0.6.14-r1 revbump. Install python modules in /usr/lib/calibre, including bundled modules, since that's how upstream wants it.
(Portage version: 2.2_rc42_p14468/cvs/Linux i686)
Revision Changes Path
1.49 app-text/calibre/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/calibre/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/calibre/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/calibre/ChangeLog?r1=1.48&r2=1.49
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/calibre/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -u -r1.48 -r1.49
--- ChangeLog 1 Oct 2009 02:19:34 -0000 1.48
+++ ChangeLog 1 Oct 2009 03:14:01 -0000 1.49
@@ -1,6 +1,13 @@
# ChangeLog for app-text/calibre
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/calibre/ChangeLog,v 1.48 2009/10/01 02:19:34 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/calibre/ChangeLog,v 1.49 2009/10/01 03:14:01 zmedico Exp $
+
+*calibre-0.6.14-r1 (01 Oct 2009)
+
+ 01 Oct 2009; Zac Medico <zmedico@gentoo.org> -calibre-0.6.14.ebuild,
+ +calibre-0.6.14-r1.ebuild:
+ Install python modules in /usr/lib/calibre, including bundled modules,
+ since that's how upstream wants it.
*calibre-0.6.14 (01 Oct 2009)
1.1 app-text/calibre/calibre-0.6.14-r1.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/calibre/calibre-0.6.14-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/calibre/calibre-0.6.14-r1.ebuild?rev=1.1&content-type=text/plain
Index: calibre-0.6.14-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/calibre/calibre-0.6.14-r1.ebuild,v 1.1 2009/10/01 03:14:01 zmedico Exp $
EAPI=2
NEED_PYTHON=2.6
inherit python distutils eutils fdo-mime bash-completion
DESCRIPTION="Ebook management application."
HOMEPAGE="http://calibre.kovidgoyal.net"
SRC_URI="http://calibre.kovidgoyal.net/downloads/$P.tar.gz"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="0"
IUSE=""
# libusb-compat is untested
SHARED_DEPEND=">=dev-lang/python-2.6[sqlite]
>=dev-python/setuptools-0.6_rc5
>=dev-python/imaging-1.1.6
dev-libs/libusb:0
>=dev-python/PyQt4-4.5[X,svg,webkit]
>=dev-python/mechanize-0.1.11
>=media-gfx/imagemagick-6.3.5
>=x11-misc/xdg-utils-1.0.2
>=dev-python/dbus-python-0.82.2
>=dev-python/lxml-2.1.5
>=dev-python/python-dateutil-1.4.1
>=dev-python/beautifulsoup-3.0.5
>=dev-python/dnspython-1.6.0
>=sys-apps/help2man-1.36.4
|| ( app-text/podofo >=app-text/pdftk-1.12 )"
RDEPEND="$SHARED_DEPEND
>=dev-python/reportlab-2.1"
DEPEND="$SHARED_DEPEND
dev-python/setuptools
>=gnome-base/librsvg-2.0.0
>=x11-misc/xdg-utils-1.0.2-r2
sys-apps/help2man"
S=$WORKDIR/$PN
src_prepare() {
# Avoid sandbox violation in /usr/share/gnome/apps when linux.py
# calls xdg-* (bug #258938).
sed -e "s:'xdg-desktop-menu', 'install':'xdg-desktop-menu', 'install', '--mode', 'user':" \
-e "s:xdg-icon-resource install:xdg-icon-resource install --mode user:" \
-e "s:xdg-mime install:xdg-mime install --mode user:" \
-e "s:old_udev = '/etc:old_udev = '${D}etc:" \
-i src/calibre/linux.py || die "sed'ing in the IMAGE path failed"
distutils_src_prepare
}
src_install() {
# --bindir and --sharedir don't seem to work.
# Pass them in anyway so we'll know when they are fixed.
PYTHONPATH=${S}/src${PYTHONPATH:+:}${PYTHONPATH} \
distutils_src_install --bindir="${D}usr/bin" --sharedir="${D}usr/share"
grep -rlZ "${D}" "${D}" | xargs -0 sed -e "s:${D}:/:g" -i ||
die "failed to fix harcoded \$D in paths"
# This code may fail if behavior of --root, --bindir or
# --sharedir changes in the future.
dodir /usr/lib
mv "${D}lib/calibre" "${D}usr/lib/" ||
die "failed to move lib dir"
find "${D}"lib -type d -empty -delete
dodir /usr/bin
mv "${D}bin/"* "${D}usr/bin/" ||
die "failed to move bin dir"
find "${D}"bin -type d -empty -delete
dodir /usr/share
mv "${D}share/"* "${D}usr/share/" ||
die "failed to move share dir"
find "${D}"share -type d -empty -delete
# The menu entries end up here due to '--mode user' being added to
# xdg-* options in src_prepare.
dodir /usr/share/mime/packages
mv "$HOME"/.local/share/mime/packages/* "$D"usr/share/mime/packages/ ||
die "failed to register mime types"
dodir /usr/share/icons
mv "$HOME"/.local/share/icons/* "$D"usr/share/icons/ ||
die "failed to install icon files"
domenu "$HOME"/.local/share/applications/*.desktop ||
die "failed to install .desktop menu files"
dobashcompletion "$D"etc/bash_completion.d/calibre
rm -r "${D}"etc/bash_completion.d
find "${D}"etc -type d -empty -delete
}
pkg_postinst() {
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
distutils_pkg_postinst
bash-completion_pkg_postinst
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2009-10-01 3:14 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2009-10-01 3:14 [gentoo-commits] gentoo-x86 commit in app-text/calibre: ChangeLog calibre-0.6.14-r1.ebuild calibre-0.6.14.ebuild Zac Medico (zmedico)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox