[gentoo-commits] gentoo-x86 commit in net-misc/aria2: ChangeLog aria2-1.3.0.ebuild aria2-1.1.2.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/aria2: ChangeLog aria2-1.3.0.ebuild aria2-1.1.2.ebuild

[Tiziano Mueller (dev-zero)]

dev-zero    09/04/06 15:35:59

  Modified:             ChangeLog
  Added:                aria2-1.3.0.ebuild
  Removed:              aria2-1.1.2.ebuild
  Log:
  Version bump, renamed sqlite3 USE flag to sqlite (bug #251397). Dropped buggy old version.
  (Portage version: 2.1.6.11/cvs/Linux x86_64)

Revision  Changes    Path
1.40                 net-misc/aria2/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/aria2/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/aria2/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/aria2/ChangeLog?r1=1.39&r2=1.40

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/aria2/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog	23 Feb 2009 20:23:26 -0000	1.39
+++ ChangeLog	6 Apr 2009 15:35:59 -0000	1.40
@@ -1,6 +1,14 @@
 # ChangeLog for net-misc/aria2
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/aria2/ChangeLog,v 1.39 2009/02/23 20:23:26 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/aria2/ChangeLog,v 1.40 2009/04/06 15:35:59 dev-zero Exp $
+
+*aria2-1.3.0 (06 Apr 2009)
+
+  06 Apr 2009; Tiziano Müller <dev-zero@gentoo.org>
+  -files/1.1.2-testRetrieveCookie-testfix.patch, -aria2-1.1.2.ebuild,
+  +aria2-1.3.0.ebuild:
+  Version bump, renamed sqlite3 USE flag to sqlite (bug #251397). Dropped
+  buggy old version.
 
 *aria2-1.2.0 (23 Feb 2009)
 



1.1                  net-misc/aria2/aria2-1.3.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/aria2/aria2-1.3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/aria2/aria2-1.3.0.ebuild?rev=1.1&content-type=text/plain

Index: aria2-1.3.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/aria2/aria2-1.3.0.ebuild,v 1.1 2009/04/06 15:35:59 dev-zero Exp $

EAPI="2"

DESCRIPTION="A download utility with resuming and segmented downloading with HTTP/HTTPS/FTP/BitTorrent support."
HOMEPAGE="http://aria2.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
SLOT="0"
IUSE="ares bittorrent expat gnutls metalink nls sqlite ssl test"

CDEPEND="sys-libs/zlib
	ssl? (
		gnutls? ( >=net-libs/gnutls-1.2.9 )
		!gnutls? ( dev-libs/openssl ) )
	ares? ( >=net-dns/c-ares-1.5.0 )
	bittorrent? (
		gnutls? ( >=net-libs/gnutls-1.2.9 >=dev-libs/libgcrypt-1.2.2 )
		!gnutls? ( dev-libs/openssl ) )
	metalink? (
		!expat? ( >=dev-libs/libxml2-2.6.26 )
		expat? ( dev-libs/expat )
	)
	sqlite? ( dev-db/sqlite:3 )"
DEPEND="${CDEPEND}
	nls? ( sys-devel/gettext )
	test? ( >=dev-util/cppunit-1.12.0 )"
RDEPEND="${CDEPEND}
	nls? ( virtual/libiconv virtual/libintl )"

src_prepare() {
	sed -i -e "s|/tmp|${T}|" test/*.cc test/*.txt || die "sed failed"
}

src_configure() {
	local myconf="--without-gnutls --without-openssl"
	use ssl && \
		myconf="$(use_with gnutls) $(use_with !gnutls openssl)"

	# Note:
	# - depends on libgcrypt only when using gnutls
	# - links only against libxml2 and libexpat when metalink is enabled
	# - always enable gzip/http compression since zlib should always be available anyway
	# - always enable epoll since we can assume kernel 2.6.x
	# - other options for threads: solaris, pth, win32
	econf \
		--enable-epoll \
		--enable-threads=posix \
		--with-libz \
		$(use_enable nls) \
		$(use_enable metalink) \
		$(use_with expat libexpat) \
		$(use_with !expat libxml2) \
		$(use_with sqlite sqlite3) \
		$(use_enable bittorrent) \
		$(use_with ares libcares) \
		${myconf} \
		|| die "econf failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	rm -rf "${D}/usr/share/doc/aria2c"
	dodoc ChangeLog README AUTHORS NEWS
	dohtml README.html doc/aria2c.1.html
}