* [gentoo-commits] gentoo-x86 commit in dev-lang/mono: ChangeLog mono-2.4.ebuild
@ 2009-03-30 21:48 Peter Alfredsen (loki_val)
0 siblings, 0 replies; 3+ messages in thread
From: Peter Alfredsen (loki_val) @ 2009-03-30 21:48 UTC (permalink / raw
To: gentoo-commits
loki_val 09/03/30 21:48:20
Modified: ChangeLog
Added: mono-2.4.ebuild
Log:
Bump to mono-2.4 version.
(Portage version: 2.2_rc28/cvs/Linux x86_64)
Revision Changes Path
1.158 dev-lang/mono/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/ChangeLog?rev=1.158&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/ChangeLog?rev=1.158&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/ChangeLog?r1=1.157&r2=1.158
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/mono/ChangeLog,v
retrieving revision 1.157
retrieving revision 1.158
diff -u -r1.157 -r1.158
--- ChangeLog 28 Mar 2009 00:53:50 -0000 1.157
+++ ChangeLog 30 Mar 2009 21:48:20 -0000 1.158
@@ -1,6 +1,11 @@
# ChangeLog for dev-lang/mono
# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/mono/ChangeLog,v 1.157 2009/03/28 00:53:50 loki_val Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/mono/ChangeLog,v 1.158 2009/03/30 21:48:20 loki_val Exp $
+
+*mono-2.4 (30 Mar 2009)
+
+ 30 Mar 2009; Peter Alfredsen <loki_val@gentoo.org> +mono-2.4.ebuild:
+ Bump to mono-2.4 version.
28 Mar 2009; Peter Alfredsen <loki_val@gentoo.org>
+files/mono-2.2-freebsd-elf_common.patch, mono-2.2-r4.ebuild:
1.1 dev-lang/mono/mono-2.4.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/mono-2.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/mono-2.4.ebuild?rev=1.1&content-type=text/plain
Index: mono-2.4.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/mono/mono-2.4.ebuild,v 1.1 2009/03/30 21:48:20 loki_val Exp $
EAPI=2
inherit mono eutils flag-o-matic multilib go-mono
DESCRIPTION="Mono runtime and class libraries, a C# compiler/interpreter"
HOMEPAGE="http://www.go-mono.com"
LICENSE="MIT LGPL-2.1 GPL-2 BSD-4 NPL-1.1 Ms-PL GPL-2-with-linking-exception IDPL"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="xen moonlight minimal"
#Bash requirement is for += operator
COMMONDEPEND="!<dev-dotnet/pnet-0.6.12
!dev-util/monodoc
dev-libs/glib:2
!minimal? ( =dev-dotnet/libgdiplus-${GO_MONO_REL_PV}* )
ia64? (
sys-libs/libunwind
)"
RDEPEND="${COMMONDEPEND}
|| ( www-client/links www-client/lynx )"
DEPEND="${COMMONDEPEND}
sys-devel/bc
>=app-shells/bash-3.2"
PDEPEND="dev-dotnet/pe-format"
MAKEOPTS="${MAKEOPTS} -j1"
RESTRICT="test"
PATCHES=(
"${WORKDIR}/mono-2.2-libdir126.patch"
"${FILESDIR}/mono-2.2-ppc-threading.patch"
"${FILESDIR}/mono-2.2-uselibdir.patch"
)
pkg_setup() {
MONO_NUNIT_DIR="/usr/$(get_libdir)/mono/mono-nunit"
NUNIT_DIR="/usr/$(get_libdir)/mono/nunit"
}
src_prepare() {
sed -e "s:@MONOLIBDIR@:$(get_libdir):" \
< "${FILESDIR}"/mono-2.2-libdir126.patch \
> "${WORKDIR}"/mono-2.2-libdir126.patch ||
die "Sedding patch file failed"
go-mono_src_prepare
}
src_configure() {
# mono's build system is finiky, strip the flags
strip-flags
#Remove this at your own peril. Mono will barf in unexpected ways.
append-flags -fno-strict-aliasing
#NOTE: We need the static libs for now so mono-debugger works.
#See http://bugs.gentoo.org/show_bug.cgi?id=256264 for details
go-mono_src_configure \
--enable-static \
--disable-quiet-build \
--with-preview \
--with-glib=system \
$(use_with moonlight) \
--with-libgdiplus=$(use minimal && printf "no" || printf "installed" ) \
$(use_with xen xen_opt) \
--without-ikvm-native \
--with-jit \
--disable-dtrace
}
src_test() {
vecho ">>> Test phase [check]: ${CATEGORY}/${PF}"
export MONO_REGISTRY_PATH="${T}/registry"
export XDG_DATA_HOME="${T}/data"
export MONO_SHARED_DIR="${T}/shared"
export XDG_CONFIG_HOME="${T}/config"
export HOME="${T}/home"
emake -j1 check
}
src_install() {
go-mono_src_install
#Bug 255610
sed -i -e "s:mono/2.0/mod.exe:mono/1.0/mod.exe:" \
"${D}"/usr/bin/mod || die "Failed to fix mod."
find "${D}"/usr/ -name '*nunit-docs*' -exec rm -rf '{}' '+' || die "Removing nunit .docs failed"
#Standardize install paths for eselect-nunit
dodir ${MONO_NUNIT_DIR}
rm -f "${D}"/usr/bin/nunit-console*
for file in "${D}"/usr/$(get_libdir)/mono/1.0/nunit*.dll "${D}"/usr/$(get_libdir)/mono/1.0/nunit*.exe
do
dosym ../1.0/${file##*/} ${MONO_NUNIT_DIR}/${file##*/}
done
make_wrapper "nunit-console" "mono ${MONO_NUNIT_DIR}/nunit-console.exe" "" "" "${MONO_NUNIT_DIR}"
dosym nunit-console "${MONO_NUNIT_DIR}"/nunit-console2
}
#THINK!!!! Before touching postrm and postinst
#Reference phase order:
#pkg_preinst
#pkg_prerm
#pkg_postrm
#pkg_postinst
pkg_postrm() {
if [[ "$(readlink "${ROOT}"/${NUNIT_DIR})" == *"mono-nunit" ]]
then
ebegin "Removing old symlinks for nunit"
rm -rf "${ROOT}"/${NUNIT_DIR} &> /dev/null
rm -rf "${ROOT}"/usr/bin/nunit-console &> /dev/null
rm -rf "${ROOT}"/usr/bin/nunit-console2 &> /dev/null
rm -rf "${ROOT}"/usr/$(get_libdir)/pkgconfig/nunit.pc &> /dev/null
eend 0
fi
}
pkg_postinst() {
local -a FAIL
local fail return=0
if ! [[ -L "${ROOT}/${NUNIT_DIR}" ]]
then
einfo "No default NUnit installed, using mono-nunit as default."
ebegin "Removing stale symlinks for nunit, if any"
rm -rf "${ROOT}"/${NUNIT_DIR} &> /dev/null
rm -rf "${ROOT}"/usr/bin/nunit-console &> /dev/null
rm -rf "${ROOT}"/usr/bin/nunit-console2 &> /dev/null
rm -rf "${ROOT}"/usr/$(get_libdir)/pkgconfig/nunit.pc &> /dev/null
eend 0
ebegin "Installing mono-nunit symlinks"
ln -sf mono-nunit "${ROOT}/${NUNIT_DIR}" || { return=1; FAIL+=( $NUNIT_DIR ) ; }
ln -sf ../..${NUNIT_DIR}/nunit-console "${ROOT}"/usr/bin/nunit-console || { return=1; FAIL+=( /usr/bin/nunit-console ) ; }
ln -sf ../..${NUNIT_DIR}/nunit-console2 "${ROOT}"/usr/bin/nunit-console2 || { return=1; FAIL+=( /usr/bin/nunit-console2 ) ; }
ln -sf mono-nunit.pc "${ROOT}"/usr/$(get_libdir)/pkgconfig/nunit.pc || { return=1; FAIL+=( /usr/$(get_libdir)/pkgconfig/nunit.pc ) ; }
eend $return
if [[ "$return" = "1" ]]
then
elog "These errors are non-fatal, if re-emerging mono does not solve them, file a bug."
for fail in "${FAIL[@]}"
do
eerror "Linking $fail failed"
done
fi
fi
elog "PLEASE TAKE NOTE!"
elog ""
elog "Some of the namespaces supported by Mono require extra packages to be installed."
elog "Below is a list of namespaces and the corresponding package you must install:"
elog ""
elog ">=x11-libs/cairo-1.6.4"
elog " Mono.Cairo"
elog "Also read:"
elog "http://www.mono-project.com/Mono.Cairo"
elog ""
elog ">=dev-db/firebird-2.0.4.13130.1"
elog " FirebirdSql.Data.Firebird"
elog "Also read:"
elog "http://www.mono-project.com/Firebird_Interbase"
elog ""
elog "=dev-dotnet/gluezilla-${GO_MONO_REL_PV}*"
elog " Mono.Mozilla"
elog " Mono.Mozilla.WebBrowser"
elog " Mono.Mozilla.Widget"
elog " Interop.SHDocVw"
elog " AxInterop.SHDocVw"
elog " Interop.mshtml.dll"
elog " System.Windows.Forms.WebBrowser"
elog " Microsoft.IE"
elog "Also read:"
elog "http://www.mono-project.com/WebBrowser"
elog ""
elog "dev-db/sqlite:3"
elog " Mono.Data.Sqlite"
elog " Mono.Data.SqliteClient"
elog "Also read:"
elog "http://www.mono-project.com/SQLite"
elog ""
elog ">=dev-db/oracle-instantclient-basic-10.2"
elog " System.Data.OracleClient"
elog "Also read:"
elog "http://www.mono-project.com/Oracle"
elog ""
elog "Mono also has support for packages that are not included in portage:"
elog ""
elog "No ebuild available:"
elog " IBM.Data.DB2"
elog "Also read: http://www.mono-project.com/IBM_DB2"
elog ""
elog "No ebuild needed:"
elog " Mono.Data.SybaseClient"
elog "Also read: http://www.mono-project.com/Sybase"
}
# NOTICE: THE COPYRIGHT FILES IN THE TARBALL ARE UNCLEAR!
# WHENEVER YOU THINK SOMETHING IS GPL-2+, IT'S ONLY GPL-2
# UNLESS MIGUEL DE ICAZA HIMSELF SAYS OTHERWISE.
# mono
# The code we use is LGPL, but contributions must be made under the MIT/X11
# license, so Novell can serve its paying customers. Exception is mono/man.
# LICENSE="LGPL-2.1"
# mono/man
# LICENSE="MIT"
# mcs/mcs
# mcs/gmcs
# LICENSE="GPL-2 MIT"
# tests
# LICENSE="MIT"
# mcs/class
# Except the listed exceptions:
# LICENSE="MIT"
# mcs/class/ByteFX.Data
# mcs/class/Npgsql
# LICENSE="LGPL-2.1"
# mcs/class/FirebirdSql.Data.Firebird
# LICENSE="IDPL"
# mcs/class/ICSharpCode.SharpZipLib
# LICENSE="GPL-2-with-linking-exception"
# mcs/class/MicrosoftAjaxLibrary
# LICENSE="Ms-Pl"
# mcs/class/Microsoft.JScript/Microsoft.JScript/TokenStream.cs
# mcs/class/Microsoft.JScript/Microsoft.JScript/Token.cs
# mcs/class/Microsoft.JScript/Microsoft.JScript/Parser.cs
# mcs/class/Microsoft.JScript/Microsoft.JScript/Decompiler.cs
# LICENSE="|| ( NPL-1.1 GPL-2 )"
# mcs/jay
# LICENSE="BSD-4"
# mcs/tools
# Except the listed exceptions:
# LICENSE="MIT"
# mcs/tools/mdoc/Mono.Documentation/monodocs2html.cs
# LICENSE="GPL-2"
# mcs/tools/sqlsharp/SqlSharpCli.cs
# LICENSE="GPL-2"
# mcs/tools/csharp/repl.cs
# LICENSE="|| ( MIT GPL-2 )"
# mcs/tools/mono-win32-setup.nsi
# LICENSE="GPL-2"
# samples
# LICENSE="MIT"
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in dev-lang/mono: ChangeLog mono-2.4.ebuild
@ 2009-04-10 23:11 Peter Alfredsen (loki_val)
0 siblings, 0 replies; 3+ messages in thread
From: Peter Alfredsen (loki_val) @ 2009-04-10 23:11 UTC (permalink / raw
To: gentoo-commits
loki_val 09/04/10 23:11:08
Modified: ChangeLog mono-2.4.ebuild
Log:
Add fix for build on ppc/ppc64 from upstream CVS
(Portage version: 2.2_rc28/cvs/Linux x86_64)
Revision Changes Path
1.162 dev-lang/mono/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/ChangeLog?rev=1.162&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/ChangeLog?rev=1.162&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/ChangeLog?r1=1.161&r2=1.162
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/mono/ChangeLog,v
retrieving revision 1.161
retrieving revision 1.162
diff -u -r1.161 -r1.162
--- ChangeLog 6 Apr 2009 15:12:26 -0000 1.161
+++ ChangeLog 10 Apr 2009 23:11:08 -0000 1.162
@@ -1,6 +1,10 @@
# ChangeLog for dev-lang/mono
# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/mono/ChangeLog,v 1.161 2009/04/06 15:12:26 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/mono/ChangeLog,v 1.162 2009/04/10 23:11:08 loki_val Exp $
+
+ 10 Apr 2009; Peter Alfredsen <loki_val@gentoo.org>
+ +files/mono-2.4-ppcbuild-fix.patch, mono-2.4.ebuild:
+ Add fix for build on ppc/ppc64 from upstream CVS
06 Apr 2009; Brent Baude <ranger@gentoo.org> mono-2.2-r5.ebuild:
Marking mono-2.2-r5 ~ppc for bug 255410
1.3 dev-lang/mono/mono-2.4.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/mono-2.4.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/mono-2.4.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/mono-2.4.ebuild?r1=1.2&r2=1.3
Index: mono-2.4.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/mono/mono-2.4.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- mono-2.4.ebuild 4 Apr 2009 23:26:03 -0000 1.2
+++ mono-2.4.ebuild 10 Apr 2009 23:11:08 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/mono/mono-2.4.ebuild,v 1.2 2009/04/04 23:26:03 loki_val Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/mono/mono-2.4.ebuild,v 1.3 2009/04/10 23:11:08 loki_val Exp $
EAPI=2
@@ -38,6 +38,7 @@
"${WORKDIR}/mono-2.2-libdir126.patch"
"${FILESDIR}/mono-2.2-ppc-threading.patch"
"${FILESDIR}/mono-2.2-uselibdir.patch"
+ "${FILESDIR}/mono-2.4-ppcbuild-fix.patch"
)
src_prepare() {
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in dev-lang/mono: ChangeLog mono-2.4.ebuild
@ 2009-05-20 19:51 Brent Baude (ranger)
0 siblings, 0 replies; 3+ messages in thread
From: Brent Baude (ranger) @ 2009-05-20 19:51 UTC (permalink / raw
To: gentoo-commits
ranger 09/05/20 19:51:28
Modified: ChangeLog mono-2.4.ebuild
Log:
Marking mono-2.4 ppc for bug 268517
(Portage version: 2.1.6.13/cvs/Linux ppc64)
Revision Changes Path
1.171 dev-lang/mono/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/ChangeLog?rev=1.171&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/ChangeLog?rev=1.171&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/ChangeLog?r1=1.170&r2=1.171
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/mono/ChangeLog,v
retrieving revision 1.170
retrieving revision 1.171
diff -u -r1.170 -r1.171
--- ChangeLog 14 May 2009 16:29:43 -0000 1.170
+++ ChangeLog 20 May 2009 19:51:28 -0000 1.171
@@ -1,6 +1,9 @@
# ChangeLog for dev-lang/mono
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/mono/ChangeLog,v 1.170 2009/05/14 16:29:43 loki_val Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/mono/ChangeLog,v 1.171 2009/05/20 19:51:28 ranger Exp $
+
+ 20 May 2009; Brent Baude <ranger@gentoo.org> mono-2.4.ebuild:
+ Marking mono-2.4 ~ppc for bug 268517
*mono-2.4-r3 (14 May 2009)
1.6 dev-lang/mono/mono-2.4.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/mono-2.4.ebuild?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/mono-2.4.ebuild?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/mono/mono-2.4.ebuild?r1=1.5&r2=1.6
Index: mono-2.4.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/mono/mono-2.4.ebuild,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- mono-2.4.ebuild 20 Apr 2009 05:01:45 -0000 1.5
+++ mono-2.4.ebuild 20 May 2009 19:51:28 -0000 1.6
@@ -1,6 +1,6 @@
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/mono/mono-2.4.ebuild,v 1.5 2009/04/20 05:01:45 loki_val Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/mono/mono-2.4.ebuild,v 1.6 2009/05/20 19:51:28 ranger Exp $
EAPI=2
@@ -11,7 +11,7 @@
LICENSE="MIT LGPL-2.1 GPL-2 BSD-4 NPL-1.1 Ms-PL GPL-2-with-linking-exception IDPL"
SLOT="0"
-KEYWORDS="~x86 ~amd64"
+KEYWORDS="~amd64 ~ppc ~x86"
IUSE="xen moonlight minimal"
#Bash requirement is for += operator
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2009-05-20 19:51 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2009-04-10 23:11 [gentoo-commits] gentoo-x86 commit in dev-lang/mono: ChangeLog mono-2.4.ebuild Peter Alfredsen (loki_val)
-- strict thread matches above, loose matches on Subject: below --
2009-05-20 19:51 Brent Baude (ranger)
2009-03-30 21:48 Peter Alfredsen (loki_val)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox