[gentoo-commits] gentoo-x86 commit in net-proxy/privoxy: ChangeLog privoxy-3.0.14_beta.ebuild

[gentoo-commits] gentoo-x86 commit in net-proxy/privoxy: ChangeLog privoxy-3.0.14_beta.ebuild

[Alin Nastac (mrness)]

mrness      09/08/08 09:52:48

  Modified:             ChangeLog
  Added:                privoxy-3.0.14_beta.ebuild
  Log:
  Version bump (#279447).
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.53                 net-proxy/privoxy/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/privoxy/ChangeLog?rev=1.53&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/privoxy/ChangeLog?rev=1.53&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/privoxy/ChangeLog?r1=1.52&r2=1.53

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-proxy/privoxy/ChangeLog,v
retrieving revision 1.52
retrieving revision 1.53
diff -u -r1.52 -r1.53
--- ChangeLog	27 Jul 2009 14:17:28 -0000	1.52
+++ ChangeLog	8 Aug 2009 09:52:48 -0000	1.53
@@ -1,6 +1,12 @@
 # ChangeLog for net-proxy/privoxy
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/privoxy/ChangeLog,v 1.52 2009/07/27 14:17:28 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/privoxy/ChangeLog,v 1.53 2009/08/08 09:52:48 mrness Exp $
+
+*privoxy-3.0.14_beta (08 Aug 2009)
+
+  08 Aug 2009; Alin Năstac <mrness@gentoo.org>
+  +files/privoxy-3.0.14_beta-gentoo.patch, +privoxy-3.0.14_beta.ebuild:
+  Version bump (#279447).
 
   27 Jul 2009; <chainsaw@gentoo.org> privoxy-3.0.12.ebuild:
   Marked stable on AMD64 as requested by Alin Năstac <mrness@gentoo.org> in



1.1                  net-proxy/privoxy/privoxy-3.0.14_beta.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/privoxy/privoxy-3.0.14_beta.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/privoxy/privoxy-3.0.14_beta.ebuild?rev=1.1&content-type=text/plain

Index: privoxy-3.0.14_beta.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-proxy/privoxy/privoxy-3.0.14_beta.ebuild,v 1.1 2009/08/08 09:52:48 mrness Exp $

EAPI="2"

inherit eutils toolchain-funcs autotools

[ "${PV##*_}" = "beta" ] &&
	PRIVOXY_STATUS="beta" ||
	PRIVOXY_STATUS="stable"

HOMEPAGE="http://www.privoxy.org
	http://sourceforge.net/projects/ijbswa/"
DESCRIPTION="A web proxy with advanced filtering capabilities for protecting privacy against Internet junk"
SRC_URI="mirror://sourceforge/ijbswa/${P%_*}-${PRIVOXY_STATUS}-src.tar.gz"

IUSE="selinux threads zlib"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
LICENSE="GPL-2"

DEPEND="dev-libs/libpcre
	zlib? ( sys-libs/zlib )"
RDEPEND="${DEPEND}
	selinux? ( sec-policy/selinux-privoxy )"

S="${WORKDIR}/${P%_*}-${PRIVOXY_STATUS}"

pkg_setup() {
	enewgroup privoxy
	enewuser privoxy -1 -1 /etc/privoxy privoxy
}

src_prepare() {
	epatch "${FILESDIR}"/${P}-gentoo.patch
	# autoreconf needs to be called even if we don't modify any autotools source files
	# See main makefile
	eautoreconf || die "eautoreconf failed"
}

src_configure() {
	export CC=$(tc-getCC)
	econf \
		$(use_enable zlib) \
		$(use_enable threads pthread) \
		--enable-dynamic-pcre \
		--with-user=privoxy \
		--with-group=privoxy \
		--sysconfdir=/etc/privoxy \
		--docdir=/usr/share/doc/${PF} \
		|| die "econf failed"
}

src_install () {
	emake DESTDIR="${D}" install || die "emake install failed"

	newinitd "${FILESDIR}/privoxy.initd" privoxy
	insinto /etc/logrotate.d
	newins "${FILESDIR}/privoxy.logrotate" privoxy

	diropts -m 0750 -g privoxy -o privoxy
	keepdir /var/log/privoxy
}