* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-0.6.4.ebuild ChangeLog
@ 2009-06-09 12:48 Doug Goldstein (cardoe)
0 siblings, 0 replies; 2+ messages in thread
From: Doug Goldstein (cardoe) @ 2009-06-09 12:48 UTC (permalink / raw
To: gentoo-commits
cardoe 09/06/09 12:48:52
Modified: ChangeLog
Added: libvirt-0.6.4.ebuild
Log:
version bump. use v2 of my kvm-img patch
(Portage version: 2.1.6.13/cvs/Linux x86_64)
Revision Changes Path
1.27 app-emulation/libvirt/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.27&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.27&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.26&r2=1.27
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.26
retrieving revision 1.27
diff -u -r1.26 -r1.27
--- ChangeLog 28 May 2009 21:57:26 -0000 1.26
+++ ChangeLog 9 Jun 2009 12:48:52 -0000 1.27
@@ -1,6 +1,13 @@
# ChangeLog for app-emulation/libvirt
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.26 2009/05/28 21:57:26 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.27 2009/06/09 12:48:52 cardoe Exp $
+
+*libvirt-0.6.4 (09 Jun 2009)
+
+ 09 Jun 2009; Doug Goldstein <cardoe@gentoo.org> +libvirt-0.6.4.ebuild,
+ +files/libvirt-0.6.4-kvm-img.patch,
+ +files/libvirt-0.6.4-qemu-img-logic-fix.patch:
+ version bump. use v2 of my kvm-img patch
*libvirt-0.6.3-r3 (28 May 2009)
1.1 app-emulation/libvirt/libvirt-0.6.4.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/libvirt-0.6.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/libvirt-0.6.4.ebuild?rev=1.1&content-type=text/plain
Index: libvirt-0.6.4.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.6.4.ebuild,v 1.1 2009/06/09 12:48:52 cardoe Exp $
EAPI="2"
inherit eutils autotools confutils
DESCRIPTION="C toolkit to manipulate virtual machines"
HOMEPAGE="http://www.libvirt.org/"
SRC_URI="http://libvirt.org/sources/${P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avahi iscsi hal kvm lvm +lxc +network nls numa openvz policykit \
parted qemu sasl selinux uml virtualbox xen"
# devicekit isn't in portage
RDEPEND="sys-libs/readline
sys-libs/ncurses
>=dev-libs/libxml2-2.5
>=net-libs/gnutls-1.0.25
dev-lang/python
sys-fs/sysfsutils
net-analyzer/netcat
avahi? ( >=net-dns/avahi-0.6 )
iscsi? ( sys-block/open-iscsi )
kvm? ( app-emulation/kvm )
lvm? ( sys-fs/lvm2 )
network? ( net-misc/bridge-utils net-dns/dnsmasq net-firewall/iptables )
numa? ( sys-process/numactl )
openvz? ( sys-kernel/openvz-sources )
parted? ( >=sys-apps/parted-1.8 )
policykit? ( >=sys-auth/policykit-0.6 )
qemu? ( >=app-emulation/qemu-0.10.0 )
sasl? ( dev-libs/cyrus-sasl )
selinux? ( sys-libs/libselinux )
virtualbox? ( >=app-emulation/virtualbox-bin-2.2.0 )
xen? ( app-emulation/xen-tools app-emulation/xen )"
DEPEND="${RDEPEND}
dev-util/pkgconfig"
src_prepare() {
# Patch sent upstream for working with kvm-img
epatch "${FILESDIR}/${P}-kvm-img.patch"
# upstream patch. fix shared/read-only disk labeling
epatch "${FILESDIR}/${PN}-0.6.2-shared-readonly-label.patch"
# upstream patch. don't try to label a disk with no path (empty cdrom)
epatch "${FILESDIR}/${PN}-0.6.2-fix-nosource-label.patch"
# Fix logic error when using qemu-img
epatch "${FILESDIR}/${P}-qemu-img-logic-fix.patch"
eautoreconf
}
pkg_setup() {
confutils_require_any lxc kvm openvz qemu uml virtualbox xen
}
src_configure() {
local my_conf=""
if use qemu || use kvm ; then
my_conf="--with-qemu"
else
my_conf="--without-qemu"
fi
econf \
$(use_with iscsi storage-iscsi) \
$(use_with lvm storage-lvm) \
$(use_with parted storage-disk) \
$(use_with lxc) \
$(use_with openvz) \
$(use_with uml) \
$(use_with virtualbox vbox) \
$(use_with xen) \
$(use_with xen xen-inotify) \
$(use_with avahi) \
$(use_with hal) \
$(use_with sasl) \
$(use_with network) \
$(use_with policykit polkit) \
$(use_with selinux) \
$(use_enable nls) \
$(use_with numa numactl) \
${my_conf} \
--without-devkit \
--with-remote \
--disable-iptables-lokkit \
--localstatedir=/var \
--with-remote-pid-file=/var/run/libvirtd.pid
}
src_install() {
emake DESTDIR="${D}" install || die "emake instal lfailed"
mv "${D}"/usr/share/doc/{${PN}-python*,${P}/python}
newinitd "${FILESDIR}/libvirtd.init" libvirtd
newconfd "${FILESDIR}/libvirtd.confd" libvirtd
keepdir /var/lib/libvirt/images
}
pkg_postinst() {
elog "To allow normal users to connect to libvirtd you must change the"
elog " unix sock group and/or perms in /etc/libvirt/libvirtd.conf"
elog
ewarn "If you have a DNS server setup on your machine, you will have"
ewarn "to configure /etc/dnsmasq.conf to enable the following settings: "
ewarn " bind-interfaces"
ewarn " interface or except-interface"
elog
ewarn "Otherwise you might have issues with your existing DNS server."
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-0.6.4.ebuild ChangeLog
@ 2009-06-09 18:37 Patrick Lauer (patrick)
0 siblings, 0 replies; 2+ messages in thread
From: Patrick Lauer (patrick) @ 2009-06-09 18:37 UTC (permalink / raw
To: gentoo-commits
patrick 09/06/09 18:37:33
Modified: libvirt-0.6.4.ebuild ChangeLog
Log:
Fixing virtualbox dep for #272264
(Portage version: 2.2_rc33/cvs/Linux x86_64)
Revision Changes Path
1.2 app-emulation/libvirt/libvirt-0.6.4.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/libvirt-0.6.4.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/libvirt-0.6.4.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/libvirt-0.6.4.ebuild?r1=1.1&r2=1.2
Index: libvirt-0.6.4.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.6.4.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- libvirt-0.6.4.ebuild 9 Jun 2009 12:48:52 -0000 1.1
+++ libvirt-0.6.4.ebuild 9 Jun 2009 18:37:33 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.6.4.ebuild,v 1.1 2009/06/09 12:48:52 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.6.4.ebuild,v 1.2 2009/06/09 18:37:33 patrick Exp $
EAPI="2"
@@ -35,7 +35,7 @@
qemu? ( >=app-emulation/qemu-0.10.0 )
sasl? ( dev-libs/cyrus-sasl )
selinux? ( sys-libs/libselinux )
- virtualbox? ( >=app-emulation/virtualbox-bin-2.2.0 )
+ virtualbox? ( || ( >=app-emulation/virtualbox-ose-2.2.0 >=app-emulation/virtualbox-bin-2.2.0 ) )
xen? ( app-emulation/xen-tools app-emulation/xen )"
DEPEND="${RDEPEND}
dev-util/pkgconfig"
1.29 app-emulation/libvirt/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-emulation/libvirt/ChangeLog?r1=1.28&r2=1.29
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog 9 Jun 2009 13:26:37 -0000 1.28
+++ ChangeLog 9 Jun 2009 18:37:33 -0000 1.29
@@ -1,6 +1,9 @@
# ChangeLog for app-emulation/libvirt
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.28 2009/06/09 13:26:37 cardoe Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.29 2009/06/09 18:37:33 patrick Exp $
+
+ 09 Jun 2009; Patrick Lauer <patrick@gentoo.org> libvirt-0.6.4.ebuild:
+ Fixing virtualbox dep for #272264
09 Jun 2009; Doug Goldstein <cardoe@gentoo.org>
-files/libvirt-0.4.4-binary-paths.patch,
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2009-06-09 18:37 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2009-06-09 12:48 [gentoo-commits] gentoo-x86 commit in app-emulation/libvirt: libvirt-0.6.4.ebuild ChangeLog Doug Goldstein (cardoe)
-- strict thread matches above, loose matches on Subject: below --
2009-06-09 18:37 Patrick Lauer (patrick)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox