[gentoo-commits] gentoo-x86 commit in dev-dotnet/monotorrent: monotorrent-0.70.ebuild metadata.xml ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-dotnet/monotorrent: monotorrent-0.70.ebuild metadata.xml ChangeLog

[Peter Alfredsen (loki_val)]

loki_val    09/04/05 12:39:45

  Added:                monotorrent-0.70.ebuild metadata.xml ChangeLog
  Log:
  Initial commit, ebuild by me.
  (Portage version: 2.2_rc28/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  dev-dotnet/monotorrent/monotorrent-0.70.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-dotnet/monotorrent/monotorrent-0.70.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-dotnet/monotorrent/monotorrent-0.70.ebuild?rev=1.1&content-type=text/plain

Index: monotorrent-0.70.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-dotnet/monotorrent/monotorrent-0.70.ebuild,v 1.1 2009/04/05 12:39:45 loki_val Exp $

EAPI=2

inherit mono multilib

DESCRIPTION="Monotorrent is an open source C# bittorrent library"
HOMEPAGE="http://www.monotorrent.com/"
SRC_URI="http://monotorrent.com/Files/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE=""
RDEPEND=">=dev-lang/mono-2.0.1"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.23"

# The hack we do to get the dll installed in the GAC makes the unit-tests
# defunct.
RESTRICT="test"

src_prepare() {
	sed -i	\
		-e "/InternalsVisibleTo/d" \
		MonoTorrent/AssemblyInfo.cs* || die
}

src_compile() {
	emake -j1 ASSEMBLY_COMPILER_COMMAND="/usr/bin/gmcs -keyfile:${FILESDIR}/mono.snk"
}

src_install() {
	egacinstall $(find . -name "MonoTorrent.dll")
	dodir /usr/$(get_libdir)/pkgconfig
	ebegin "Installing .pc file"
	sed  \
		-e "s:@LIBDIR@:$(get_libdir):" \
		-e "s:@PACKAGENAME@:${PN}:" \
		-e "s:@DESCRIPTION@:${DESCRIPTION}:" \
		-e "s:@VERSION@:${PV}:" \
		-e 's;@LIBS@;-r:${libdir}/mono/monotorrent/MonoTorrent.dll;' \
		"${FILESDIR}"/${PN}.pc.in > "${D}"/usr/$(get_libdir)/pkgconfig/${PN}.pc
	PKG_CONFIG_PATH="${D}/usr/$(get_libdir)/pkgconfig/" pkg-config --exists monotorrent || die ".pc file failed to validate."
	eend $?
}



1.1                  dev-dotnet/monotorrent/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-dotnet/monotorrent/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-dotnet/monotorrent/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>dotnet</herd>
</pkgmetadata>



1.1                  dev-dotnet/monotorrent/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-dotnet/monotorrent/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-dotnet/monotorrent/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for dev-dotnet/monotorrent
# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-dotnet/monotorrent/ChangeLog,v 1.1 2009/04/05 12:39:45 loki_val Exp $

*monotorrent-0.70 (05 Apr 2009)

  05 Apr 2009; Peter Alfredsen <loki_val@gentoo.org> +files/mono.snk,
  +files/monotorrent.pc.in, +metadata.xml, +monotorrent-0.70.ebuild:
  Initial commit, ebuild by me.