[gentoo-commits] gentoo-x86 commit in sys-libs/e2fsprogs-libs: ChangeLog e2fsprogs-libs-1.41.5.ebuild

["Mike Frysinger (vapier)" <vapier@gentoo.org>]

vapier      09/05/29 23:26:49

  Modified:             ChangeLog
  Added:                e2fsprogs-libs-1.41.5.ebuild
  Log:
  Version bump #267402 by Paul Mulders.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.24                 sys-libs/e2fsprogs-libs/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?rev=1.24&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?rev=1.24&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?r1=1.23&r2=1.24

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v
retrieving revision 1.23
retrieving revision 1.24
diff -u -r1.23 -r1.24
--- ChangeLog	15 Mar 2009 05:01:39 -0000	1.23
+++ ChangeLog	29 May 2009 23:26:49 -0000	1.24
@@ -1,6 +1,12 @@
 # ChangeLog for sys-libs/e2fsprogs-libs
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v 1.23 2009/03/15 05:01:39 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v 1.24 2009/05/29 23:26:49 vapier Exp $
+
+*e2fsprogs-libs-1.41.5 (29 May 2009)
+
+  29 May 2009; Mike Frysinger <vapier@gentoo.org>
+  +e2fsprogs-libs-1.41.5.ebuild:
+  Version bump #267402 by Paul Mulders.
 
   15 Mar 2009; Mike Frysinger <vapier@gentoo.org>
   e2fsprogs-libs-1.41.4.ebuild:



1.1                  sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.5.ebuild?rev=1.1&content-type=text/plain

Index: e2fsprogs-libs-1.41.5.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.5.ebuild,v 1.1 2009/05/29 23:26:49 vapier Exp $

EAPI="2"

inherit flag-o-matic toolchain-funcs

DESCRIPTION="e2fsprogs libraries (common error, subsystem, uuid, block id)"
HOMEPAGE="http://e2fsprogs.sourceforge.net/"
SRC_URI="mirror://sourceforge/e2fsprogs/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="nls"

RDEPEND="elibc_glibc? ( >=sys-libs/glibc-2.6 )
	!sys-libs/com_err
	!sys-libs/ss
	!<sys-fs/e2fsprogs-1.41"
DEPEND="nls? ( sys-devel/gettext )
	sys-devel/bc"

src_prepare() {
	# stupid configure script clobbers CC for us
	sed -i '/if test -z "$CC" ; then CC=cc; fi/d' configure
}

src_configure() {
	# We want to use the "bsd" libraries while building on Darwin, but while
	# building on other Gentoo/*BSD we prefer elf-naming scheme.
	local libtype
	case ${CHOST} in
		*-darwin*) libtype=bsd;;
		*)         libtype=elf;;
	esac

	ac_cv_path_LDCONFIG=: \
	econf \
		--enable-${libtype}-shlibs \
		$(use_enable !elibc_uclibc tls) \
		$(use_enable nls)
}

src_install() {
	emake STRIP=: DESTDIR="${D}" install || die

	set -- "${D}"/usr/$(get_libdir)/*.a
	set -- ${@/*\/lib}
	gen_usr_ldscript -a "${@/.a}"
}