[gentoo-commits] gentoo-x86 commit in gnome-base/gnome-session: metadata.xml ChangeLog gnome-session-2.24.3.ebuild

[gentoo-commits] gentoo-x86 commit in gnome-base/gnome-session: metadata.xml ChangeLog gnome-session-2.24.3.ebuild

[Nirbheek Chauhan (nirbheek)]

nirbheek    09/03/17 08:32:33

  Modified:             metadata.xml ChangeLog
  Added:                gnome-session-2.24.3.ebuild
  Log:
  Add =gnome-session-2.24.3 from overlay (p.masked)
  (Portage version: 2.2_rc25/cvs/Linux i686)

Revision  Changes    Path
1.2                  gnome-base/gnome-session/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-session/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-session/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-session/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-session/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	2 Jul 2003 23:54:32 -0000	1.1
+++ metadata.xml	17 Mar 2009 08:32:33 -0000	1.2
@@ -1,5 +1,9 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>gnome</herd>
+	<herd>gnome</herd>
+	<use>
+		<flag name="policykit">Enable <pkg>sys-auth/policykit</pkg>
+			authentication support</flag>
+	</use>
 </pkgmetadata>



1.230                gnome-base/gnome-session/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-session/ChangeLog?rev=1.230&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-session/ChangeLog?rev=1.230&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-session/ChangeLog?r1=1.229&r2=1.230

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-session/ChangeLog,v
retrieving revision 1.229
retrieving revision 1.230
diff -u -r1.229 -r1.230
--- ChangeLog	15 Mar 2009 21:50:07 -0000	1.229
+++ ChangeLog	17 Mar 2009 08:32:33 -0000	1.230
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-base/gnome-session
 # Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-session/ChangeLog,v 1.229 2009/03/15 21:50:07 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-session/ChangeLog,v 1.230 2009/03/17 08:32:33 nirbheek Exp $
+
+*gnome-session-2.24.3 (17 Mar 2009)
+
+  17 Mar 2009; Nirbheek Chauhan <nirbheek@gentoo.org>
+  +files/gnome-session-2.23.5-polkit-automagic.patch,
+  +files/gnome-session-2.24.2-shutdown.patch, +gnome-session-2.24.3.ebuild:
+  Add gnome-session-2.24.3 from overlay (p.masked)
 
   15 Mar 2009; Markus Meier <maekke@gentoo.org>
   gnome-session-2.22.3-r1.ebuild:



1.1                  gnome-base/gnome-session/gnome-session-2.24.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-session/gnome-session-2.24.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-session/gnome-session-2.24.3.ebuild?rev=1.1&content-type=text/plain

Index: gnome-session-2.24.3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-session/gnome-session-2.24.3.ebuild,v 1.1 2009/03/17 08:32:33 nirbheek Exp $

inherit autotools eutils gnome2

DESCRIPTION="Gnome session manager"
HOMEPAGE="http://www.gnome.org/"
SRC_URI="${SRC_URI}
		branding? ( mirror://gentoo/gentoo-splash.png )"

LICENSE="GPL-2 LGPL-2 FDL-1.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

IUSE="branding ipv6 policykit"

RDEPEND=">=dev-libs/glib-2.16
	>=gnome-base/libgnomeui-2.2
	>=x11-libs/gtk+-2.11.1
	>=gnome-base/libglade-2.3.6
	>=dev-libs/dbus-glib-0.76
	>=gnome-base/gnome-keyring-2.21.92
	>=gnome-base/gconf-2
	>=x11-libs/startup-notification-0.9
	policykit? ( >=gnome-extra/policykit-gnome-0.7 )

	x11-apps/xdpyinfo"
DEPEND="${RDEPEND}
	>=sys-devel/gettext-0.10.40
	>=dev-util/pkgconfig-0.17
	>=dev-util/intltool-0.40
	!<gnome-base/gdm-2.20.4"
# gnome-base/gdm does not provide gnome.desktop anymore

DOCS="AUTHORS ChangeLog NEWS README"

pkg_setup() {
	# TODO: convert libnotify to a configure option
	G2CONF="${G2CONF} $(use_enable ipv6) $(use_enable policykit polkit)"
}

src_unpack() {
	gnome2_src_unpack

	# Patch for Gentoo Branding (bug #42687)
	use branding && epatch "${FILESDIR}/${PN}-2.17.90.1-gentoo-branding.patch"

	# Fix automagic dependency on policykit, upstream bug #551766
	epatch "${FILESDIR}/${PN}-2.23.5-polkit-automagic.patch"

	# Fix shutdown/restart capability, upstream bug #549150
	epatch "${FILESDIR}/${PN}-2.24.2-shutdown.patch"

	intltoolize --force --copy --automake || die "intltoolize failed"
	eautoreconf
}

src_install() {
	gnome2_src_install

	dodir /etc/X11/Sessions
	exeinto /etc/X11/Sessions
	doexe "${FILESDIR}/Gnome"

	# Our own splash for world domination
	if use branding ; then
		insinto /usr/share/pixmaps/splash/
		doins "${DISTDIR}/gentoo-splash.png"
	fi
}