[gentoo-commits] gentoo-x86 commit in dev-java/jfreechart: ChangeLog jfreechart-1.0.13.ebuild

["Serkan Kaba (serkan)" <serkan@gentoo.org>]

serkan      09/05/11 20:48:54

  Modified:             ChangeLog
  Added:                jfreechart-1.0.13.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.47                 dev-java/jfreechart/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/jfreechart/ChangeLog?rev=1.47&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/jfreechart/ChangeLog?rev=1.47&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/jfreechart/ChangeLog?r1=1.46&r2=1.47

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/jfreechart/ChangeLog,v
retrieving revision 1.46
retrieving revision 1.47
diff -u -r1.46 -r1.47
--- ChangeLog	5 Oct 2008 17:47:25 -0000	1.46
+++ ChangeLog	11 May 2009 20:48:54 -0000	1.47
@@ -1,6 +1,12 @@
 # ChangeLog for dev-java/jfreechart
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/jfreechart/ChangeLog,v 1.46 2008/10/05 17:47:25 betelgeuse Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/jfreechart/ChangeLog,v 1.47 2009/05/11 20:48:54 serkan Exp $
+
+*jfreechart-1.0.13 (11 May 2009)
+
+  11 May 2009; Serkan Kaba <serkan@gentoo.org> +jfreechart-1.0.13.ebuild,
+  +files/jfreechart-1.0.13-build.xml.patch:
+  Version bump.
 
   05 Oct 2008; Petteri Räty <betelgeuse@gentoo.org>
   jfreechart-1.0.9-r1.ebuild, jfreechart-1.0.10.ebuild:



1.1                  dev-java/jfreechart/jfreechart-1.0.13.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/jfreechart/jfreechart-1.0.13.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/jfreechart/jfreechart-1.0.13.ebuild?rev=1.1&content-type=text/plain

Index: jfreechart-1.0.13.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/jfreechart/jfreechart-1.0.13.ebuild,v 1.1 2009/05/11 20:48:54 serkan Exp $

EAPI=2
JAVA_PKG_IUSE="doc source"

inherit java-pkg-2 java-ant-2

DESCRIPTION="JFreeChart is a free Java class library for generating charts"
HOMEPAGE="http://www.jfree.org/jfreechart"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="1.0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="test"
COMMON_DEPEND="
	>=dev-java/itext-1.4.6:0
	dev-java/jcommon:1.0
	java-virtuals/servlet-api:2.3"
DEPEND=">=virtual/jdk-1.4
	${COMMON_DEPEND}
	test? ( dev-java/ant-junit:0 )"
RDEPEND=">=virtual/jdk-1.4
	${COMMON_DEPEND}"

JAVA_PKG_FILTER_COMPILER="jikes"

src_prepare() {
	epatch "${FILESDIR}/${P}-build.xml.patch"

	rm -v *.jar lib/*.jar || die
}

src_compile() {
	# Note that compile-experimental depends on compile so it is sufficient to run
	# just compile-experimental
	eant -f ant/build.xml compile-experimental $(use_doc) $(get_jars)
}

src_test() {
	# X11 tests are disabled using java.awt.headless=true
	ANT_TASKS="ant-junit" \
	ANT_OPTS="-Djava.awt.headless=true -Duser.timezone=UTC" \
		eant -f ant/build.xml test $(get_jars)
}

src_install() {
	java-pkg_newjar lib/${P}.jar ${PN}.jar
	java-pkg_newjar lib/${P}-experimental.jar ${PN}-experimental.jar
	dodoc README.txt ChangeLog NEWS || die
	use doc && java-pkg_dojavadoc javadoc
	use source && java-pkg_dosrc source/org
}

get_jars() {
	local antflags="
		-Ditext.jar=$(java-pkg_getjar itext iText.jar) \
		-Djcommon.jar=$(java-pkg_getjar jcommon-1.0 jcommon.jar) \
		-Dservlet.jar=$(java-pkg_getjars servlet-api-2.3)"
	use test && antflags="${antflags} \
		-Djunit.jar=$(java-pkg_getjars --build-only junit)"
	echo "${antflags}"
}