[gentoo-commits] gentoo-x86 commit in media-gfx/eog: ChangeLog eog-2.24.3.1.ebuild

["Arun Raghavan (ford_prefect)" <ford_prefect@gentoo.org>]

ford_prefect    09/01/19 19:38:20

  Modified:             ChangeLog
  Added:                eog-2.24.3.1.ebuild
  Log:
  Bump to 2.24.3.1, and fix bug #254943. Dropping the sparc sigbus patch since it has been committed.
  (Portage version: 2.2_rc22/cvs/Linux 2.6.28 i686)

Revision  Changes    Path
1.222                media-gfx/eog/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/eog/ChangeLog?rev=1.222&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/eog/ChangeLog?rev=1.222&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/eog/ChangeLog?r1=1.221&r2=1.222

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/eog/ChangeLog,v
retrieving revision 1.221
retrieving revision 1.222
diff -u -r1.221 -r1.222
--- ChangeLog	28 Dec 2008 16:32:15 -0000	1.221
+++ ChangeLog	19 Jan 2009 19:38:20 -0000	1.222
@@ -1,6 +1,13 @@
 # ChangeLog for media-gfx/eog
-# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/eog/ChangeLog,v 1.221 2008/12/28 16:32:15 bluebird Exp $
+# Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/eog/ChangeLog,v 1.222 2009/01/19 19:38:20 ford_prefect Exp $
+
+*eog-2.24.3.1 (19 Jan 2009)
+
+  19 Jan 2009; Arun Raghavan <ford_prefect@gentoo.org>
+  +files/eog-2.24.3.1-noexif-doc.patch, +eog-2.24.3.1.ebuild:
+  Bump to 2.24.3.1, and fix bug #254943. Dropping the sparc sigbus patch
+  since it has been committed.
 
   28 Dec 2008; Friedrich Oslage <bluebird@gentoo.org> eog-2.24.2-r1.ebuild:
   Add ~sparc keyword, bug #242812



1.1                  media-gfx/eog/eog-2.24.3.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/eog/eog-2.24.3.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/eog/eog-2.24.3.1.ebuild?rev=1.1&content-type=text/plain

Index: eog-2.24.3.1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/eog/eog-2.24.3.1.ebuild,v 1.1 2009/01/19 19:38:20 ford_prefect Exp $

inherit eutils gnome2 autotools

DESCRIPTION="The Eye of GNOME image viewer"
HOMEPAGE="http://www.gnome.org/projects/eog/"

LICENSE="GPL-2"
SLOT="1"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~sparc ~x86"
IUSE="dbus doc exif lcms python xmp"

RDEPEND=">=x11-libs/gtk+-2.13.1
	>=dev-libs/glib-2.15.3
	>=gnome-base/libgnomeui-2.10
	>=gnome-base/libglade-2.3.6
	>=gnome-base/gconf-2.5.90
	>=media-libs/libart_lgpl-2.3.16
	>=gnome-base/gnome-desktop-2.10
	>=x11-themes/gnome-icon-theme-2.19.1
	>=x11-misc/shared-mime-info-0.20
	dbus? ( >=dev-libs/dbus-glib-0.71 )
	exif? (
		>=media-libs/libexif-0.6.14
		media-libs/jpeg )
	lcms? ( media-libs/lcms )
	python? (
		>=dev-lang/python-2.3
		>=dev-python/pygobject-2.11.5
		>=dev-python/pygtk-2.9.7
		>=dev-python/gnome-python-2.18.2 )
	xmp? ( >=media-libs/exempi-2 )"

DEPEND="${RDEPEND}
	app-text/gnome-doc-utils
	sys-devel/gettext
	>=dev-util/intltool-0.40
	>=dev-util/pkgconfig-0.17
	doc? ( >=dev-util/gtk-doc-1.10 )"

DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README THANKS TODO"

pkg_setup() {
	G2CONF="${G2CONF}
		$(use_with exif libjpeg)
		$(use_with exif libexif)
		$(use_with dbus)
		$(use_with lcms cms)
		$(use_enable python)
		$(use_with xmp)
		--disable-scrollkeeper
		--disable-schemas-install"
}

src_unpack() {
	gnome2_src_unpack

	# Fix documentation with USE="-exif doc"
	sed 's:-I$(top_srcdir)/plugins \\:\\:g' \
		-i doc/reference/Makefile.am doc/reference/Makefile.in \
		|| die "sed	failed"

	# Fix build with USE="doc -exif -xmp". Bug #254943
	epatch "${FILESDIR}/${P}-noexif-doc.patch"
	eautoreconf
}

pkg_postinst() {
	gnome2_pkg_postinst

	if ! built_with_use =x11-libs/gtk+-2* jpeg; then
		ewarn "For JPEG file support to work, x11-libs/gtk+ must be rebuilt"
		ewarn "with the 'jpeg' USE flag enabled."
	fi

	if ! built_with_use =x11-libs/gtk+-2* tiff; then
		ewarn "For TIFF file support to work, x11-libs/gtk+ must be rebuilt"
		ewarn "with the 'tiff' USE flag enabled."
	fi
}