[gentoo-commits] gentoo-x86 commit in net-news/liferea: ChangeLog liferea-1.4.28.ebuild

[gentoo-commits] gentoo-x86 commit in net-news/liferea: ChangeLog liferea-1.4.28.ebuild

[Daniel Gryniewicz (dang)]

dang        09/04/16 18:08:13

  Modified:             ChangeLog
  Added:                liferea-1.4.28.ebuild
  Log:
  Bump to liferea-1.4.28
  (Portage version: 2.2_rc30/cvs/Linux x86_64)

Revision  Changes    Path
1.170                net-news/liferea/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-news/liferea/ChangeLog?rev=1.170&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-news/liferea/ChangeLog?rev=1.170&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-news/liferea/ChangeLog?r1=1.169&r2=1.170

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-news/liferea/ChangeLog,v
retrieving revision 1.169
retrieving revision 1.170
diff -u -r1.169 -r1.170
--- ChangeLog	16 Feb 2009 17:12:40 -0000	1.169
+++ ChangeLog	16 Apr 2009 18:08:13 -0000	1.170
@@ -1,6 +1,11 @@
 # ChangeLog for net-news/liferea
 # Copyright 2000-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/ChangeLog,v 1.169 2009/02/16 17:12:40 dang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/ChangeLog,v 1.170 2009/04/16 18:08:13 dang Exp $
+
+*liferea-1.4.28 (16 Apr 2009)
+
+  16 Apr 2009; Daniel Gryniewicz <dang@gentoo.org> +liferea-1.4.28.ebuild:
+  Bump to liferea-1.4.28
 
   16 Feb 2009; Daniel Gryniewicz <dang@gentoo.org> liferea-1.4.24.ebuild:
   Back out gnome use requirement for xulrunner. It seems to not matter. Bug



1.1                  net-news/liferea/liferea-1.4.28.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-news/liferea/liferea-1.4.28.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-news/liferea/liferea-1.4.28.ebuild?rev=1.1&content-type=text/plain

Index: liferea-1.4.28.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-news/liferea/liferea-1.4.28.ebuild,v 1.1 2009/04/16 18:08:13 dang Exp $

WANT_AUTOMAKE=1.9
inherit gnome2 eutils autotools

DESCRIPTION="News Aggregator for RDF/RSS/CDF/Atom/Echo/etc feeds"
HOMEPAGE="http://liferea.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="GPL-2"

EAPI="1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="dbus gtkhtml +gnutls libnotify lua networkmanager webkit +xulrunner"

RDEPEND="
	libnotify? ( >=x11-libs/libnotify-0.3.2 )
	lua? ( >=dev-lang/lua-5.1 )
	xulrunner? ( net-libs/xulrunner:1.9 )
	!xulrunner? ( webkit? ( net-libs/webkit-gtk ) )
	!amd64? ( !xulrunner? ( !webkit? ( gtkhtml? ( gnome-extra/gtkhtml:2 ) ) ) )
	>=x11-libs/gtk+-2.8
	x11-libs/pango
	>=gnome-base/gconf-2
	>=dev-libs/libxml2-2.6.27
	>=dev-libs/libxslt-1.1.19
	>=dev-db/sqlite-3.3
	>=dev-libs/glib-2
	>=gnome-base/libglade-2
	dbus? ( >=dev-libs/dbus-glib-0.71 )
	networkmanager? ( net-misc/networkmanager )
	gnutls? ( net-libs/gnutls )"

DEPEND="${RDEPEND}
	dev-util/pkgconfig
	>=dev-util/intltool-0.35"

DOCS="AUTHORS ChangeLog NEWS README"

pkg_setup() {
	# Backends are now mutually exclusive.
	# we prefer xulrunner over webkit over seamonkey over gtkhtml
	if use xulrunner ; then
		G2CONF="${G2CONF} --with-gecko=libxul"
		G2CONF="${G2CONF} --disable-webkit"
		G2CONF="${G2CONF} --disable-gtkhtml2"
	elif use webkit ; then
		G2CONF="${G2CONF} --enable-webkit"
		G2CONF="${G2CONF} --without-gecko"
		G2CONF="${G2CONF} --disable-gtkhtml2"
	elif use gtkhtml ; then
		if ! use amd64 ; then
			G2CONF="${G2CONF} --enable-gtkhtml2"
			G2CONF="${G2CONF} --without-gecko"
			G2CONF="${G2CONF} --disable-webkit"
		else
			elog ""
			elog "gtkhtml is no longer supported on amd64; you will need to "
			elog "select either xulrunner or webkit to use liferea."
			elog "Preference is: xulrunner, then webkit."
			die "You must enable xulrunner or webkit on amd64"
		fi
	else
		elog ""
		elog "You must choose one backend for liferea to work.  Preference is:"
		elog "xulrunner, webkit, then gtkhtml."
		die "You must enable on of the backends"
	fi

	G2CONF="${G2CONF}
		$(use_enable dbus)
		$(use_enable gnutls)
		$(use_enable libnotify)
		$(use_enable lua)
		$(use_enable networkmanager nm)"
}

src_install() {
	gnome2_src_install
	rm -f "${D}/usr/bin/${PN}"
	mv "${D}/usr/bin/${PN}-bin" "${D}/usr/bin/${PN}"
}