[gentoo-commits] gentoo-x86 commit in mail-client/balsa: balsa-2.4.0.ebuild ChangeLog balsa-2.3.28.ebuild

[gentoo-commits] gentoo-x86 commit in mail-client/balsa: balsa-2.4.0.ebuild ChangeLog balsa-2.3.28.ebuild

[Gilles Dartiguelongue (eva)]

eva         09/05/28 21:56:38

  Modified:             ChangeLog balsa-2.3.28.ebuild
  Added:                balsa-2.4.0.ebuild
  Log:
  Bump to 2.4.0. VCALENDAR & VEVENT handling, use gmime:2.4, libunique, drop libgnomeprint usage.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.83                 mail-client/balsa/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/balsa/ChangeLog?rev=1.83&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/balsa/ChangeLog?rev=1.83&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/balsa/ChangeLog?r1=1.82&r2=1.83

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/balsa/ChangeLog,v
retrieving revision 1.82
retrieving revision 1.83
diff -u -r1.82 -r1.83
--- ChangeLog	28 May 2009 21:27:33 -0000	1.82
+++ ChangeLog	28 May 2009 21:56:38 -0000	1.83
@@ -1,6 +1,13 @@
 # ChangeLog for mail-client/balsa
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/balsa/ChangeLog,v 1.82 2009/05/28 21:27:33 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/balsa/ChangeLog,v 1.83 2009/05/28 21:56:38 eva Exp $
+
+*balsa-2.4.0 (28 May 2009)
+
+  28 May 2009; Gilles Dartiguelongue <eva@gentoo.org> balsa-2.3.28.ebuild,
+  +balsa-2.4.0.ebuild:
+  Bump to 2.4.0. VCALENDAR & VEVENT handling, use gmime:2.4, libunique, drop
+  libgnomeprint usage.
 
   28 May 2009; Gilles Dartiguelongue <eva@gentoo.org> -balsa-2.3.25.ebuild,
   -balsa-2.3.26.ebuild, -balsa-2.3.27.ebuild:



1.7                  mail-client/balsa/balsa-2.3.28.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/balsa/balsa-2.3.28.ebuild?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/balsa/balsa-2.3.28.ebuild?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/balsa/balsa-2.3.28.ebuild?r1=1.6&r2=1.7

Index: balsa-2.3.28.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/balsa/balsa-2.3.28.ebuild,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- balsa-2.3.28.ebuild	20 May 2009 16:54:24 -0000	1.6
+++ balsa-2.3.28.ebuild	28 May 2009 21:56:38 -0000	1.7
@@ -1,11 +1,11 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/balsa/balsa-2.3.28.ebuild,v 1.6 2009/05/20 16:54:24 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/balsa/balsa-2.3.28.ebuild,v 1.7 2009/05/28 21:56:38 eva Exp $
 
 inherit gnome2
 
 DESCRIPTION="Email client for GNOME"
-HOMEPAGE="http://balsa.gnome.org"
+HOMEPAGE="http://pawsa.fedorapeople.org/balsa/"
 SRC_URI="http://balsa.gnome.org/${P}.tar.bz2"
 
 LICENSE="GPL-2"



1.1                  mail-client/balsa/balsa-2.4.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/balsa/balsa-2.4.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/mail-client/balsa/balsa-2.4.0.ebuild?rev=1.1&content-type=text/plain

Index: balsa-2.4.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-client/balsa/balsa-2.4.0.ebuild,v 1.1 2009/05/28 21:56:38 eva Exp $

EAPI="2"

inherit gnome2

DESCRIPTION="Email client for GNOME"
HOMEPAGE="http://pawsa.fedorapeople.org/balsa/"
SRC_URI="http://pawsa.fedorapeople.org/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
# Doesn't currently build with -gnome
IUSE="crypt doc gnome gtkhtml +gtkspell kerberos ldap libnotify rubrica sqlite ssl xface"

RDEPEND=">=dev-libs/glib-2.16
	>=x11-libs/gtk+-2.14
	dev-libs/gmime:2.4
	>=net-libs/libesmtp-1.0.3
	x11-themes/hicolor-icon-theme
	net-mail/mailbase
	crypt? ( >=app-crypt/gpgme-1.0 )
	gnome? (
		>=gnome-base/orbit-2
		>=gnome-base/libbonobo-2.0
		>=gnome-base/libgnome-2.0
		>=gnome-base/libgnomeui-2.0
		>=gnome-base/gconf-2.0
		>=gnome-base/gnome-keyring-2.20
		>=x11-libs/gtksourceview-2 )
	gtkhtml? ( >=gnome-extra/gtkhtml-3.14 )
	sqlite? ( >=dev-db/sqlite-2.8 )
	libnotify? ( x11-libs/libnotify )
	gtkspell? ( =app-text/gtkspell-2* )
	!gtkspell? ( virtual/aspell-dict )
	kerberos? ( app-crypt/mit-krb5 )
	ldap? ( net-nds/openldap )
	rubrica? ( dev-libs/libxml2 )
	ssl? ( dev-libs/openssl )
	xface? ( >=media-libs/compface-1.5.1 )"
DEPEND="${RDEPEND}
	dev-util/intltool
	dev-util/pkgconfig
	sys-devel/gettext
	>=app-text/scrollkeeper-0.1.4
	app-text/gnome-doc-utils
	doc? ( dev-util/gtk-doc )"

DOCS="AUTHORS ChangeLog HACKING NEWS README TODO docs/*"

pkg_setup() {
	if use crypt ; then
		G2CONF="${G2CONF} --with-gpgme=gpgme-config"
	else
		G2CONF="${G2CONF} --without-gpgme"
	fi

	if use gtkhtml ; then
		G2CONF="${G2CONF} --with-gtkhtml=3"
	else
		G2CONF="${G2CONF} --without-gtkhtml"
	fi

	G2CONF="${G2CONF}
		--disable-pcre
		--enable-gregex
		--enable-threads
		--with-unique
		$(use_with gnome)
		$(use_with gnome gtksourceview)
		$(use_with gtkspell)
		$(use_with kerberos gss)
		$(use_with ldap)
		$(use_with libnotify)
		$(use_with rubrica)
		$(use_with sqlite)
		$(use_with ssl)
		$(use_with xface compface)"
}

src_prepare() {
	gnome2_src_prepare

	# Remove disable deprecated statement
	sed -i -e '/DISABLE_DEPRECATED/d' \
		libinit_balsa/Makefile.am libinit_balsa/Makefile.in \
		libbalsa/Makefile.am libbalsa/Makefile.in \
		src/Makefile.am src/Makefile.in || die "sed failed"
}