[gentoo-commits] gentoo-x86 commit in media-sound/aqualung: ChangeLog aqualung-0.9_beta10-r2.ebuild

[gentoo-commits] gentoo-x86 commit in media-sound/aqualung: ChangeLog aqualung-0.9_beta10-r2.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    09/07/26 12:49:51

  Modified:             ChangeLog
  Added:                aqualung-0.9_beta10-r2.ebuild
  Log:
  Use transition package media-libs/libmpcdecsv7 instead of media-libs/libmpcdec for Musepack support.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  media-sound/aqualung/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/aqualung/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/aqualung/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/aqualung/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/aqualung/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	22 Jul 2009 15:54:43 -0000	1.5
+++ ChangeLog	26 Jul 2009 12:49:51 -0000	1.6
@@ -1,6 +1,14 @@
 # ChangeLog for media-sound/aqualung
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/aqualung/ChangeLog,v 1.5 2009/07/22 15:54:43 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/aqualung/ChangeLog,v 1.6 2009/07/26 12:49:51 ssuominen Exp $
+
+*aqualung-0.9_beta10-r2 (26 Jul 2009)
+
+  26 Jul 2009; Samuli Suominen <ssuominen@gentoo.org>
+  +aqualung-0.9_beta10-r2.ebuild,
+  +files/aqualung-0.9_beta10-libmpcdecsv7.patch:
+  Use transition package media-libs/libmpcdecsv7 instead of
+  media-libs/libmpcdec for Musepack support.
 
   22 Jul 2009; Samuli Suominen <ssuominen@gentoo.org> metadata.xml:
   USE cdda is now global.



1.1                  media-sound/aqualung/aqualung-0.9_beta10-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/aqualung/aqualung-0.9_beta10-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/aqualung/aqualung-0.9_beta10-r2.ebuild?rev=1.1&content-type=text/plain

Index: aqualung-0.9_beta10-r2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/aqualung/aqualung-0.9_beta10-r2.ebuild,v 1.1 2009/07/26 12:49:51 ssuominen Exp $

EAPI=2
inherit autotools eutils versionator

MY_PV="$(delete_version_separator 2)"
MY_PV="${MY_PV/_p/.}"

DESCRIPTION="A music player for a wide range of formats designed for gapless playback"
HOMEPAGE="http://aqualung.factorial.hu/"
SRC_URI="mirror://sourceforge/aqualung/${PN}-${MY_PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
IUSE="sndfile modplug mp3 vorbis speex flac musepack wavpack ffmpeg ladspa
	cddb cdda ifp jack lua alsa oss lame systray libsamplerate podcast debug"
KEYWORDS="~amd64 ~x86"

RDEPEND="vorbis? ( media-libs/libvorbis )
	sndfile? ( media-libs/libsndfile )
	flac? ( media-libs/flac )
	modplug? ( media-libs/libmodplug )
	alsa? ( virtual/alsa )
	mp3? ( media-libs/libmad )
	lame? ( media-sound/lame )
	musepack? ( media-libs/libmpcdecsv7 )
	ffmpeg? ( media-video/ffmpeg )
	speex? ( media-libs/speex media-libs/liboggz )
	wavpack? ( media-sound/wavpack )
	cddb? ( media-libs/libcddb )
	jack? ( media-sound/jack-audio-connection-kit )
	cdda? ( dev-libs/libcdio )
	ifp? ( media-libs/libifp )
	lua? ( dev-lang/lua )
	libsamplerate? ( media-libs/libsamplerate )
	x11-libs/gtk+:2"
DEPEND="${RDEPEND}
	ladspa? ( media-libs/liblrdf )
	dev-util/pkgconfig
	dev-libs/libxml2"

S=${WORKDIR}/${PN}-${MY_PV}

src_prepare() {
	epatch "${FILESDIR}"/${P}-libmpcdecsv7.patch
	eautoreconf
}

src_configure() {
	econf \
		$(use_with alsa) \
		$(use_with oss) \
		$(use_with jack) \
		$(use_with flac) \
		$(use_with vorbis ogg) \
		$(use_with vorbis vorbisenc) \
		$(use_with sndfile) \
		$(use_with mp3 mpeg) \
		$(use_with lame) \
		$(use_with modplug mod) \
		$(use_with musepack mpc) \
		$(use_with ffmpeg lavc) \
		$(use_with speex) \
		$(use_with wavpack) \
		$(use_with cddb) \
		$(use_with systray) \
		$(use_with ladspa) \
		$(use_with cdda) \
		$(use_with lua) \
		$(use_with ifp) \
		$(use_with libsamplerate src) \
		$(use_with podcast) \
		$(use_enable debug) \
		--with-loop \
		|| die "econf failed"
}

src_install() {
	emake install DESTDIR="${D}" || die "make install failed"
	dodoc AUTHORS README || die "dodoc failed"
	newicon src/img/icon_64.png aqualung.png
	make_desktop_entry aqualung Aqualung
}