[gentoo-commits] gentoo-x86 commit in media-sound/alsa-utils: alsa-utils-1.0.19.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in media-sound/alsa-utils: alsa-utils-1.0.19.ebuild ChangeLog

[Tony Vroon (chainsaw)]

chainsaw    09/01/19 17:21:11

  Modified:             ChangeLog
  Added:                alsa-utils-1.0.19.ebuild
  Log:
  Version bump, disabling the ill-advised automatic module unloading. Closes bug #175740 and #253535.
  (Portage version: 2.1.6.7/cvs/Linux x86_64)

Revision  Changes    Path
1.255                media-sound/alsa-utils/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/ChangeLog?rev=1.255&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/ChangeLog?rev=1.255&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/ChangeLog?r1=1.254&r2=1.255

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v
retrieving revision 1.254
retrieving revision 1.255
diff -u -r1.254 -r1.255
--- ChangeLog	21 Dec 2008 15:03:35 -0000	1.254
+++ ChangeLog	19 Jan 2009 17:21:11 -0000	1.255
@@ -1,6 +1,20 @@
 # ChangeLog for media-sound/alsa-utils
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v 1.254 2008/12/21 15:03:35 nixnut Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/ChangeLog,v 1.255 2009/01/19 17:21:11 chainsaw Exp $
+
+*alsa-utils-1.0.19 (19 Jan 2009)
+
+  19 Jan 2009; <chainsaw@gentoo.org> +files/alsasound-1.0.19.confd,
+  +files/alsasound-1.0.19.initd, +alsa-utils-1.0.19.ebuild:
+  Version bump, disabling the ill-advised automatic module unloading. Note
+  that our recommendations have changed, you are encouraged to build your
+  audio drivers into the kernels unless the device is hotpluggable or needs
+  special parameters (such as model= for HD-Audio). Unloading did not work
+  if the audio device prefix was not snd, as reported by chad heuschober
+  <chad_ryan1@hotmail.com> in bug #175740. As Dieter Ries <clip2@gmx.de>
+  reported in bug #253535 the modularisation of the HD-Audio driver meant
+  that the fragile code handling this broke further as ordering was not
+  taken into account.
 
   21 Dec 2008; nixnut <nixnut@gentoo.org> alsa-utils-1.0.17.ebuild:
   Stable on ppc wrt bug 245517



1.1                  media-sound/alsa-utils/alsa-utils-1.0.19.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.19.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.19.ebuild?rev=1.1&content-type=text/plain

Index: alsa-utils-1.0.19.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/alsa-utils/alsa-utils-1.0.19.ebuild,v 1.1 2009/01/19 17:21:11 chainsaw Exp $

inherit eutils

MY_P="${P/_rc/rc}"

DESCRIPTION="Advanced Linux Sound Architecture Utils (alsactl, alsamixer, etc.)"
HOMEPAGE="http://www.alsa-project.org/"
SRC_URI="mirror://alsaproject/utils/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0.9"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="nls midi minimal"

DEPEND=">=sys-libs/ncurses-5.1
	dev-util/dialog
	>=media-libs/alsa-lib-${PV}
	app-text/xmlto"
RDEPEND="${DEPEND}
	virtual/modutils
	!minimal? ( sys-apps/pciutils )"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	if use midi && ! built_with_use --missing true media-libs/alsa-lib midi; then
		eerror ""
		eerror "To be able to build alsa-utils with midi support you need"
		eerror "to have built media-libs/alsa-lib with midi USE flag."
		die "Missing midi USE flag on media-libs/alsa-lib"
	fi
}

src_compile() {
	econf $(use_enable nls) \
		$(use_enable midi sequencer) \
		|| die "configure failed"

	emake || die "make failed"
}

pkg_preinst() {
	if [[ -a /etc/modules.d/alsa ]] && [[ ! -a /etc/modprobe.d/alsa ]]; then
		elog "Moving old alsa configuration in modules.d to new"
		elog "location in modprobe.d in /etc/"
		mv "${ROOT}/etc/modules.d/alsa" "${ROOT}/etc/modprobe.d/alsa"
	fi
}

src_install() {
	local ALSA_UTILS_DOCS="ChangeLog README TODO
		seq/aconnect/README.aconnect
		seq/aseqnet/README.aseqnet"

	emake DESTDIR="${D}" install || die "Installation Failed"

	dodoc ${ALSA_UTILS_DOCS} || die
	newdoc alsamixer/README README.alsamixer || die

	newinitd "${FILESDIR}/alsasound-1.0.19.initd" alsasound
	newconfd "${FILESDIR}/alsasound-1.0.19.confd" alsasound
	insinto /etc/modprobe.d
	newins "${FILESDIR}/alsa-modules.conf-rc" alsa

	keepdir /var/lib/alsa
}

pkg_postinst() {
	echo
	elog "To take advantage of the init script, and automate the process of"
	elog "storing and restoring sound-card mixer levels you should"
	elog "add alsasound to the boot runlevel. You can do this as"
	elog "root like so:"
	elog "	# rc-update add alsasound boot"
	echo
	elog "The script will load ALSA modules, if you choose to use a modular"
	elog "configuration. The Gentoo ALSA developers recommend you to build"
	elog "your audio drivers into the kernel unless the device is hotpluggable"
	elog "or you need to supply specific options (such as model= to HD Audio)."
	echo
	ewarn "Automated unloading of ALSA modules is deprecated and unsupported."
	ewarn "Should you choose to use it, bug reports will not be accepted."
	echo
	if use minimal; then
		ewarn "The minimal use flag disables the dependency on pciutils that"
		ewarn "is needed by alsaconf at runtime."
	fi
}