[gentoo-commits] gentoo-x86 commit in games-strategy/wesnoth: ChangeLog wesnoth-1.6.2.ebuild

["Michael Sterrett (mr_bones_)" <mr_bones_@gentoo.org>]

mr_bones_    09/05/11 01:39:45

  Modified:             ChangeLog
  Added:                wesnoth-1.6.2.ebuild
  Log:
  version bump
  (Portage version: 2.1.6.11/cvs/Linux i686)

Revision  Changes    Path
1.144                games-strategy/wesnoth/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/wesnoth/ChangeLog?rev=1.144&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/wesnoth/ChangeLog?rev=1.144&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/wesnoth/ChangeLog?r1=1.143&r2=1.144

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/wesnoth/ChangeLog,v
retrieving revision 1.143
retrieving revision 1.144
diff -u -r1.143 -r1.144
--- ChangeLog	16 Apr 2009 06:23:39 -0000	1.143
+++ ChangeLog	11 May 2009 01:39:44 -0000	1.144
@@ -1,6 +1,12 @@
 # ChangeLog for games-strategy/wesnoth
 # Copyright 2000-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/wesnoth/ChangeLog,v 1.143 2009/04/16 06:23:39 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/wesnoth/ChangeLog,v 1.144 2009/05/11 01:39:44 mr_bones_ Exp $
+
+*wesnoth-1.6.2 (11 May 2009)
+
+  11 May 2009; Michael Sterrett <mr_bones_@gentoo.org>
+  +wesnoth-1.6.2.ebuild:
+  version bump
 
   16 Apr 2009; Michael Sterrett <mr_bones_@gentoo.org> wesnoth-1.6.1.ebuild:
   fix the desktop files install (bug #263666)



1.1                  games-strategy/wesnoth/wesnoth-1.6.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/wesnoth/wesnoth-1.6.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/wesnoth/wesnoth-1.6.2.ebuild?rev=1.1&content-type=text/plain

Index: wesnoth-1.6.2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/wesnoth/wesnoth-1.6.2.ebuild,v 1.1 2009/05/11 01:39:44 mr_bones_ Exp $

EAPI=2
inherit cmake-utils eutils toolchain-funcs flag-o-matic games

DESCRIPTION="Battle for Wesnoth - A fantasy turn-based strategy game"
HOMEPAGE="http://www.wesnoth.org/"
SRC_URI="mirror://sourceforge/wesnoth/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="dedicated nls server tinygui"

RDEPEND=">=media-libs/libsdl-1.2.7[X]
	media-libs/sdl-net
	>=media-libs/sdl-ttf-2.0.8
	>=media-libs/sdl-mixer-1.2[vorbis]
	>=media-libs/sdl-image-1.2[jpeg,png]
	dev-libs/boost
	sys-libs/zlib
	x11-libs/pango
	media-libs/fontconfig
	virtual/libintl"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	!dedicated? (
		tinygui? ( media-gfx/imagemagick[jpeg,png] )
	)
	nls? ( sys-devel/gettext )"

src_prepare() {
	if use dedicated || use server ; then
		sed \
			-e "s:GAMES_BINDIR:${GAMES_BINDIR}:" \
			-e "s:GAMES_STATEDIR:${GAMES_STATEDIR}:" \
			-e "s/GAMES_USER_DED/${GAMES_USER_DED}/" \
			-e "s/GAMES_GROUP/${GAMES_GROUP}/" "${FILESDIR}"/wesnothd.rc \
			> "${T}"/wesnothd \
			|| die "sed failed"
	fi
	# FIXME: remove this bit in the next version
	sed -i \
		-e '/Version/s/1/1.0/' \
		icons/*desktop \
		|| die "sed failed"
}

src_configure() {
	filter-flags -ftracer -fomit-frame-pointer
	if [[ $(gcc-major-version) -eq 3 ]] ; then
		filter-flags -fstack-protector
		append-flags -fno-stack-protector
	fi
	if use dedicated || use server ; then
		mycmakeargs="${mycmakeargs}
			-DENABLE_CAMPAIGN_SERVER=TRUE
			-DENABLE_SERVER=TRUE
			-DSERVER_UID=${GAMES_USER_DED}
			-DSERVER_GID=${GAMES_GROUP}
			-DFIFO_DIR=${GAMES_STATEDIR}/run/wesnothd"
	else
		mycmakeargs="${mycmakeargs}
			-DENABLE_CAMPAIGN_SERVER=FALSE
			-DENABLE_SERVER=FALSE"
	fi
	mycmakeargs="
		${mycmakeargs}
		$(cmake-utils_use_enable !dedicated GAME)
		$(cmake-utils_use_enable !dedicated ENABLE_DESKTOP_ENTRY)
		$(cmake-utils_use_enable nls NLS)
		-DGUI=$(use tinygui && echo tiny || echo normal)
		-DENABLE_FRIBIDI=FALSE
		-DCMAKE_INSTALL_PREFIX=${GAMES_PREFIX}
		-DPREFERENCES_DIR=.wesnoth
		-DDATAROOTDIR=${GAMES_DATADIR}
		-DBINDIR=${GAMES_BINDIR}
		-DICONDIR=/usr/share/pixmaps
		-DDESKTOPDIR=/usr/share/applications
		-DMANDIR=/usr/share/man
		-DDOCDIR=/usr/share/doc/${PF}"
	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
}

src_install() {
	DOCS="README changelog players_changelog" cmake-utils_src_install
	if use dedicated || use server; then
		keepdir "${GAMES_STATEDIR}/run/wesnothd"
		doinitd "${T}"/wesnothd || die "doinitd failed"
	fi
	prepgamesdirs
}