[gentoo-commits] gentoo-x86 commit in dev-libs/elfutils: elfutils-0.143.ebuild ChangeLog metadata.xml

[gentoo-commits] gentoo-x86 commit in dev-libs/elfutils: elfutils-0.143.ebuild ChangeLog metadata.xml

[Ryan Hill (dirtyepic)]

dirtyepic    09/09/26 21:53:41

  Modified:             ChangeLog metadata.xml
  Added:                elfutils-0.143.ebuild
  Log:
  Version bump, bug #278144 by Conrad Kostecki.
  (Portage version: 2.2_rc42/cvs/Linux x86_64)

Revision  Changes    Path
1.125                dev-libs/elfutils/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/elfutils/ChangeLog?rev=1.125&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/elfutils/ChangeLog?rev=1.125&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/elfutils/ChangeLog?r1=1.124&r2=1.125

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/elfutils/ChangeLog,v
retrieving revision 1.124
retrieving revision 1.125
diff -u -r1.124 -r1.125
--- ChangeLog	15 Mar 2009 11:29:33 -0000	1.124
+++ ChangeLog	26 Sep 2009 21:53:40 -0000	1.125
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/elfutils
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/elfutils/ChangeLog,v 1.124 2009/03/15 11:29:33 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/elfutils/ChangeLog,v 1.125 2009/09/26 21:53:40 dirtyepic Exp $
+
+*elfutils-0.143 (26 Sep 2009)
+
+  26 Sep 2009; Ryan Hill <dirtyepic@gentoo.org> +elfutils-0.143.ebuild,
+  metadata.xml:
+  Version bump, bug #278144 by Conrad Kostecki.
 
 *elfutils-0.140 (15 Mar 2009)
 



1.2                  dev-libs/elfutils/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/elfutils/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/elfutils/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/elfutils/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/elfutils/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	1 Jun 2005 12:42:10 -0000	1.1
+++ metadata.xml	26 Sep 2009 21:53:40 -0000	1.2
@@ -1,5 +1,8 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>toolchain</herd>
+	<herd>toolchain</herd>
+	<use>
+		<flag name="lzma">Support automatic decompression of LZMA-compressed files and kernel images.</flag>
+	</use>
 </pkgmetadata>



1.1                  dev-libs/elfutils/elfutils-0.143.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/elfutils/elfutils-0.143.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-libs/elfutils/elfutils-0.143.ebuild?rev=1.1&content-type=text/plain

Index: elfutils-0.143.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/elfutils/elfutils-0.143.ebuild,v 1.1 2009/09/26 21:53:40 dirtyepic Exp $

inherit eutils

DESCRIPTION="Libraries/utilities to handle ELF objects (drop in replacement for libelf)"
HOMEPAGE="http://people.redhat.com/drepper/"
#SRC_URI="ftp://sources.redhat.com/pub/systemtap/${PN}/${P}.tar.gz"
#SRC_URI="mirror://debian/pool/main/e/elfutils/elfutils_${PV}.orig.tar.gz"
SRC_URI="https://fedorahosted.org/releases/e/l/elfutils/${P}.tar.bz2"

LICENSE="GPL-2-with-exceptions"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="bzip2 lzma nls test zlib"

# This pkg does not actually seem to compile currently in a uClibc
# environment (xrealloc errs), but we need to ensure that glibc never
# gets pulled in as a dep since this package does not respect virtual/libc
RDEPEND="zlib? ( >=sys-libs/zlib-1.2.2.3 )
	bzip2? ( app-arch/bzip2 )
	lzma? ( app-arch/xz-utils )"
DEPEND="${RDEPEND}
	elibc_glibc? ( >=sys-libs/glibc-2.7 )
	nls? ( sys-devel/gettext )
	>=sys-devel/flex-2.5.4a
	sys-devel/m4
	>=sys-devel/binutils-2.15.90.0.1
	>=sys-devel/gcc-4.1.2
	!dev-libs/libelf"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-0.118-PaX-support.patch
	find . -name Makefile.in -print0 | xargs -0 sed -i -e 's:-W\(error\|extra\)::g'
	use test || sed -i -e 's: tests::' Makefile.in #226349
}

src_compile() {
	econf \
		$(use_enable nls) \
		--program-prefix="eu-" \
		$(use_with zlib) \
		$(use_with bzip2 bzlib) \
		$(use_with lzma)

	emake || die
}

src_test() {
	env LD_LIBRARY_PATH="${S}/libelf:${S}/libebl:${S}/libdw:${S}/libasm" \
		make check || die "test failed"
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc AUTHORS ChangeLog NEWS NOTES README THANKS TODO
}