* [gentoo-commits] gentoo-x86 commit in net-misc/mico: mico-2.3.13-r1.ebuild ChangeLog
@ 2009-09-09 6:34 Michael Haubenwallner (haubi)
0 siblings, 0 replies; 2+ messages in thread
From: Michael Haubenwallner (haubi) @ 2009-09-09 6:34 UTC (permalink / raw
To: gentoo-commits
haubi 09/09/09 06:34:16
Modified: ChangeLog
Added: mico-2.3.13-r1.ebuild
Log:
work with (forced) --as-needed linker flag (#280678)
(Portage version: 2.1.6.13/cvs/Linux x86_64)
Revision Changes Path
1.22 net-misc/mico/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/mico/ChangeLog?rev=1.22&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/mico/ChangeLog?rev=1.22&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/mico/ChangeLog?r1=1.21&r2=1.22
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/mico/ChangeLog,v
retrieving revision 1.21
retrieving revision 1.22
diff -u -r1.21 -r1.22
--- ChangeLog 7 Jul 2009 08:00:06 -0000 1.21
+++ ChangeLog 9 Sep 2009 06:34:16 -0000 1.22
@@ -1,6 +1,12 @@
# ChangeLog for net-misc/mico
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/mico/ChangeLog,v 1.21 2009/07/07 08:00:06 haubi Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/mico/ChangeLog,v 1.22 2009/09/09 06:34:16 haubi Exp $
+
+*mico-2.3.13-r1 (09 Sep 2009)
+
+ 09 Sep 2009; Michael Haubenwallner <haubi@gentoo.org>
+ +mico-2.3.13-r1.ebuild, +files/mico-2.3.13-as-needed.patch:
+ work with (forced) --as-needed linker flag (#280678)
07 Jul 2009; Michael Haubenwallner <haubi@gentoo.org>
+files/mico-2.3.13-hpux.patch, mico-2.3.13.ebuild:
1.1 net-misc/mico/mico-2.3.13-r1.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/mico/mico-2.3.13-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/mico/mico-2.3.13-r1.ebuild?rev=1.1&content-type=text/plain
Index: mico-2.3.13-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/mico/mico-2.3.13-r1.ebuild,v 1.1 2009/09/09 06:34:16 haubi Exp $
inherit eutils flag-o-matic toolchain-funcs
DESCRIPTION="A freely available and fully compliant implementation of the CORBA standard"
HOMEPAGE="http://www.mico.org/"
SRC_URI="http://www.mico.org/${P}.tar.gz"
LICENSE="GPL-2 LGPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
IUSE="gtk postgres qt3 ssl tcl threads X"
# doesn't compile:
# bluetooth? ( net-wireless/bluez-libs )
RDEPEND="
gtk? ( >=x11-libs/gtk+-2 )
postgres? ( dev-db/postgresql )
qt3? ( =x11-libs/qt-3* )
ssl? ( dev-libs/openssl )
tcl? ( dev-lang/tcl )
X? ( x11-libs/libXt )
"
DEPEND="${RDEPEND}
>=sys-devel/flex-2.5.2
>=sys-devel/bison-1.22
"
S=${WORKDIR}/${PN}
src_unpack() {
unpack ${A}
cd "${S}" || die "failed to cd to '${S}'"
epatch "${FILESDIR}"/${P}-nolibcheck.patch
epatch "${FILESDIR}"/${P}-gcc43.patch
epatch "${FILESDIR}"/${P}-pthread.patch
epatch "${FILESDIR}"/${P}-aix.patch
epatch "${FILESDIR}"/${P}-hpux.patch
epatch "${FILESDIR}"/${P}-as-needed.patch #280678
# cannot use big TOC (AIX only), gdb doesn't like it.
# This assumes that the compiler (or -wrapper) uses
# gcc flag '-mminimal-toc' for compilation.
sed -i -e 's/,-bbigtoc//' "${S}"/configure
}
src_compile() {
tc-export CC CXX
if use gtk; then
# set up gtk-1 wrapper for gtk-2
mkdir "${T}"/path || die "failed to create temporary path"
cp "${FILESDIR}"/gtk-config "${T}"/path || die "failed to dupe gtk-config"
chmod +x "${T}"/path/gtk-config || die "failed to arm gtk-config"
export PATH="${T}"/path:${PATH}
fi
# Don't know which version of JavaCUP would suffice, but there is no
# configure argument to disable checking for JavaCUP.
# So we override the configure check to not find 'javac'.
export ac_cv_path_JAVAC=no
# '--without-ssl' just does not add another search path - the only way
# to disable openssl utilization seems to override the configure check.
use ssl || export ac_cv_lib_ssl_open=no
# '--without-*' or '--with-*=no' does not disable some features, the value
# needs to be empty instead. This applies to: bluetooth, gtk, pgsql, qt, tcl.
# But --without-x works.
# moc is searched within PATH, not within QTDIR.
use qt3 && export MOC="${QTDIR}"/bin/moc
# http://www.mico.org/pipermail/mico-devel/2009-April/010285.html
[[ ${CHOST} == *-hpux* ]] && append-cppflags -D_XOPEN_SOURCE_EXTENDED
# bluetooth and wireless both don't compile cleanly
econf \
--disable-mini-stl \
$(use_enable threads) \
--with-gtk=$(use gtk && echo /usr) \
--with-pgsql=$(use postgres && echo /usr) \
--with-qt=$(use qt3 && echo "${QTDIR}") \
--with-tcl=$(use tcl && echo /usr) \
$(use_with X x /usr) \
--with-bluetooth='' \
--disable-wireless
emake || die "make failed"
}
src_install() {
emake INSTDIR="${D}"/usr SHARED_INSTDIR="${D}"/usr install LDCONFIG=: || die "install failed"
dodir /usr/share || die
mv "${D}"/usr/man "${D}"/usr/share || die
dodir /usr/share/doc/${PF} || die
mv "${D}"/usr/doc "${D}"/usr/share/doc/${PF} || die
dodoc BUGS CHANGES* CONVERT FAQ README* ROADMAP TODO VERSION WTODO || die
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-misc/mico: mico-2.3.13-r1.ebuild ChangeLog
@ 2009-09-28 9:35 Michael Haubenwallner (haubi)
0 siblings, 0 replies; 2+ messages in thread
From: Michael Haubenwallner (haubi) @ 2009-09-28 9:35 UTC (permalink / raw
To: gentoo-commits
haubi 09/09/28 09:35:29
Modified: mico-2.3.13-r1.ebuild ChangeLog
Log:
incorporated prefix support and keywords
(Portage version: 2.1.6.13/cvs/Linux x86_64)
Revision Changes Path
1.2 net-misc/mico/mico-2.3.13-r1.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/mico/mico-2.3.13-r1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/mico/mico-2.3.13-r1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/mico/mico-2.3.13-r1.ebuild?r1=1.1&r2=1.2
Index: mico-2.3.13-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/mico/mico-2.3.13-r1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- mico-2.3.13-r1.ebuild 9 Sep 2009 06:34:16 -0000 1.1
+++ mico-2.3.13-r1.ebuild 28 Sep 2009 09:35:28 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/mico/mico-2.3.13-r1.ebuild,v 1.1 2009/09/09 06:34:16 haubi Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/mico/mico-2.3.13-r1.ebuild,v 1.2 2009/09/28 09:35:28 haubi Exp $
inherit eutils flag-o-matic toolchain-funcs
@@ -10,7 +10,7 @@
LICENSE="GPL-2 LGPL-2"
SLOT="0"
-KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~ppc-aix ~ia64-hpux ~amd64-linux ~x86-linux ~x86-winnt"
IUSE="gtk postgres qt3 ssl tcl threads X"
# doesn't compile:
@@ -42,6 +42,8 @@
epatch "${FILESDIR}"/${P}-hpux.patch
epatch "${FILESDIR}"/${P}-as-needed.patch #280678
+ [[ ${CHOST} == *-winnt* ]] && epatch "${FILESDIR}"/${P}-winnt.patch.bz2
+
# cannot use big TOC (AIX only), gdb doesn't like it.
# This assumes that the compiler (or -wrapper) uses
# gcc flag '-mminimal-toc' for compilation.
@@ -75,6 +77,14 @@
# moc is searched within PATH, not within QTDIR.
use qt3 && export MOC="${QTDIR}"/bin/moc
+ local winopts=
+ if [[ ${CHOST} == *-winnt* ]]; then
+ # disabling static libs, since ar on interix takes nearly
+ # one hour per library, thanks to mico's monster objects.
+ winopts="${winopts} --disable-threads --disable-static --enable-final"
+ append-flags -D__STDC__
+ fi
+
# http://www.mico.org/pipermail/mico-devel/2009-April/010285.html
[[ ${CHOST} == *-hpux* ]] && append-cppflags -D_XOPEN_SOURCE_EXTENDED
@@ -88,18 +98,19 @@
--with-tcl=$(use tcl && echo /usr) \
$(use_with X x /usr) \
--with-bluetooth='' \
- --disable-wireless
+ --disable-wireless \
+ ${winopts}
emake || die "make failed"
}
src_install() {
- emake INSTDIR="${D}"/usr SHARED_INSTDIR="${D}"/usr install LDCONFIG=: || die "install failed"
+ emake INSTDIR="${D}${EPREFIX}"/usr SHARED_INSTDIR="${D}${EPREFIX}"/usr install LDCONFIG=: || die "install failed"
dodir /usr/share || die
- mv "${D}"/usr/man "${D}"/usr/share || die
+ mv "${D}${EPREFIX}"/usr/man "${D}${EPREFIX}"/usr/share || die
dodir /usr/share/doc/${PF} || die
- mv "${D}"/usr/doc "${D}"/usr/share/doc/${PF} || die
+ mv "${D}${EPREFIX}"/usr/doc "${D}${EPREFIX}"/usr/share/doc/${PF} || die
dodoc BUGS CHANGES* CONVERT FAQ README* ROADMAP TODO VERSION WTODO || die
}
1.23 net-misc/mico/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/mico/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/mico/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/mico/ChangeLog?r1=1.22&r2=1.23
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/mico/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog 9 Sep 2009 06:34:16 -0000 1.22
+++ ChangeLog 28 Sep 2009 09:35:28 -0000 1.23
@@ -1,6 +1,10 @@
# ChangeLog for net-misc/mico
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/mico/ChangeLog,v 1.22 2009/09/09 06:34:16 haubi Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/mico/ChangeLog,v 1.23 2009/09/28 09:35:28 haubi Exp $
+
+ 28 Sep 2009; Michael Haubenwallner <haubi@gentoo.org>
+ mico-2.3.13-r1.ebuild, +files/mico-2.3.13-winnt.patch.bz2:
+ incorporated prefix support and keywords
*mico-2.3.13-r1 (09 Sep 2009)
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2009-09-28 9:35 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2009-09-28 9:35 [gentoo-commits] gentoo-x86 commit in net-misc/mico: mico-2.3.13-r1.ebuild ChangeLog Michael Haubenwallner (haubi)
-- strict thread matches above, loose matches on Subject: below --
2009-09-09 6:34 Michael Haubenwallner (haubi)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox