* [gentoo-commits] gentoo-x86 commit in x11-wm/compiz: ChangeLog compiz-0.8.2-r1.ebuild
@ 2009-04-26 11:46 Jorge Manuel B. S. Vicetto (jmbsvicetto)
0 siblings, 0 replies; 2+ messages in thread
From: Jorge Manuel B. S. Vicetto (jmbsvicetto) @ 2009-04-26 11:46 UTC (permalink / raw
To: gentoo-commits
jmbsvicetto 09/04/26 11:46:25
Modified: ChangeLog
Added: compiz-0.8.2-r1.ebuild
Log:
Added fix for tests. Thanks to Pacho Ramos <pacho@condmat1.ciencias.uniovi.es> for initial report and Brent Baude <ranger@gentoo.org> for recalling me about it again - fixes bug 265226.
Added gtk/gnome/compiz-wm.desktop.in and metadata/core.xml.in files to po/POTFILES.skip.
Install compiz.desktop file. Thanks to Philip Allison <sane@not.co.uk> for the file and Nirbheek Chauhan <nirbheek@gentoo.org> for the check from the gnome team - fixes bug 254166.
(Portage version: 2.2_rc31/cvs/Linux x86_64)
Revision Changes Path
1.41 x11-wm/compiz/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/ChangeLog?rev=1.41&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/ChangeLog?rev=1.41&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/ChangeLog?r1=1.40&r2=1.41
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/compiz/ChangeLog,v
retrieving revision 1.40
retrieving revision 1.41
diff -u -r1.40 -r1.41
--- ChangeLog 25 Apr 2009 16:06:37 -0000 1.40
+++ ChangeLog 26 Apr 2009 11:46:25 -0000 1.41
@@ -1,6 +1,17 @@
# ChangeLog for x11-wm/compiz
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/compiz/ChangeLog,v 1.40 2009/04/25 16:06:37 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/compiz/ChangeLog,v 1.41 2009/04/26 11:46:25 jmbsvicetto Exp $
+
+*compiz-0.8.2-r1 (26 Apr 2009)
+
+ 26 Apr 2009; Jorge Manuel B. S. Vicetto <jmbsvicetto@gentoo.org>
+ +files/compiz.desktop, +compiz-0.8.2-r1.ebuild:
+ Added fix for tests. Thanks to Pacho Ramos
+ <pacho@condmat1.ciencias.uniovi.es> for initial report and Brent Baude
+ <ranger@gentoo.org> for recalling me about it again - fixes bug 265226.
+ Install compiz.desktop file. Thanks to Philip Allison <sane@not.co.uk> for
+ the file and Nirbheek Chauhan <nirbheek@gentoo.org> for the check from the
+ gnome team - fixes bug 254166.
25 Apr 2009; Brent Baude <ranger@gentoo.org> compiz-0.8.2.ebuild:
Marking compiz-0.8.2 ~ppc for bug 246804
1.1 x11-wm/compiz/compiz-0.8.2-r1.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/compiz-0.8.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/compiz-0.8.2-r1.ebuild?rev=1.1&content-type=text/plain
Index: compiz-0.8.2-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-wm/compiz/compiz-0.8.2-r1.ebuild,v 1.1 2009/04/26 11:46:25 jmbsvicetto Exp $
EAPI="2"
inherit autotools eutils gnome2-utils multilib
DESCRIPTION="3D composite and windowmanager"
HOMEPAGE="http://www.compiz.org/"
SRC_URI="http://releases.compiz.org/${PV}/${P}.tar.gz"
LICENSE="GPL-2 LGPL-2.1 MIT"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="+cairo dbus fuse gnome gtk kde kde4 +svg"
DEPEND="
dev-libs/glib:2
dev-libs/libxml2
dev-libs/libxslt
>=media-libs/glitz-0.5.6
media-libs/libpng
>=media-libs/mesa-6.5.1-r1
>=x11-base/xorg-server-1.1.1-r1
x11-libs/libX11[xcb]
x11-libs/libxcb
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXinerama
x11-libs/libXrandr
x11-libs/libICE
x11-libs/libSM
>=x11-libs/libXrender-0.8.4
>=x11-libs/startup-notification-0.7
cairo? (
x11-libs/cairo[X]
)
dbus? ( >=sys-apps/dbus-1.0 )
fuse? ( sys-fs/fuse )
gnome? (
>=gnome-base/gnome-control-center-2.16.1:2
gnome-base/gnome-desktop
gnome-base/gconf:2
)
gtk? (
>=x11-libs/gtk+-2.8.0:2
>=x11-libs/libwnck-2.18.3
x11-libs/pango
)
kde? (
|| ( kde-base/kwin:3.5
kde-base/kdebase:3.5
)
dev-libs/dbus-qt3-old
)
kde4? (
|| (
kde-base/kwin:4.2
kde-base/kwin:live
)
)
svg? (
>=gnome-base/librsvg-2.14.0:2
>=x11-libs/cairo-1.0
)
"
RDEPEND="${DEPEND}
x11-apps/mesa-progs
x11-apps/xvinfo"
DEPEND="${DEPEND}
dev-util/pkgconfig
x11-proto/damageproto
x11-proto/xineramaproto"
src_prepare() {
echo "gtk/gnome/compiz-wm.desktop.in" >> "${S}/po/POTFILES.skip"
echo "metadata/core.xml.in" >> "${S}/po/POTFILES.skip"
use gnome || {
epatch "${FILESDIR}"/${PN}-no-gconf.patch
ln -s /usr/share/aclocal/gconf-2.m4 acinclude.m4
# required to apply the above patch
intltoolize --copy --force || die "intltoolize failed"
eautoreconf || die "eautoreconf failed"
}
}
src_configure() {
econf \
--disable-gnome-keybindings \
--enable-librsvg \
--with-default-plugins \
$(use_enable cairo annotate) \
$(use_enable dbus) \
$(use_enable dbus dbus-glib) \
$(use_enable fuse) \
$(use_enable gnome) \
$(use_enable gnome gconf) \
$(use_enable gnome metacity) \
$(use_enable gtk) \
$(use_enable kde) \
$(use_enable kde4) \
|| die "econf failed"
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
# Install compiz-manager
dobin "${FILESDIR}/compiz-manager" || die "dobin failed"
# Add the full-path to lspci
sed -i "s#lspci#/usr/sbin/lspci#" "${D}/usr/bin/compiz-manager"
# Fix the hardcoded lib paths
sed -i "s#/lib/#/$(get_libdir)/#g" "${D}/usr/bin/compiz-manager"
# Create gentoo's config file
dodir /etc/xdg/compiz
cat <<- EOF > "${D}/etc/xdg/compiz/compiz-manager"
COMPIZ_BIN_PATH="/usr/bin/"
PLUGIN_PATH="/usr/$(get_libdir)/compiz/"
LIBGL_NVIDIA="/usr/$(get_libdir)/opengl/xorg-x11/libGL.so.1.2"
LIBGL_FGLRX="/usr/$(get_libdir)/opengl/xorg-x11/libGL.so.1.2"
KWIN="$(type -p kwin)"
METACITY="$(type -p metacity)"
SKIP_CHECKS="yes"
EOF
dodoc AUTHORS ChangeLog NEWS README TODO || die "dodoc failed"
insinto "/usr/share/applications"
doins "${FILESDIR}/compiz.desktop" || die "Failed to install compiz.desktop"
}
pkg_postinst() {
use gnome && gnome2_gconf_install
ewarn "If you update to x11-wm/metacity-2.24 after you install ${P},"
ewarn "gtk-window-decorator will crash until you reinstall ${PN} again."
}
pkg_prerm() {
use gnome && gnome2_gconf_uninstall
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in x11-wm/compiz: ChangeLog compiz-0.8.2-r1.ebuild
@ 2009-04-26 13:59 Jorge Manuel B. S. Vicetto (jmbsvicetto)
0 siblings, 0 replies; 2+ messages in thread
From: Jorge Manuel B. S. Vicetto (jmbsvicetto) @ 2009-04-26 13:59 UTC (permalink / raw
To: gentoo-commits
jmbsvicetto 09/04/26 13:59:27
Modified: ChangeLog compiz-0.8.2-r1.ebuild
Log:
Added missing call to gnome2_gconf_savelist. Thanks to Pacho Ramos <pacho@condmat1.ciencias.uniovi.es> - fixes bug 258238.
(Portage version: 2.2_rc31/cvs/Linux x86_64)
Revision Changes Path
1.42 x11-wm/compiz/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/ChangeLog?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/ChangeLog?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/ChangeLog?r1=1.41&r2=1.42
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/compiz/ChangeLog,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- ChangeLog 26 Apr 2009 11:46:25 -0000 1.41
+++ ChangeLog 26 Apr 2009 13:59:27 -0000 1.42
@@ -1,6 +1,11 @@
# ChangeLog for x11-wm/compiz
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/compiz/ChangeLog,v 1.41 2009/04/26 11:46:25 jmbsvicetto Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/compiz/ChangeLog,v 1.42 2009/04/26 13:59:27 jmbsvicetto Exp $
+
+ 26 Apr 2009; Jorge Manuel B. S. Vicetto <jmbsvicetto@gentoo.org>
+ compiz-0.8.2-r1:
+ Added missing call to gnome2_gconf_savelist. Thanks to Pacho Ramos
+ <pacho@condmat1.ciencias.uniovi.es> - fixes bug 258238.
*compiz-0.8.2-r1 (26 Apr 2009)
1.2 x11-wm/compiz/compiz-0.8.2-r1.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/compiz-0.8.2-r1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/compiz-0.8.2-r1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-wm/compiz/compiz-0.8.2-r1.ebuild?r1=1.1&r2=1.2
Index: compiz-0.8.2-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-wm/compiz/compiz-0.8.2-r1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- compiz-0.8.2-r1.ebuild 26 Apr 2009 11:46:25 -0000 1.1
+++ compiz-0.8.2-r1.ebuild 26 Apr 2009 13:59:27 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-wm/compiz/compiz-0.8.2-r1.ebuild,v 1.1 2009/04/26 11:46:25 jmbsvicetto Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-wm/compiz/compiz-0.8.2-r1.ebuild,v 1.2 2009/04/26 13:59:27 jmbsvicetto Exp $
EAPI="2"
@@ -139,6 +139,10 @@
doins "${FILESDIR}/compiz.desktop" || die "Failed to install compiz.desktop"
}
+pkg_preinst() {
+ use gnome && gnome2_gconf_savelist
+}
+
pkg_postinst() {
use gnome && gnome2_gconf_install
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2009-04-26 13:59 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2009-04-26 13:59 [gentoo-commits] gentoo-x86 commit in x11-wm/compiz: ChangeLog compiz-0.8.2-r1.ebuild Jorge Manuel B. S. Vicetto (jmbsvicetto)
-- strict thread matches above, loose matches on Subject: below --
2009-04-26 11:46 Jorge Manuel B. S. Vicetto (jmbsvicetto)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox