[gentoo-commits] gentoo-x86 commit in media-video/smplayer: ChangeLog smplayer-0.6.8.ebuild smplayer-0.6.7_p2872-r1.ebuild smplayer-0.6.5.1.ebuild smplayer-0.6.5-r1.ebuild smplayer-0.6.1-r1.ebuild smplayer-0.6.6_p2776.ebuild

[gentoo-commits] gentoo-x86 commit in media-video/smplayer: ChangeLog smplayer-0.6.8.ebuild smplayer-0.6.7_p2872-r1.ebuild smplayer-0.6.5.1.ebuild smplayer-0.6.5-r1.ebuild smplayer-0.6.1-r1.ebuild smplayer-0.6.6_p2776.ebuild

[Ben de Groot (yngwin)]

yngwin      09/07/26 13:14:37

  Modified:             ChangeLog
  Added:                smplayer-0.6.8.ebuild
  Removed:              smplayer-0.6.7_p2872-r1.ebuild
                        smplayer-0.6.5.1.ebuild smplayer-0.6.5-r1.ebuild
                        smplayer-0.6.1-r1.ebuild
                        smplayer-0.6.6_p2776.ebuild
  Log:
  Version bump. Add Estonian and Vietnamese translations. Remove some old ebuilds.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.72                 media-video/smplayer/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/smplayer/ChangeLog?rev=1.72&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/smplayer/ChangeLog?rev=1.72&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/smplayer/ChangeLog?r1=1.71&r2=1.72

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/smplayer/ChangeLog,v
retrieving revision 1.71
retrieving revision 1.72
diff -u -r1.71 -r1.72
--- ChangeLog	6 Jul 2009 22:34:27 -0000	1.71
+++ ChangeLog	26 Jul 2009 13:14:37 -0000	1.72
@@ -1,6 +1,15 @@
 # ChangeLog for media-video/smplayer
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/ChangeLog,v 1.71 2009/07/06 22:34:27 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/ChangeLog,v 1.72 2009/07/26 13:14:37 yngwin Exp $
+
+*smplayer-0.6.8 (26 Jul 2009)
+
+  26 Jul 2009; Ben de Groot <yngwin@gentoo.org> -smplayer-0.6.1-r1.ebuild,
+  -smplayer-0.6.5-r1.ebuild, -smplayer-0.6.5.1.ebuild,
+  -smplayer-0.6.6_p2776.ebuild, -smplayer-0.6.7_p2872-r1.ebuild,
+  +smplayer-0.6.8.ebuild:
+  Version bump. Add Estonian and Vietnamese translations. Remove some old
+  ebuilds.
 
   06 Jul 2009; Jeroen Roovers <jer@gentoo.org> smplayer-0.6.6.ebuild:
   Stable for HPPA (bug #257852).



1.1                  media-video/smplayer/smplayer-0.6.8.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/smplayer/smplayer-0.6.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/smplayer/smplayer-0.6.8.ebuild?rev=1.1&content-type=text/plain

Index: smplayer-0.6.8.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/smplayer-0.6.8.ebuild,v 1.1 2009/07/26 13:14:37 yngwin Exp $

EAPI=2
inherit eutils qt4

MY_PV=${PV##*_p}
if [[ "${MY_PV}" != "${PV}" ]]; then
	# svn snapshot
	MY_PV=r${MY_PV}
	MY_P=${PN}-${MY_PV}
	S="${WORKDIR}/${MY_P}"
	SRC_URI="mirror://gentoo/${MY_P}.tar.bz2"
else
	# regular upstream release
	SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
fi

DESCRIPTION="Great Qt4 GUI front-end for mplayer"
HOMEPAGE="http://smplayer.sourceforge.net"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="debug"

DEPEND="x11-libs/qt-gui:4"
RDEPEND="${DEPEND}
	media-video/mplayer[ass,png]"

LANGS="bg ca cs de en_US es et eu fi fr gl hu it ja ka ko ku mk nl pl pt_BR
pt_PT sk sr sv tr zh_CN zh_TW"
# langs with long notation in pkg, but no long notation in portage:
NOLONGLANGS="ar_SY el_GR ro_RO ru_RU sl_SI uk_UA vi_VN"
for X in ${LANGS}; do
	IUSE="${IUSE} linguas_${X}"
done
for X in ${NOLONGLANGS}; do
	IUSE="${IUSE} linguas_${X%_*}"
done

src_prepare() {
	# Upstream Makefile sucks
	sed -i -e "/^PREFIX=/s:/usr/local:/usr:" \
		-e "/^DOC_PATH=/s:packages/smplayer:${PF}:" \
		-e '/\.\/get_svn_revision\.sh/,+2c\
	cd src && $(DEFS) $(MAKE)' \
		"${S}"/Makefile || die "sed failed"

	# Turn debug message flooding off
	if ! use debug ; then
		sed -i 's:#\(DEFINES += NO_DEBUG_ON_CONSOLE\):\1:' \
			"${S}"/src/smplayer.pro || die "sed failed"
	fi
}

src_configure() {
	cd "${S}"/src
	echo "#define SVN_REVISION \"SVN-${MY_PV} (Gentoo)\"" > svn_revision.h
	eqmake4
}

gen_translation() {
	ebegin "Generating $1 translation"
	lrelease ${PN}_${1}.ts
	eend $? || die "failed to generate $1 translation"
}

src_compile() {
	emake || die "emake failed"

	# Generate translations
	cd "${S}"/src/translations
	local lang= nolangs= x=
	for lang in ${LINGUAS}; do
		if has ${lang} ${LANGS}; then
			gen_translation ${lang}
			continue
		elif [[ " ${NOLONGLANGS} " == *" ${lang}_"* ]]; then
			for x in ${NOLONGLANGS}; do
				if [[ "${lang}" == "${x%_*}" ]]; then
					gen_translation ${x}
					continue 2
				fi
			done
		fi
		nolangs="${nolangs} ${lang}"
	done
	[[ -n ${nolangs} ]] && ewarn "Sorry, but ${PN} does not support the LINGUAS:" ${nolangs}
	# install fails when no translation is present (bug 244370)
	[[ -z $(ls *.qm 2>/dev/null) ]] && gen_translation en_US
}

src_install() {
	# remove unneeded copies of GPL
	rm -f Copying.txt docs/{cs,en,ja,ru}/gpl.html
	rm -rf docs/{de,es,nl,ro}

	# remove windows-only files
	rm "${S}"/*.bat

	emake DESTDIR="${D}" install || die "emake install failed"
	prepalldocs
}