[gentoo-commits] gentoo-x86 commit in net-misc/wicd: ChangeLog wicd-1.6.1.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/wicd: ChangeLog wicd-1.6.1.ebuild

[Jeremy Olexa (darkside)]

darkside    09/06/24 00:13:27

  Modified:             ChangeLog
  Added:                wicd-1.6.1.ebuild
  Log:
  Version bump, misc bug fixes and small UI improvements. Now supports udhcp for mobile hosts, etc. See CHANGES file for complete list
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.49                 net-misc/wicd/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/wicd/ChangeLog?rev=1.49&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/wicd/ChangeLog?rev=1.49&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/wicd/ChangeLog?r1=1.48&r2=1.49

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/wicd/ChangeLog,v
retrieving revision 1.48
retrieving revision 1.49
diff -u -r1.48 -r1.49
--- ChangeLog	17 Jun 2009 05:14:21 -0000	1.48
+++ ChangeLog	24 Jun 2009 00:13:27 -0000	1.49
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/wicd
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/wicd/ChangeLog,v 1.48 2009/06/17 05:14:21 darkside Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/wicd/ChangeLog,v 1.49 2009/06/24 00:13:27 darkside Exp $
+
+*wicd-1.6.1 (24 Jun 2009)
+
+  24 Jun 2009; Jeremy Olexa <darkside@gentoo.org> +wicd-1.6.1.ebuild:
+  Version bump, misc bug fixes and small UI improvements. Now supports udhcp
+  for mobile hosts, etc. See CHANGES file for complete list
 
 *wicd-1.6.0-r1 (17 Jun 2009)
 



1.1                  net-misc/wicd/wicd-1.6.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/wicd/wicd-1.6.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/wicd/wicd-1.6.1.ebuild?rev=1.1&content-type=text/plain

Index: wicd-1.6.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/wicd/wicd-1.6.1.ebuild,v 1.1 2009/06/24 00:13:27 darkside Exp $

EAPI="2"

inherit distutils eutils

DESCRIPTION="A lightweight wired and wireless network manager for Linux"
HOMEPAGE="http://wicd.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="ioctl libnotify ncurses +pm-utils"

DEPEND=""
RDEPEND="
	dev-python/dbus-python
	dev-python/pygtk
	|| (
		net-misc/dhcpcd
		net-misc/dhcp
		net-misc/pump
	)
	net-wireless/wireless-tools
	net-wireless/wpa_supplicant
	|| (
		sys-apps/net-tools
		sys-apps/ethtool
	)
	|| (
		x11-misc/ktsuss
		x11-libs/gksu
		kde-base/kdesu
	)
	ioctl? ( dev-python/python-iwscan dev-python/python-wpactrl )
	libnotify? ( dev-python/notify-python )
	ncurses? ( >=dev-python/urwid-0.9.8.4 )
	pm-utils? ( >=sys-power/pm-utils-1.1.1 )
	"

src_compile() {
	local myconf
	use libnotify || myconf="${myconf} --no-use-notifications"
	use ncurses || myconf="${myconf} --no-install-ncurses"
	use pm-utils || myconf="${myconf} --no-install-pmutils"
	${python} ./setup.py configure --no-install-docs --resume=/usr/share/wicd/scripts/ --suspend=/usr/share/wicd/scripts/ --verbose ${myconf}
	distutils_src_compile
}

src_install() {
	DOCS="CHANGES"
	distutils_src_install
	keepdir /var/lib/wicd/configurations \
		|| die "keepdir failed, critical for this app"
	keepdir /etc/wicd/scripts/{postconnect,disconnect,preconnect} \
		|| die "keepdir failed, critical for this app"
}

pkg_postinst() {
	distutils_pkg_postinst

	elog "You may need to restart the dbus service after upgrading wicd."
	echo
	elog "To start wicd at boot, add /etc/init.d/wicd to a runlevel and:"
	elog "- Remove all net.* initscripts (except for net.lo) from all runlevels"
	elog "- Add these scripts to the RC_PLUG_SERVICES line in /etc/conf.d/rc"
	elog "(For example, RC_PLUG_SERVICES=\"!net.eth0 !net.wlan0\")"
	# Maintainer's note: the consolekit use flag short circuits a dbus rule and
	# allows the connection. Else, you need to be in the group.
	if has_version sys-auth/pambase; then
		if ! built_with_use sys-auth/pambase consolekit; then
			ewarn "Wicd-1.6 and newer requires your user to be in the 'users' group. If"
			ewarn "you are not in that group, then modify /etc/dbus-1/system.d/wicd.conf"
		fi
	fi
}