* [gentoo-commits] gentoo-x86 commit in net-misc/nxserver-freenx: nxserver-freenx-0.7.3-r3.ebuild metadata.xml ChangeLog nxserver-freenx-0.7.3-r1.ebuild
@ 2009-01-23 10:09 Bernard Cafarelli (voyageur)
0 siblings, 0 replies; only message in thread
From: Bernard Cafarelli (voyageur) @ 2009-01-23 10:09 UTC (permalink / raw
To: gentoo-commits
voyageur 09/01/23 10:09:12
Modified: metadata.xml ChangeLog
Added: nxserver-freenx-0.7.3-r3.ebuild
Removed: nxserver-freenx-0.7.3-r1.ebuild
Log:
EAPI 1, enabling nxclient USE-flag by default, update the flag description
(Portage version: 2.2_rc23/cvs/Linux x86_64)
Revision Changes Path
1.5 net-misc/nxserver-freenx/metadata.xml
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nxserver-freenx/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nxserver-freenx/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nxserver-freenx/metadata.xml?r1=1.4&r2=1.5
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/nxserver-freenx/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml 8 Aug 2008 05:01:06 -0000 1.4
+++ metadata.xml 23 Jan 2009 10:09:12 -0000 1.5
@@ -7,6 +7,6 @@
desktops over low-bandwidth links such as the Internet, WANS, and wireless
</longdescription>
<use>
- <flag name="nxclient">Add support for the commercial nxclient</flag>
+ <flag name="nxclient">Allow to install <pkg>net-misc/nxclient</pkg> in parallel with this package, using it to display messages in the sessions</flag>
</use>
</pkgmetadata>
1.56 net-misc/nxserver-freenx/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nxserver-freenx/ChangeLog?rev=1.56&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nxserver-freenx/ChangeLog?rev=1.56&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nxserver-freenx/ChangeLog?r1=1.55&r2=1.56
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/nxserver-freenx/ChangeLog,v
retrieving revision 1.55
retrieving revision 1.56
diff -u -r1.55 -r1.56
--- ChangeLog 19 Dec 2008 16:12:10 -0000 1.55
+++ ChangeLog 23 Jan 2009 10:09:12 -0000 1.56
@@ -1,6 +1,12 @@
# ChangeLog for net-misc/nxserver-freenx
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/nxserver-freenx/ChangeLog,v 1.55 2008/12/19 16:12:10 voyageur Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/nxserver-freenx/ChangeLog,v 1.56 2009/01/23 10:09:12 voyageur Exp $
+
+*nxserver-freenx-0.7.3-r3 (23 Jan 2009)
+
+ 23 Jan 2009; Bernard Cafarelli <voyageur@gentoo.org> metadata.xml,
+ -nxserver-freenx-0.7.3-r1.ebuild, +nxserver-freenx-0.7.3-r3.ebuild:
+ EAPI 1, enabling nxclient USE-flag by default, update the flag description
*nxserver-freenx-0.7.3-r2 (19 Dec 2008)
1.1 net-misc/nxserver-freenx/nxserver-freenx-0.7.3-r3.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nxserver-freenx/nxserver-freenx-0.7.3-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/nxserver-freenx/nxserver-freenx-0.7.3-r3.ebuild?rev=1.1&content-type=text/plain
Index: nxserver-freenx-0.7.3-r3.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/nxserver-freenx/nxserver-freenx-0.7.3-r3.ebuild,v 1.1 2009/01/23 10:09:12 voyageur Exp $
EAPI=1
inherit multilib eutils toolchain-funcs
MY_PN="freenx-server"
DESCRIPTION="Free Software Implementation of the NX Server"
HOMEPAGE="http://freenx.berlios.de/"
SRC_URI="mirror://berlios/freenx/${MY_PN}-${PV}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RESTRICT="strip"
IUSE="arts cups esd +nxclient"
DEPEND="x11-misc/gccmakedep
x11-misc/imake"
RDEPEND="dev-tcltk/expect
media-fonts/font-misc-misc
media-fonts/font-cursor-misc
net-analyzer/gnu-netcat
>=net-misc/nx-2.1.0
sys-apps/gawk
virtual/ssh
x11-apps/xauth
x11-apps/xrdb
x11-apps/sessreg
arts? ( kde-base/arts )
cups? ( net-print/cups )
esd? ( media-sound/esound )
nxclient? ( net-misc/nxclient )
!nxclient? ( !net-misc/nxclient
|| ( x11-misc/xdialog
x11-apps/xmessage ) )
!net-misc/nxserver-freeedition
!net-misc/nxserver-2xterminalserver"
S=${WORKDIR}/${MY_PN}-${PV}
export NX_HOME_DIR=/var/lib/nxserver/home
pkg_setup () {
enewuser nx -1 -1 ${NX_HOME_DIR}
}
src_unpack() {
unpack ${A}
cd "${S}"
epatch "${FILESDIR}"/${P}-nxloadconfig.patch
epatch "${FILESDIR}"/${P}-roundrobin.patch
epatch "${FILESDIR}"/${P}-cflags.patch
epatch "${FILESDIR}"/${PN}-0.7.2-cups.patch
sed -e "s/3\.\[012\]/3.[0123]/g" \
-e "/PATH_LIB=/s/lib/$(get_libdir)/g" \
-e "/REAL_PATH_BIN=/s/lib/$(get_libdir)/g" \
-i nxloadconfig || die "nxloadconfig sed failed"
# Change the defaults in nxloadconfig to meet the users needs.
if use arts ; then
einfo "Enabling arts support."
sed -i '/ENABLE_ARTSD_PRELOAD=/s/"0"/"1"/' nxloadconfig || die
sed -i '/ENABLE_ARTSD_PRELOAD=/s/"0"/"1"/' node.conf.sample || die
fi
if use esd ; then
einfo "Enabling esd support."
sed -i '/ENABLE_ESD_PRELOAD=/s/"0"/"1"/' nxloadconfig || die
sed -i '/ENABLE_ESD_PRELOAD=/s/"0"/"1"/' node.conf.sample || die
fi
if use cups ; then
einfo "Enabling cups support."
sed -i '/ENABLE_KDE_CUPS=/s/"0"/"1"/' nxloadconfig || die
sed -i '/ENABLE_KDE_CUPS=/s/"0"/"1"/' node.conf.sample || die
fi
}
src_compile() {
emake CC=$(tc-getCC) CDEBUGFLAGS="${CFLAGS}" || die "compilation failed"
}
src_install() {
export NX_ETC_DIR=/etc/nxserver
export NX_SESS_DIR=/var/lib/nxserver/db
emake DESTDIR="${D}" install || die "install failed"
# This should be renamed to remove the blocker on net-misc/nxclient
use nxclient && rm "${D}"/usr/bin/nxprint
mv "${D}"/etc/nxserver/node.conf.sample "${D}"/etc/nxserver/node.conf ||
die "cannot find default configuration file"
dodir ${NX_ETC_DIR}
for x in passwords passwords.orig ; do
touch "${D}"${NX_ETC_DIR}/$x
chmod 600 "${D}"${NX_ETC_DIR}/$x
done
dodir ${NX_HOME_DIR}
for x in closed running failed ; do
keepdir ${NX_SESS_DIR}/$x
fperms 0700 ${NX_SESS_DIR}/$x
done
newinitd "${FILESDIR}"/nxserver.init nxserver
}
pkg_postinst () {
# Other NX servers ebuilds may have already created the nx account
# However they use different login shell/home directory paths
if [[ ${ROOT} == "/" ]]; then
usermod -s /usr/bin/nxserver nx || die "Unable to set login shell of nx user!!"
usermod -d ${NX_HOME_DIR} nx || die "Unable to set home directory of nx user!!"
usermod -G utmp nx || die "Unable to add nx user to utmp group!!"
else
elog "If you had another NX server installed before, please make sure"
elog "the nx user account is correctly set to:"
elog " * login shell: /usr/bin/nxserver"
elog " * home directory: ${NX_HOME_DIR}"
elog " * supplementary groups: utmp"
fi
elog "To complete the installation, run:"
elog " nxsetup --install --setup-nomachine-key --clean --purge"
elog "This will use the default Nomachine SSH key"
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2009-01-23 10:09 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2009-01-23 10:09 [gentoo-commits] gentoo-x86 commit in net-misc/nxserver-freenx: nxserver-freenx-0.7.3-r3.ebuild metadata.xml ChangeLog nxserver-freenx-0.7.3-r1.ebuild Bernard Cafarelli (voyageur)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox