[gentoo-commits] gentoo-x86 commit in media-libs/mediastreamer: metadata.xml ChangeLog mediastreamer-2.2.3.ebuild

[gentoo-commits] gentoo-x86 commit in media-libs/mediastreamer: metadata.xml ChangeLog mediastreamer-2.2.3.ebuild

[Mounir Lamouri (volkmar)]

volkmar     09/04/25 00:29:08

  Added:                metadata.xml ChangeLog mediastreamer-2.2.3.ebuild
  Log:
  new born via a version bump for this package removed from the tree a few months ago
  (Portage version: 2.1.6.7/cvs/Linux ppc)

Revision  Changes    Path
1.4                  media-libs/mediastreamer/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/mediastreamer/metadata.xml?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/mediastreamer/metadata.xml?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/mediastreamer/metadata.xml?r1=1.3&r2=1.4




1.6                  media-libs/mediastreamer/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/mediastreamer/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/mediastreamer/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/mediastreamer/ChangeLog?r1=1.5&r2=1.6




1.1                  media-libs/mediastreamer/mediastreamer-2.2.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/mediastreamer/mediastreamer-2.2.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/mediastreamer/mediastreamer-2.2.3.ebuild?rev=1.1&content-type=text/plain

Index: mediastreamer-2.2.3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/mediastreamer/mediastreamer-2.2.3.ebuild,v 1.1 2009/04/25 00:29:08 volkmar Exp $

EAPI="2"

inherit eutils autotools multilib

DESCRIPTION="Mediastreaming library for telephony application"
HOMEPAGE="http://www.linphone.org/index.php/eng/code_review/mediastreamer2"
SRC_URI="http://download.savannah.nongnu.org/releases/linphone/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~ppc"
IUSE="alsa arts debug doc examples gsm ipv6 jack oss portaudio speex theora
video X"

RDEPEND=">=net-libs/ortp-0.15.0
	alsa? ( media-libs/alsa-lib )
	arts? ( kde-base/arts )
	gsm? ( media-sound/gsm )
	jack? ( media-libs/libsamplerate
		media-sound/jack-audio-connection-kit )
	portaudio? ( media-libs/portaudio )
	speex? ( >=media-libs/speex-1.1.12 )
	video? ( media-libs/libsdl[video,X]
		media-video/ffmpeg
		theora? ( media-libs/libtheora )
		X? ( x11-libs/libX11 ) )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( app-doc/doxygen )"

# TODO:
# run-time test for arts support
# run-time test for ipv6 : does it need ortp[ipv6] ?

# NOTES:
# in some way, v4l support is auto-magic but keeping it like that atm

pkg_setup() {
	if ! use oss && ! use alsa && ! use arts && ! use jack && ! use portaudio;
	then
		eerror "You must enable at least oss, alsa, arts, jack or portaudio"
		eerror "Please, re-emerge ${PN} with one of this USE flag enabled"
		die
	fi

	if ! use video && ( use theora || use X ); then
		ewarn "X and theora support are enabled if video USE flag is enabled"
		ewarn "If you want X or theora support, consider re-emerge with USE=\"video\""
	fi
}

src_prepare() {
	# fixing oss, jack, gsm, speex, theora and X auto-magic deps
	epatch "${FILESDIR}"/${P}-autodeps.patch

	# fix arts detection for gentoo
	epatch "${FILESDIR}"/${P}-arts.patch

	# too hard to have a flexible lib dir in a clean way
	sed -i -e "s:\(/usr/kde/3.5/\)lib:\1$(get_libdir):" configure.ac \
		|| die "patching configure.ac failed"

	# respect user's CFLAGS
	sed -i -e "s:-O2::" configure.ac || die "patching configure.ac failed"

	# change default paths
	sed -i -e "s:\(\${prefix}/\)lib:\1$(get_libdir):" \
		-e "s:\(prefix/share\):\1/${PN}:" configure.ac \
		|| die "patching configure.ac failed"

	eautoreconf

	# fix arts include
	sed -i -e "s:kde/\(artsc/artsc.h\):\1:" src/arts.c \
		|| die "patching src/arts.c failed"

	# don't build examples in tests/
	sed -i -e "s:\(SUBDIRS = .*\) tests \(.*\):\1 \2:" Makefile.in \
		|| die "patching Makefile.in failed"
}

src_configure() {
	# strict: don't want -Werror
	# macsnd and macaqsnd: macosx related
	# external-ortp: don't use bundled libs
	econf \
		--datadir=/usr/share/${PN} \
		--libdir=/usr/$(get_libdir) \
		--disable-strict \
		--disable-macsnd \
		--disable-macaqsnd \
		--enable-external-ortp \
		--disable-dependency-tracking \
		$(use_enable alsa) \
		$(use_enable arts artsc) \
		$(use_enable debug) \
		$(use_enable gsm) \
		$(use_enable ipv6) \
		$(use_enable jack) \
		$(use_enable oss) \
		$(use_enable portaudio) \
		$(use_enable speex) \
		$(use_enable theora) \
		$(use_enable video) \
		$(use_enable X x11)
}

src_compile() {
	default_src_compile

	if use doc; then
		doxygen help/DoxyFile || die "building doc failed"
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS ChangeLog NEWS README || die "dodoc failed"

	if use doc; then
		dohtml -r help/doc/html/* || die "dohtml failed"
		newman help/doc/man/man3/${PN}2.3 ${PN}.3 || die "newman failed"
	fi

	if use examples; then
		insinto /usr/share/doc/${PF}/examples
		doins tests/*.c || die "doins failed"
	fi
}