[gentoo-commits] gentoo-x86 commit in gnome-base/gnome-panel: ChangeLog gnome-panel-2.24.3-r1.ebuild gnome-panel-2.24.2-r1.ebuild

[gentoo-commits] gentoo-x86 commit in gnome-base/gnome-panel: ChangeLog gnome-panel-2.24.3-r1.ebuild gnome-panel-2.24.2-r1.ebuild

[Gilles Dartiguelongue (eva)]

eva         09/02/26 23:23:29

  Modified:             ChangeLog
  Added:                gnome-panel-2.24.3-r1.ebuild
  Removed:              gnome-panel-2.24.2-r1.ebuild
  Log:
  Bump to 2.24.3-r1. Add patch to allow shutdown without gdm, #259138. Clean up old revisions.
  (Portage version: 2.2_rc23/cvs/Linux x86_64)

Revision  Changes    Path
1.269                gnome-base/gnome-panel/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-panel/ChangeLog?rev=1.269&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-panel/ChangeLog?rev=1.269&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-panel/ChangeLog?r1=1.268&r2=1.269

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/ChangeLog,v
retrieving revision 1.268
retrieving revision 1.269
diff -u -r1.268 -r1.269
--- ChangeLog	5 Feb 2009 19:25:25 -0000	1.268
+++ ChangeLog	26 Feb 2009 23:23:28 -0000	1.269
@@ -1,6 +1,15 @@
 # ChangeLog for gnome-base/gnome-panel
 # Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/ChangeLog,v 1.268 2009/02/05 19:25:25 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/ChangeLog,v 1.269 2009/02/26 23:23:28 eva Exp $
+
+*gnome-panel-2.24.3-r1 (26 Feb 2009)
+
+  26 Feb 2009; Gilles Dartiguelongue <eva@gentoo.org>
+  -files/gnome-panel-2.24.1-logout.patch.gz,
+  +files/gnome-panel-2.24.3-shutdown.patch, -gnome-panel-2.24.2-r1.ebuild,
+  +gnome-panel-2.24.3-r1.ebuild:
+  Bump to 2.24.3-r1. Add patch to allow shutdown without gdm, #259138.
+  Clean up old revisions.
 
   05 Feb 2009; Alexis Ballier <aballier@gentoo.org>
   +files/gnome-panel-2.24.3-daylight.patch, gnome-panel-2.24.3.ebuild:



1.1                  gnome-base/gnome-panel/gnome-panel-2.24.3-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-panel/gnome-panel-2.24.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-panel/gnome-panel-2.24.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: gnome-panel-2.24.3-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/gnome-panel-2.24.3-r1.ebuild,v 1.1 2009/02/26 23:23:29 eva Exp $

GCONF_DEBUG="no"

inherit autotools gnome2

MY_P="${PN}-2.24.2"
DESCRIPTION="The GNOME panel"
HOMEPAGE="http://www.gnome.org/"
SRC_URI="${SRC_URI}
	mirror://gentoo/${MY_P}-logout+po.tar.bz2"

LICENSE="GPL-2 FDL-1.1 LGPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="doc eds networkmanager"

RDEPEND=">=gnome-base/gnome-desktop-2.12
	>=x11-libs/pango-1.15.4
	>=dev-libs/glib-2.16.0
	>=x11-libs/gtk+-2.13.1
	>=dev-libs/libgweather-2.24.1
	dev-libs/libxml2
	>=gnome-base/libglade-2.5
	>=gnome-base/libgnome-2.13
	>=gnome-base/libgnomeui-2.5.4
	>=gnome-base/libbonoboui-2.1.1
	>=gnome-base/orbit-2.4
	>=x11-libs/libwnck-2.19.5
	>=gnome-base/gconf-2.6.1
	>=gnome-base/gnome-menus-2.11.1
	>=gnome-base/libbonobo-2.20.4
	gnome-base/librsvg
	>=dev-libs/dbus-glib-0.71
	>=sys-apps/dbus-1.1.2
	x11-libs/libXau
	>=x11-libs/cairo-1.0.0
	eds? ( >=gnome-extra/evolution-data-server-1.6 )
	networkmanager? ( >=net-misc/networkmanager-0.6 )"
DEPEND="${RDEPEND}
	app-text/scrollkeeper
	>=app-text/gnome-doc-utils-0.3.2
	>=dev-util/pkgconfig-0.9
	>=dev-util/intltool-0.40
	~app-text/docbook-xml-dtd-4.1.2
	>=dev-util/gtk-doc-am-1
	doc? ( >=dev-util/gtk-doc-1 )"

DOCS="AUTHORS ChangeLog HACKING NEWS README"

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-scrollkeeper
		--disable-schemas-install
		--with-in-process-applets=clock,notification-area,wncklet
		--disable-polkit
		$(use_enable networkmanager network-manager)
		$(use_enable eds)"
}

src_unpack() {
	gnome2_src_unpack

	# Allow logout/shutdown without gnome-session 2.24, bug #246170
	epatch "${WORKDIR}/${MY_P}-logout.patch"
	epatch "${WORKDIR}/${MY_P}-po.patch"

	# Fixes build on BSD, bug #256859
	epatch "${FILESDIR}/${P}-daylight.patch"

	# Fixes shutdown without gdm, bug #259138
	epatch "${FILESDIR}/${P}-shutdown.patch"

	intltoolize --force --copy --automake || die "intltoolize failed"
	eautomake
}

pkg_postinst() {
	local entries="${ROOT}etc/gconf/schemas/panel-default-setup.entries"
	local gconftool="${ROOT}usr/bin/gconftool-2"

	if [ -e "$entries" ]; then
		einfo "setting panel gconf defaults..."

		GCONF_CONFIG_SOURCE="$("${gconftool}" --get-default-source | sed "s;:/;:${ROOT};")"

		"${gconftool}" --direct --config-source \
			"${GCONF_CONFIG_SOURCE}" --load="${entries}"
	fi

	# Calling this late so it doesn't process the GConf schemas file we already
	# took care of.
	gnome2_pkg_postinst
}