* [gentoo-commits] gentoo-x86 commit in net-irc/bip: ChangeLog bip-0.8.1.ebuild bip-0.7.4-r1.ebuild bip-0.8.0_rc1.ebuild
@ 2009-07-31 18:51 Alex Legler (a3li)
0 siblings, 0 replies; only message in thread
From: Alex Legler (a3li) @ 2009-07-31 18:51 UTC (permalink / raw
To: gentoo-commits
a3li 09/07/31 18:51:29
Modified: ChangeLog
Added: bip-0.8.1.ebuild
Removed: bip-0.7.4-r1.ebuild bip-0.8.0_rc1.ebuild
Log:
Version bump, remove old, fix configure. Thanks, diego.
(Portage version: 2.2_rc33/cvs/Linux x86_64)
Revision Changes Path
1.7 net-irc/bip/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/bip/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/bip/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/bip/ChangeLog?r1=1.6&r2=1.7
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/bip/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog 23 Mar 2009 15:58:15 -0000 1.6
+++ ChangeLog 31 Jul 2009 18:51:29 -0000 1.7
@@ -1,6 +1,13 @@
# ChangeLog for net-irc/bip
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/bip/ChangeLog,v 1.6 2009/03/23 15:58:15 a3li Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/bip/ChangeLog,v 1.7 2009/07/31 18:51:29 a3li Exp $
+
+*bip-0.8.1 (31 Jul 2009)
+
+ 31 Jul 2009; Alex Legler <a3li@gentoo.org> -bip-0.7.4-r1.ebuild,
+ -bip-0.8.0_rc1.ebuild, +bip-0.8.1.ebuild,
+ +files/bip-0.8.1-configure-oidentd.patch:
+ Version bump, removing old versions, fix configure (thanks to flameeyes)
*bip-0.8.0 (23 Mar 2009)
1.1 net-irc/bip/bip-0.8.1.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/bip/bip-0.8.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-irc/bip/bip-0.8.1.ebuild?rev=1.1&content-type=text/plain
Index: bip-0.8.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/bip/bip-0.8.1.ebuild,v 1.1 2009/07/31 18:51:29 a3li Exp $
EAPI="2"
inherit autotools
DESCRIPTION="Multiuser IRC proxy with ssl support"
HOMEPAGE="http://bip.t1r.net/"
SRC_URI="http://bip.t1r.net/downloads/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug ssl vim-syntax oidentd"
DEPEND="ssl? ( dev-libs/openssl )"
RDEPEND="${DEPEND}
vim-syntax? ( || ( app-editors/vim
app-editors/gvim ) )
oidentd? ( >=net-misc/oidentd-2.0 )"
src_prepare() {
# configure broken: --disable-oidentd enables it, too
epatch "${FILESDIR}/${P}-configure-oidentd.patch"
eautoreconf
}
src_configure() {
econf \
$(use_enable ssl openssl)\
$(use_enable debug)\
$(use_enable oidentd)
}
src_compile() {
# Parallel make fails.
# {C,CXX,LD}FLAGS aren't respected, bug 241030.
emake CFLAGS="${CFLAGS}" CPPFLAGS="${CXXFLAGS}" \
LDFLAGS="${LDFLAGS}" -j1 || die "emake failed"
}
src_install() {
dobin src/bip src/bipmkpw || die "dobin failed"
dodoc AUTHORS ChangeLog README NEWS TODO || die "dodoc failed"
newdoc samples/bip.conf bip.conf.sample || die "newdoc failed"
doman bip.1 bip.conf.5 bipmkpw.1 || die "doman failed"
if use vim-syntax; then
insinto /usr/share/vim/vimfiles/syntax
doins samples/bip.vim || die "doins failed"
insinto /usr/share/vim/vimfiles/ftdetect
doins "${FILESDIR}"/bip.vim || die "doins failed"
fi
}
pkg_postinst() {
elog 'Default configuration file is "~/.bip/bip.conf"'
elog "You can find a sample configuration file in"
elog "/usr/share/doc/${PF}/bip.conf.sample"
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2009-07-31 18:51 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2009-07-31 18:51 [gentoo-commits] gentoo-x86 commit in net-irc/bip: ChangeLog bip-0.8.1.ebuild bip-0.7.4-r1.ebuild bip-0.8.0_rc1.ebuild Alex Legler (a3li)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox