[gentoo-commits] gentoo-x86 commit in net-firewall/ipp2p: ChangeLog ipp2p-0.8.2-r5.ebuild ipp2p-0.8.2-r4.ebuild

[gentoo-commits] gentoo-x86 commit in net-firewall/ipp2p: ChangeLog ipp2p-0.8.2-r5.ebuild ipp2p-0.8.2-r4.ebuild

[Alin Nastac (mrness)]

mrness      09/09/20 12:58:24

  Modified:             ChangeLog
  Added:                ipp2p-0.8.2-r5.ebuild
  Removed:              ipp2p-0.8.2-r4.ebuild
  Log:
  Fix crash on 2.6.30 kernel (#278858).
  (Portage version: 2.1.6.13/cvs/Linux x86_64, RepoMan options: --force)

Revision  Changes    Path
1.42                 net-firewall/ipp2p/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/ipp2p/ChangeLog?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/ipp2p/ChangeLog?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/ipp2p/ChangeLog?r1=1.41&r2=1.42

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-firewall/ipp2p/ChangeLog,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- ChangeLog	25 Apr 2009 11:09:42 -0000	1.41
+++ ChangeLog	20 Sep 2009 12:58:23 -0000	1.42
@@ -1,6 +1,13 @@
 # ChangeLog for net-firewall/ipp2p
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-firewall/ipp2p/ChangeLog,v 1.41 2009/04/25 11:09:42 mrness Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-firewall/ipp2p/ChangeLog,v 1.42 2009/09/20 12:58:23 mrness Exp $
+
+*ipp2p-0.8.2-r5 (20 Sep 2009)
+
+  20 Sep 2009; Alin Năstac <mrness@gentoo.org> -ipp2p-0.8.2-r4.ebuild,
+  +ipp2p-0.8.2-r5.ebuild, -files/ipp2p-0.8.2-kernel-2.6.22.patch,
+  +files/ipp2p-0.8.2-kernel-2.6.30.patch:
+  Fix crash on 2.6.30 kernel (#278858).
 
   25 Apr 2009; Alin Năstac <mrness@gentoo.org>
   files/ipp2p-0.8.2-iptables-1.4.3.patch:



1.1                  net-firewall/ipp2p/ipp2p-0.8.2-r5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/ipp2p/ipp2p-0.8.2-r5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-firewall/ipp2p/ipp2p-0.8.2-r5.ebuild?rev=1.1&content-type=text/plain

Index: ipp2p-0.8.2-r5.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/ipp2p/ipp2p-0.8.2-r5.ebuild,v 1.1 2009/09/20 12:58:23 mrness Exp $

EAPI="2"

inherit linux-mod eutils

DESCRIPTION="Netfilter module for dealing with P2P Applications."
HOMEPAGE="http://www.ipp2p.org/index_en.html"
SRC_URI="http://www.ipp2p.org/downloads/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ~ppc ppc64 sparc x86"
IUSE=""

RDEPEND="virtual/modutils
	 net-firewall/iptables"

DEPEND="${RDEPEND}
	virtual/linux-sources"

pkg_setup() {
	CONFIG_CHECK="NETFILTER"
	NETFILTER_ERROR="Your kernel is not configured to support Netfilter."
	MODULE_NAMES="ipt_ipp2p(${PN}:${S}:${S})"

	linux-mod_pkg_setup
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-kernel-2.6.30.patch
	convert_to_m Makefile

	sed -i -e "s/^IPTABLES_VERSION/#IPTABLES_VERSION/" Makefile

	has_version '>=net-firewall/iptables-1.3.6' || return 0
	sed -i -e "s/ld -shared/\$\(CC\) -shared/" Makefile

	has_version '>=net-firewall/iptables-1.4.0' || return 0
	epatch "${FILESDIR}"/${P}-iptables-1.4.0.patch

	has_version '>=net-firewall/iptables-1.4.1' || return 0
	epatch "${FILESDIR}"/${P}-iptables-1.4.1.patch

	has_version '>=net-firewall/iptables-1.4.3' || return 0
	epatch "${FILESDIR}"/${P}-iptables-1.4.3.patch
}

src_compile() {
	local IPTABLES_VERSION="$(/sbin/iptables --version | cut -f2 -dv)"
	emake CFLAGS="${CFLAGS}" CC="$(tc-getCC)" \
	    IPTABLES_SRC="/usr" IPTABLES_VERSION="${IPTABLES_VERSION}" libipt_ipp2p.so \
	    || die "Failed to build iptables module"

	local myARCH="${ARCH}"
	ARCH="$(tc-arch-kernel)"
	emake KERNEL_SRC="${KV_DIR}" \
	    IPTABLES_SRC="/usr" IPTABLES_VERSION="${IPTABLES_VERSION}" \
	    || die "Failed to build kernel module."
	ARCH="${myARCH}"
}

src_install() {
	if has_version '>=net-firewall/iptables-1.4.1' ; then
		exeinto /$(get_libdir)/xtables
	else
		exeinto /$(get_libdir)/iptables
	fi
	doexe libipt_ipp2p.so

	dodoc README
	linux-mod_src_install
}

pkg_postinst() {
	linux-mod_pkg_postinst
}