[gentoo-commits] gentoo-x86 commit in sys-fs/ecryptfs-utils: ChangeLog ecryptfs-utils-75.ebuild

[gentoo-commits] gentoo-x86 commit in sys-fs/ecryptfs-utils: ChangeLog ecryptfs-utils-75.ebuild

[Arfrever Frehtes Taifersar Arahesis (arfrever)]

arfrever    09/05/02 18:30:04

  Modified:             ChangeLog
  Added:                ecryptfs-utils-75.ebuild
  Log:
  Version bump.
  (Portage version: 13595-svn/cvs/Linux x86_64)

Revision  Changes    Path
1.24                 sys-fs/ecryptfs-utils/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/ecryptfs-utils/ChangeLog?rev=1.24&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/ecryptfs-utils/ChangeLog?rev=1.24&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/ecryptfs-utils/ChangeLog?r1=1.23&r2=1.24

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-fs/ecryptfs-utils/ChangeLog,v
retrieving revision 1.23
retrieving revision 1.24
diff -u -r1.23 -r1.24
--- ChangeLog	29 Mar 2009 17:08:28 -0000	1.23
+++ ChangeLog	2 May 2009 18:30:04 -0000	1.24
@@ -1,6 +1,12 @@
 # ChangeLog for sys-fs/ecryptfs-utils
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-fs/ecryptfs-utils/ChangeLog,v 1.23 2009/03/29 17:08:28 arfrever Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-fs/ecryptfs-utils/ChangeLog,v 1.24 2009/05/02 18:30:04 arfrever Exp $
+
+*ecryptfs-utils-75 (02 May 2009)
+
+  02 May 2009; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
+  +ecryptfs-utils-75.ebuild, +files/ecryptfs-utils-75-fix_warnings.patch:
+  Version bump.
 
 *ecryptfs-utils-73 (29 Mar 2009)
 



1.1                  sys-fs/ecryptfs-utils/ecryptfs-utils-75.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/ecryptfs-utils/ecryptfs-utils-75.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-fs/ecryptfs-utils/ecryptfs-utils-75.ebuild?rev=1.1&content-type=text/plain

Index: ecryptfs-utils-75.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-fs/ecryptfs-utils/ecryptfs-utils-75.ebuild,v 1.1 2009/05/02 18:30:04 arfrever Exp $

EAPI="2"

inherit eutils pam

DESCRIPTION="eCryptfs userspace utilities"
HOMEPAGE="http://launchpad.net/ecryptfs"
SRC_URI="http://launchpad.net/ecryptfs/trunk/${PV}/+download/${PN}_${PV}.orig.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc gpg gtk nss openssl pam pkcs11 python suid tpm"

RDEPEND=">=sys-apps/keyutils-1.0
	>=dev-libs/libgcrypt-1.2.0
	gpg? ( app-crypt/gpgme )
	gtk? ( x11-libs/gtk+ )
	nss? ( dev-libs/nss )
	openssl? ( >=dev-libs/openssl-0.9.7 )
	pam? ( sys-libs/pam )
	pkcs11? (
		>=dev-libs/openssl-0.9.7
		>=dev-libs/pkcs11-helper-1.04
	)
	python? ( >=dev-lang/python-2.5 )
	tpm? ( app-crypt/trousers )"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.9.0
	python? ( dev-lang/swig )"

src_prepare() {
	epatch "${FILESDIR}/${P}-fix_warnings.patch"
}

src_configure() {
	econf \
		--docdir="/usr/share/doc/${PF}" \
		--with-pamdir=$(getpam_mod_dir) \
		$(use_enable doc docs) \
		$(use_enable gpg) \
		$(use_enable gtk gui) \
		$(use_enable nss) \
		$(use_enable openssl) \
		$(use_enable pam) \
		$(use_enable pkcs11 pkcs11-helper) \
		$(use_enable python pywrap) \
		$(use_enable tpm tspi)
}

src_install(){
	emake DESTDIR="${D}" install || die "emake install failed"
	use suid && fperms u+s /sbin/mount.ecryptfs
}

pkg_postinst() {
	if use suid; then
		ewarn
		ewarn "You have chosen to install ${PN} with the binary setuid root. This"
		ewarn "means that if there are any undetected vulnerabilities in the binary,"
		ewarn "then local users may be able to gain root access on your machine."
		ewarn
	fi
}