[gentoo-commits] gentoo-x86 commit in www-apache/passenger: ChangeLog passenger-2.2.2.ebuild

["Hans de Graaff (graaff)" <graaff@gentoo.org>]

graaff      09/05/19 10:04:40

  Modified:             ChangeLog
  Added:                passenger-2.2.2.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.6.11/cvs/Linux x86_64)

Revision  Changes    Path
1.8                  www-apache/passenger/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apache/passenger/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apache/passenger/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apache/passenger/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apache/passenger/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	15 Mar 2009 14:36:08 -0000	1.7
+++ ChangeLog	19 May 2009 10:04:40 -0000	1.8
@@ -1,6 +1,12 @@
 # ChangeLog for www-apache/passenger
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apache/passenger/ChangeLog,v 1.7 2009/03/15 14:36:08 a3li Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apache/passenger/ChangeLog,v 1.8 2009/05/19 10:04:40 graaff Exp $
+
+*passenger-2.2.2 (19 May 2009)
+
+  19 May 2009; Hans de Graaff <graaff@gentoo.org> +files/2.2.2-gentoo.patch,
+  +passenger-2.2.2.ebuild:
+  Version bump.
 
 *passenger-2.1.2 (15 Mar 2009)
 



1.1                  www-apache/passenger/passenger-2.2.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apache/passenger/passenger-2.2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apache/passenger/passenger-2.2.2.ebuild?rev=1.1&content-type=text/plain

Index: passenger-2.2.2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apache/passenger/passenger-2.2.2.ebuild,v 1.1 2009/05/19 10:04:40 graaff Exp $

inherit apache-module flag-o-matic ruby

DESCRIPTION="Passenger (a.k.a. mod_rails) makes deployment of Ruby on Rails applications a breeze"
HOMEPAGE="http://modrails.com/"
SRC_URI="mirror://rubyforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc"

CDEPEND=">=dev-lang/ruby-1.8.5
	>=dev-ruby/rubygems-0.9.0
	>=dev-ruby/rake-0.8.1
	>=dev-ruby/fastthread-1.0.1
	>=dev-ruby/rails-1.2.0"
DEPEND="${CDEPEND}
	doc? ( app-doc/doxygen )"
RDEPEND="${CDEPEND}"

APACHE2_MOD_FILE="${S}/ext/apache2/mod_${PN}.so"
APACHE2_MOD_CONF="30_mod_${PN}-2.0.1 30_mod_${PN}"
APACHE2_MOD_DEFINE="PASSENGER"

need_apache2_2

pkg_setup() {
	use debug && append-flags -DPASSENGER_DEBUG
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PV}-gentoo.patch
	rm -f bin/passenger-install-apache2-module
	sed -i -e '473s/, :doc//' Rakefile
}

src_compile() {
	APXS2="${APXS}" \
	HTTPD="${APACHE_BIN}" \
	rake apache2 native_support || die "rake failed"

	if use doc; then
		rake doc || die "rake doc failed"
	fi
}

src_install() {
	DISTDIR="${D}" \
	rake fakeroot || die "rake failed"

	apache-module_src_install
}