[gentoo-commits] gentoo-x86 commit in media-sound/qmpdclient: ChangeLog qmpdclient-1.1.0-r2.ebuild

["Markos Chandras (hwoarang)" <hwoarang@gentoo.org>]

hwoarang    09/05/18 18:18:30

  Modified:             ChangeLog
  Added:                qmpdclient-1.1.0-r2.ebuild
  Log:
  Add dbus use flag. Fixes bug 270324
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.44                 media-sound/qmpdclient/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/qmpdclient/ChangeLog?rev=1.44&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/qmpdclient/ChangeLog?rev=1.44&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/qmpdclient/ChangeLog?r1=1.43&r2=1.44

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/qmpdclient/ChangeLog,v
retrieving revision 1.43
retrieving revision 1.44
diff -u -r1.43 -r1.44
--- ChangeLog	17 May 2009 14:46:35 -0000	1.43
+++ ChangeLog	18 May 2009 18:18:30 -0000	1.44
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/qmpdclient
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/qmpdclient/ChangeLog,v 1.43 2009/05/17 14:46:35 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/qmpdclient/ChangeLog,v 1.44 2009/05/18 18:18:30 hwoarang Exp $
+
+*qmpdclient-1.1.0-r2 (18 May 2009)
+
+  18 May 2009; Markos Chandras <hwoarang@gentoo.org>
+  +qmpdclient-1.1.0-r2.ebuild:
+  Add dbus use flag. Fixes bug 270324
 
   17 May 2009; Raúl Porcel <armin76@gentoo.org> qmpdclient-1.1.0-r1.ebuild:
   sparc stable wrt #269408



1.1                  media-sound/qmpdclient/qmpdclient-1.1.0-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/qmpdclient/qmpdclient-1.1.0-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/qmpdclient/qmpdclient-1.1.0-r2.ebuild?rev=1.1&content-type=text/plain

Index: qmpdclient-1.1.0-r2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/qmpdclient/qmpdclient-1.1.0-r2.ebuild,v 1.1 2009/05/18 18:18:30 hwoarang Exp $

EAPI="2"

inherit qt4

MY_PN="${PN}-ne"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="QMPDClient with NBL additions, such as lyrics' display"
HOMEPAGE="http://bitcheese.net/wiki/QMPDClient"
SRC_URI="mirror://gentoo/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~sparc ~x86"
IUSE="debug dbus"

DEPEND="x11-libs/qt-gui:4[dbus=]"
RDEPEND="${DEPEND}"

LANGS="de_DE fr_FR it_IT nl_NL nn_NO no_NO ru_RU sv_SE tr_TR uk_UA"
LANGSLONG="zh_CN zh_TW pt_BR"

for X in ${LANGS}; do
	IUSE="${IUSE} linguas_${X%_*}"
done

for X in ${LANGSLONG};do
	IUSE="${IUSE} linguas_${X}"
done

S="${WORKDIR}/${MY_P}"

src_prepare() {
	# Fix the install path
	sed -i -e "s:PREFIX = /usr/local:PREFIX = /usr:" qmpdclient.pro \
		|| die "sed failed (install path)"

	# nostrip fix
	sed -i -e "s:CONFIG += :CONFIG += nostrip :" qmpdclient.pro \
		|| die "sed failed (nostrip)"

	sed -i -e "s:+= -O2 -g0 -s:+= -O2 -g0:" qmpdclient.pro \
		|| die "sed failed (nostrip)"

	# fix installation folder name
	sed -i "s/share\/QMPDClient/share\/qmpdclient/" src/config.cpp \
		|| die "failed to fix installation directory"
}

src_configure() {
	eqmake4 qmpdclient.pro
}

src_compile() {
	emake || die "emake failed"
	# generate translations
	emake translate || die "failed to generate translations"
}

src_install() {
	emake install INSTALL_ROOT="${D}" || die "emake install failed"
	dodoc README AUTHORS THANKSTO Changelog || die "Installing docs failed"
	for res in 16 22 64 ; do
		insinto /usr/share/icons/hicolor/${res}x${res}/apps/
		newins icons/qmpdclient${res}.png ${PN}.png || die "Installing icons failed"
	done

	make_desktop_entry qmpdclient "QMPDClient" ${PN} \
		"Qt;AudioVideo;Audio;" || die "Installing desktop entry failed"

	#install translations
	insinto /usr/share/${PN}/translations/
	local LANG=
	for LANG in ${LINGUAS};do
	    for X in ${LANGS};do
			if [[ ${LANG} == ${X%_*} ]];then
		    	doins -r lang/${X}.qm || die "failed to install translations"
			fi
	    done
		for X in ${LANGSLONG};do
			if [[ ${LANG} == ${X} ]]; then
				doins -r lang/${X}.qm || die "failed to install translations"
			fi
		done
	done
}