* [gentoo-commits] gentoo-x86 commit in media-video/jubler: jubler-4.1.ebuild ChangeLog jubler-3.9.6.ebuild
@ 2009-05-06 18:06 Serkan Kaba (serkan)
0 siblings, 0 replies; only message in thread
From: Serkan Kaba (serkan) @ 2009-05-06 18:06 UTC (permalink / raw
To: gentoo-commits
serkan 09/05/06 18:06:21
Modified: ChangeLog
Added: jubler-4.1.ebuild
Removed: jubler-3.9.6.ebuild
Log:
Version bump. Uses patched tarball created from upstream scm. Clean old.
(Portage version: 2.2_rc33/cvs/Linux x86_64)
Revision Changes Path
1.31 media-video/jubler/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/jubler/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/jubler/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/jubler/ChangeLog?r1=1.30&r2=1.31
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/jubler/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog 4 Apr 2009 15:20:19 -0000 1.30
+++ ChangeLog 6 May 2009 18:06:21 -0000 1.31
@@ -1,6 +1,12 @@
# ChangeLog for media-video/jubler
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/jubler/ChangeLog,v 1.30 2009/04/04 15:20:19 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/jubler/ChangeLog,v 1.31 2009/05/06 18:06:21 serkan Exp $
+
+*jubler-4.1 (06 May 2009)
+
+ 06 May 2009; Serkan Kaba <serkan@gentoo.org> -jubler-3.9.6.ebuild,
+ +jubler-4.1.ebuild:
+ Version bump. Uses patched tarball created from upstream scm. Clean old.
04 Apr 2009; Markus Meier <maekke@gentoo.org> jubler-4.0.ebuild:
amd64/x86 stable, bug #263071
1.1 media-video/jubler/jubler-4.1.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/jubler/jubler-4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/jubler/jubler-4.1.ebuild?rev=1.1&content-type=text/plain
Index: jubler-4.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/jubler/jubler-4.1.ebuild,v 1.1 2009/05/06 18:06:21 serkan Exp $
EAPI="2"
inherit gnome2-utils eutils java-pkg-2 java-ant-2 toolchain-funcs
MY_PN=${PN/#j/J}
DESCRIPTION="Java subtitle editor"
HOMEPAGE="http://www.jubler.org/"
SRC_URI="mirror://gentoo/${MY_PN}-src-${PV}.tar.bz2"
# This is a patched tarball generated from Mercurial.
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="mplayer nls spell"
RDEPEND=">=virtual/jre-1.5
>=media-video/ffmpeg-0.4.9_p20080326
mplayer? ( media-video/mplayer[ass] )
spell?
(
app-text/aspell
>=dev-java/zemberek-2.0[linguas_tr]
)
dev-java/jupidator"
DEPEND=">=virtual/jdk-1.5
>=media-video/ffmpeg-0.4.9_p20080326
app-text/docbook-sgml-utils
dev-util/pkgconfig
nls? ( sys-devel/gettext )
dev-java/jupidator"
S=${WORKDIR}/${MY_PN}-${PV}
java_prepare() {
chmod +x resources/installers/linux/iconinstall
JAVA_ANT_CLASSPATH_TAGS="java javac" java-ant_rewrite-classpath
java-ant_rewrite-classpath nbproject/build-impl.xml
}
src_compile() {
java-pkg_filter-compiler ecj-3.2
eant -Dgentoo.classpath="$(java-pkg_getjars jupidator)" distbased $(use nls && echo i18n) jar faq changelog || die "eant failed"
cp -v dist/help/jubler-faq.html build/classes/help || die "cp failed"
cd resources/ffdecode || die
CC=$(tc-getCC) NOSTRIP=true emake linuxdyn || die "make failed"
}
src_install() {
java-pkg_dojar dist/Jubler.jar
use spell && java-pkg_register-dependency zemberek zemberek2-cekirdek.jar
use spell && java-pkg_register-dependency zemberek zemberek2-tr.jar
java-pkg_doso resources/ffdecode/libffdecode.so
doicon resources/installers/linux/jubler.png
domenu resources/installers/linux/jubler.desktop
DESTDIR="${D}" eant linuxdesktopintegration
rm -vr "${D}/usr/share/menu" || die
java-pkg_dolauncher jubler --main com.panayotis.jubler.Main
dohtml ChangeLog.html || die "dohtml failed"
dodoc README || die "dodoc failed"
doman resources/installers/linux/jubler.1 || die "doman fialed"
insinto /usr/share/jubler/help
doins dist/help/* || die "doins failed"
}
pkg_preinst() {
gnome2_pkg_preinst
java-pkg-2_pkg_preinst
}
pkg_postinst() {
gnome2_icon_cache_update
}
pkg_postrm() {
gnome2_icon_cache_update
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2009-05-06 18:06 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2009-05-06 18:06 [gentoo-commits] gentoo-x86 commit in media-video/jubler: jubler-4.1.ebuild ChangeLog jubler-3.9.6.ebuild Serkan Kaba (serkan)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox