[gentoo-commits] gentoo-x86 commit in media-libs/libtheora: ChangeLog libtheora-1.1.0.ebuild

[gentoo-commits] gentoo-x86 commit in media-libs/libtheora: ChangeLog libtheora-1.1.0.ebuild

[Alexis Ballier (aballier)]

aballier    09/09/27 08:16:18

  Modified:             ChangeLog
  Added:                libtheora-1.1.0.ebuild
  Log:
  version bump, by Arseny Solokha <b0ntrict0r@yandex.ru>, bug #286421
  (Portage version: 2.2_rc42/cvs/Linux x86_64)

Revision  Changes    Path
1.97                 media-libs/libtheora/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libtheora/ChangeLog?rev=1.97&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libtheora/ChangeLog?rev=1.97&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libtheora/ChangeLog?r1=1.96&r2=1.97

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libtheora/ChangeLog,v
retrieving revision 1.96
retrieving revision 1.97
diff -u -r1.96 -r1.97
--- ChangeLog	29 Aug 2009 13:23:22 -0000	1.96
+++ ChangeLog	27 Sep 2009 08:16:18 -0000	1.97
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libtheora
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libtheora/ChangeLog,v 1.96 2009/08/29 13:23:22 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libtheora/ChangeLog,v 1.97 2009/09/27 08:16:18 aballier Exp $
+
+*libtheora-1.1.0 (27 Sep 2009)
+
+  27 Sep 2009; Alexis Ballier <aballier@gentoo.org> +libtheora-1.1.0.ebuild:
+  version bump, by Arseny Solokha <b0ntrict0r@yandex.ru>, bug #286421
 
   29 Aug 2009; Samuli Suominen <ssuominen@gentoo.org>
   libtheora-1.1_beta3.ebuild,



1.1                  media-libs/libtheora/libtheora-1.1.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libtheora/libtheora-1.1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libtheora/libtheora-1.1.0.ebuild?rev=1.1&content-type=text/plain

Index: libtheora-1.1.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libtheora/libtheora-1.1.0.ebuild,v 1.1 2009/09/27 08:16:18 aballier Exp $

EAPI=2
inherit autotools eutils flag-o-matic

DESCRIPTION="The Theora Video Compression Codec"
HOMEPAGE="http://www.theora.org"
SRC_URI="http://downloads.xiph.org/releases/theora/${P/_}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="doc +encode examples"

RDEPEND="media-libs/libogg
	encode? ( media-libs/libvorbis )
	examples? ( media-libs/libpng
		media-libs/libvorbis
		>=media-libs/libsdl-0.11.0 )"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )
	dev-util/pkgconfig"

VARTEXFONTS=${T}/fonts
S=${WORKDIR}/${P/_}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.0_beta2-flags.patch
	cp -f "${FILESDIR}"/${PN}-1.1_beta3-encoder_disabled.c "${S}"/lib/encoder_disabled.c
	AT_M4DIR="m4" eautoreconf
}

src_configure() {
	use x86 && filter-flags -fforce-addr -frename-registers #200549
	use doc || export ac_cv_prog_HAVE_DOXYGEN="false"

	local myconf
	use examples && myconf="--enable-encode"

	# --disable-spec because LaTeX documentation has been prebuilt
	econf \
		--disable-dependency-tracking \
		--disable-spec \
		$(use_enable encode) \
		$(use_enable examples) \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" docdir=/usr/share/doc/${PF} \
		install || die "emake install failed"

	dodoc AUTHORS CHANGES README
	prepalldocs

	if use examples; then
		if use doc; then
			insinto /usr/share/doc/${PF}/examples
			doins examples/*.[ch]
		fi

		dobin examples/.libs/png2theora || die "dobin failed"
		for bin in dump_{psnr,video} {encoder,player}_example; do
			newbin examples/.libs/${bin} theora_${bin} || die "newbin failed"
		done
	fi
}