[gentoo-commits] gentoo-x86 commit in dev-embedded/scratchbox: ChangeLog scratchbox-1.0.16.ebuild scratchbox-1.0.14.ebuild

[gentoo-commits] gentoo-x86 commit in dev-embedded/scratchbox: ChangeLog scratchbox-1.0.16.ebuild scratchbox-1.0.14.ebuild

[Olivier Crete (tester)]

tester      09/09/16 00:07:20

  Modified:             ChangeLog
  Added:                scratchbox-1.0.16.ebuild
  Removed:              scratchbox-1.0.14.ebuild
  Log:
  Version bump
  (Portage version: 2.1.6.13/cvs/Linux i686)

Revision  Changes    Path
1.5                  dev-embedded/scratchbox/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-embedded/scratchbox/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-embedded/scratchbox/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-embedded/scratchbox/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-embedded/scratchbox/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	6 May 2009 20:41:13 -0000	1.4
+++ ChangeLog	16 Sep 2009 00:07:20 -0000	1.5
@@ -1,6 +1,12 @@
 # ChangeLog for dev-embedded/scratchbox
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-embedded/scratchbox/ChangeLog,v 1.4 2009/05/06 20:41:13 tester Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-embedded/scratchbox/ChangeLog,v 1.5 2009/09/16 00:07:20 tester Exp $
+
+*scratchbox-1.0.16 (16 Sep 2009)
+
+  16 Sep 2009; Olivier Crête <tester@gentoo.org> -scratchbox-1.0.14.ebuild,
+  +scratchbox-1.0.16.ebuild:
+  Version bump
 
   06 May 2009; Olivier Crête <tester@gentoo.org> scratchbox-1.0.14.ebuild:
   Create right path



1.1                  dev-embedded/scratchbox/scratchbox-1.0.16.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-embedded/scratchbox/scratchbox-1.0.16.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-embedded/scratchbox/scratchbox-1.0.16.ebuild?rev=1.1&content-type=text/plain

Index: scratchbox-1.0.16.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-embedded/scratchbox/scratchbox-1.0.16.ebuild,v 1.1 2009/09/16 00:07:20 tester Exp $

inherit eutils

SBOX_GROUP="sbox"
RESTRICT="strip binchecks"

DESCRIPTION="A cross-compilation toolkit designed to make embedded Linux application development easier."
HOMEPAGE="http://www.scratchbox.org/"
SRC_URI="http://scratchbox.org/download/files/sbox-releases/stable/tarball/scratchbox-core-${PV}-i386.tar.gz
	http://scratchbox.org/download/files/sbox-releases/stable/tarball/scratchbox-libs-${PV}-i386.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

DEPEND=""
RDEPEND=""

TARGET_DIR="/opt/scratchbox"

S=${WORKDIR}/${PN}

src_install() {
	dodir ${TARGET_DIR}
	# doins doesn't work with symlinks, getting "file not found" with doins
	cp -pRP ./* "${D}/${TARGET_DIR}"
	ln -s opt/scratchbox "${D}/scratchbox"

	# scratchbox service loader
	newinitd "${FILESDIR}/scratchbox.rc" scratchbox || die "newinitd failed"

	# group already created
	echo ${SBOX_GROUP} > "${D}/${TARGET_DIR}/.run_me_first_done"
}

pkg_preinst() {
	einfo "Creating group sbox"
	enewgroup "${SBOX_GROUP}"
}

pkg_postinst() {
	"${TARGET_DIR}/sbin/sbox_configure" "no" ${SBOX_GROUP}

	elog
	elog "You can run:"
	elog "\"emerge --config =${CATEGORY}/${PF}\""
	elog "to setup scratchbox users"
	elog
	elog "For further documentation about how to setup"
	elog "scratchbox for your development needs have a look at"
	elog "http://scratchbox.org/documentation/user/scratchbox-1.0/"
	elog
	elog "Also note that when you reboot you should run:"
	elog "/etc/init.d/scratchbox start"
	elog "before trying to run scratchbox."
	elog "You can also add it to the default runlevel:"
	elog "rc-update add scratchbox default"
	elog
	elog "Type /opt/scratchbox/login to start scratchbox."
	elog
}

pkg_postrm() {
	elog
	elog "To remove all traces of scratchbox you will need to remove the file"
	elog "/etc/init.d/scratchbox. Don't forget to delete the sbox group."
	elog
}

pkg_config() {
	if [ `id -u` != "0" ]; then
		ewarn "Must be root to run this"
		die "not root"
	fi

	mkdir -p "${TARGET_DIR}/users"

	while true; do
		einfo "Existing users:"
		einfo $(ls "${TARGET_DIR}/users")
		echo

		einfo "Create new user (leaf empty to skip): "
		read newuser
		case "$newuser" in
			"")
				break;
				;;
			*)
				einfo "Note: users have to be in the '${SBOX_GROUP}' to be able to login into the scratchbox"
				"${TARGET_DIR}/sbin/sbox_adduser" ${newuser} || die "sbox_adduser failed"
				;;
		esac
	done

	einfo "Configuration finished. Make sure you run '/etc/init.d/scratchbox start' before logging in."
}