* [gentoo-commits] gentoo-x86 commit in net-www/vdradmin-am: ChangeLog vdradmin-am-3.6.4.ebuild vdradmin-am-3.6.2.ebuild vdradmin-am-3.6.0_rc.ebuild vdradmin-am-3.6.1-r1.ebuild vdradmin-am-3.6.0_beta.ebuild vdradmin-am-3.6.1.ebuild vdradmin-am-3.5.3.ebuild vdradmin-am-3.6.0.ebuild
@ 2009-01-05 21:02 Joerg Bornkessel (hd_brummy)
0 siblings, 0 replies; only message in thread
From: Joerg Bornkessel (hd_brummy) @ 2009-01-05 21:02 UTC (permalink / raw
To: gentoo-commits
hd_brummy 09/01/05 21:02:19
Modified: ChangeLog vdradmin-am-3.6.2.ebuild
Added: vdradmin-am-3.6.4.ebuild
Removed: vdradmin-am-3.6.0_rc.ebuild
vdradmin-am-3.6.1-r1.ebuild
vdradmin-am-3.6.0_beta.ebuild
vdradmin-am-3.6.1.ebuild vdradmin-am-3.5.3.ebuild
vdradmin-am-3.6.0.ebuild
Log:
versions bump; vdradmin-am-3.6.2 stabel on x86; clean up old versions
(Portage version: 2.1.6.4/cvs/Linux 2.6.21-xen-main-r1 i686)
Revision Changes Path
1.29 net-www/vdradmin-am/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/vdradmin-am/ChangeLog?rev=1.29&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/vdradmin-am/ChangeLog?rev=1.29&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/vdradmin-am/ChangeLog?r1=1.28&r2=1.29
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-www/vdradmin-am/ChangeLog,v
retrieving revision 1.28
retrieving revision 1.29
diff -u -r1.28 -r1.29
--- ChangeLog 18 Nov 2008 16:20:05 -0000 1.28
+++ ChangeLog 5 Jan 2009 21:02:19 -0000 1.29
@@ -1,6 +1,16 @@
# ChangeLog for net-www/vdradmin-am
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-www/vdradmin-am/ChangeLog,v 1.28 2008/11/18 16:20:05 tove Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-www/vdradmin-am/ChangeLog,v 1.29 2009/01/05 21:02:19 hd_brummy Exp $
+
+*vdradmin-am-3.6.4 (05 Jan 2009)
+
+ 05 Jan 2009; Joerg Bornkessel <hd_brummy@gentoo.org> -files/vdradmin-2,
+ +files/vdradmin-4, -vdradmin-am-3.5.3.ebuild,
+ -vdradmin-am-3.6.0_beta.ebuild, -vdradmin-am-3.6.0_rc.ebuild,
+ -vdradmin-am-3.6.0.ebuild, -vdradmin-am-3.6.1.ebuild,
+ -vdradmin-am-3.6.1-r1.ebuild, vdradmin-am-3.6.2.ebuild,
+ +vdradmin-am-3.6.4.ebuild:
+ versions bump; vdradmin-am-3.6.2 stabel on x86; clean up old versions
18 Nov 2008; Torsten Veller <tove@gentoo.org> vdradmin-am-3.5.3.ebuild,
vdradmin-am-3.6.0_beta.ebuild, vdradmin-am-3.6.0_rc.ebuild,
1.3 net-www/vdradmin-am/vdradmin-am-3.6.2.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/vdradmin-am/vdradmin-am-3.6.2.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/vdradmin-am/vdradmin-am-3.6.2.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/vdradmin-am/vdradmin-am-3.6.2.ebuild?r1=1.2&r2=1.3
Index: vdradmin-am-3.6.2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-www/vdradmin-am/vdradmin-am-3.6.2.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- vdradmin-am-3.6.2.ebuild 18 Nov 2008 16:20:05 -0000 1.2
+++ vdradmin-am-3.6.2.ebuild 5 Jan 2009 21:02:19 -0000 1.3
@@ -1,6 +1,6 @@
-# Copyright 1999-2008 Gentoo Foundation
+# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-www/vdradmin-am/vdradmin-am-3.6.2.ebuild,v 1.2 2008/11/18 16:20:05 tove Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-www/vdradmin-am/vdradmin-am-3.6.2.ebuild,v 1.3 2009/01/05 21:02:19 hd_brummy Exp $
inherit eutils
@@ -10,7 +10,7 @@
HOMEPAGE="http://andreas.vdr-developer.org/"
SRC_URI="http://andreas.vdr-developer.org/download/${MY_P}.tar.bz2"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="~amd64 x86"
SLOT="0"
LICENSE="GPL-2"
IUSE=""
1.1 net-www/vdradmin-am/vdradmin-am-3.6.4.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/vdradmin-am/vdradmin-am-3.6.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/vdradmin-am/vdradmin-am-3.6.4.ebuild?rev=1.1&content-type=text/plain
Index: vdradmin-am-3.6.4.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-www/vdradmin-am/vdradmin-am-3.6.4.ebuild,v 1.1 2009/01/05 21:02:19 hd_brummy Exp $
inherit eutils
MY_P="${P/_/}"
DESCRIPTION="WWW Admin for the Video Disk Recorder"
HOMEPAGE="http://andreas.vdr-developer.org/"
SRC_URI="http://andreas.vdr-developer.org/download/${MY_P}.tar.bz2"
KEYWORDS="~amd64 ~x86"
SLOT="0"
LICENSE="GPL-2"
IUSE=""
DEPEND="dev-lang/perl
dev-perl/Template-Toolkit
>=virtual/perl-Compress-Zlib-1.2.2
media-video/vdr
virtual/perl-Compress-Zlib
dev-perl/Locale-gettext
dev-perl/Authen-SASL
dev-perl/Digest-HMAC
dev-perl/URI
sys-devel/gettext"
RDEPEND="${DEPEND}"
ETC_DIR="/etc/vdradmin"
LIB_DIR="/usr/share/vdradmin"
VDRADMIN_USER="vdradmin"
VDRADMIN_GROUP="vdradmin"
TMP_DIR=/var/tmp/vdradmin
S="${WORKDIR}/${MY_P}"
pkg_setup() {
enewuser ${VDRADMIN_USER} -1 /bin/bash ${TMP_DIR}
}
src_unpack() {
unpack ${A}
cd "${S}"
epatch "${FILESDIR}"/${PN}-config-autoflush.diff
sed -i vdradmind.pl \
-e "/COMPILE_DIR/s-/tmp-${TMP_DIR}-" \
-e "s-/var/run/vdradmind.pid-/var/tmp/vdradmin/vdradmind.pid-"
}
src_install() {
newinitd "${FILESDIR}"/vdradmin-4 vdradmin
newconfd "${FILESDIR}"/confd-2 vdradmin
newbin vdradmind.pl vdradmind
insinto ${LIB_DIR}/template
doins -r "${S}"/template/*
insinto ${LIB_DIR}/lib/Template/Plugin
doins -r "${S}"/lib/Template/Plugin/JavaScript.pm
insinto /usr/share/locale/
doins -r "${S}"/locale/*
exeinto ${LIB_DIR}
doexe autotimer2searchtimer.pl
doman vdradmind.pl.1
dodoc HISTORY INSTALL CREDITS README* REQUIREMENTS FAQ
docinto contrib
dodoc "${S}"/contrib/*
diropts "-m755 -o ${VDRADMIN_USER} -g ${VDRADMIN_GROUP}"
keepdir "${ETC_DIR}"
keepdir "${TMP_DIR}"
dosed "s:FILES_IN_SYSTEM = 0;:FILES_IN_SYSTEM = 1;:g" /usr/bin/vdradmind
}
pkg_preinst() {
if [[ -f ${ROOT}${ETC_DIR}/vdradmind.conf ]]; then
cp "${ROOT}"${ETC_DIR}/vdradmind.conf "${D}"${ETC_DIR}/vdradmind.conf
else
elog "Creating a new config-file."
echo
cat <<-EOF > "${D}"${ETC_DIR}/vdradmind.conf
VDRCONFDIR = /etc/vdr
VIDEODIR = /var/vdr/video
EPG_FILENAME = /var/vdr/video/epg.data
EPGIMAGES = /var/vdr/video/epgimages
PASSWORD = gentoo-vdr
USERNAME = gentoo-vdr
EOF
# feed it with newlines
yes "" \
| "${D}"/usr/bin/vdradmind.pl --cfgdir "${D}"${ETC_DIR} --config \
|sed -e 's/: /: \n/g'
[[ ${PIPESTATUS[1]} == "0" ]] || die "Failed to create initial configuration."
elog
elog "Created default user/password: gentoo-vdr/gentoo-vdr"
elog
elog "you can run \"emerge --config vdradmin-am\" if"
elog "the default-values for vdr does not match your"
elog "installation or change it in Setup-Menu of Web-Interface."
elog
fi
chown ${VDRADMIN_USER}:${VDRADMIN_GROUP} "${D}"${ETC_DIR}/vdradmind.conf
}
pkg_postinst() {
if [[ -d ${ROOT}${ETC_DIR} ]]; then
local owner=$(stat ${ROOT}${ETC_DIR} -c "%U")
if [[ ${owner} != vdradmin ]]; then
elog "Changing ownership of ${ETC_DIR}."
chown -R ${VDRADMIN_USER}:${VDRADMIN_GROUP} "${ROOT}"${ETC_DIR}
fi
fi
if [[ -d ${ROOT}/tmp/usr/share/vdradmin ]]; then
ewarn "You have a leftover directory of vdradmin."
ewarn "You can safely remove it with:"
ewarn "# rm -rf /tmp/usr/share/vdradmin/template"
ewarn "# rmdir -p /tmp/usr/share/vdradmin"
fi
local DEST=/etc/vdr/plugins/epgsearch/epgsearch.conf
local SOURCE=${ETC_DIR}/vdradmind.at
if [[ -s ${ROOT}${SOURCE} ]]; then
ewarn "If you used the autotimer of vdradmin,"
ewarn "it is a good idea to convert them now"
ewarn "to use with epgsearch."
ewarn
if [[ ! -d ${ROOT}/etc/vdr/plugins/epgsearch ]]; then
ewarn "# install -d -o vdr -g vdr /etc/vdr/plugins/epgsearch"
fi
local SIZE=0
[[ -e ${DEST} ]] && SIZE=$(grep '^[^#]' ${ROOT}${DEST}|wc -l)
ewarn "If vdr is running with epgsearch-Plugin loaded you can use (recommended):"
local BASE_CMD="${LIB_DIR}/autotimer2searchtimer.pl -i ${SOURCE}"
ewarn "# ${BASE_CMD} -s"
ewarn
ewarn "Else you can use this:"
if [[ ${SIZE} == 0 ]]; then
ewarn "# ${BASE_CMD} -o ${DEST}"
else
ewarn "You already have some timers defined!."
ewarn "# ${BASE_CMD} -o ${DEST}.new"
ewarn
ewarn "You need to merge epgsearch.conf and epgsearch.conf.new on your own."
ewarn
fi
ewarn "# chown vdr:vdr ${DEST}"
ewarn
ewarn "If you are sure that epgsearch has got all your timer,"
ewarn "then you can delete vdradmin-autotimers."
ewarn "# rm ${SOURCE}"
fi
}
pkg_config() {
/usr/bin/vdradmind.pl -c
chown ${VDRADMIN_USER}:${VDRADMIN_GROUP} "${ROOT}"${ETC_DIR}/vdradmind.conf
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2009-01-05 21:02 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2009-01-05 21:02 [gentoo-commits] gentoo-x86 commit in net-www/vdradmin-am: ChangeLog vdradmin-am-3.6.4.ebuild vdradmin-am-3.6.2.ebuild vdradmin-am-3.6.0_rc.ebuild vdradmin-am-3.6.1-r1.ebuild vdradmin-am-3.6.0_beta.ebuild vdradmin-am-3.6.1.ebuild vdradmin-am-3.5.3.ebuild vdradmin-am-3.6.0.ebuild Joerg Bornkessel (hd_brummy)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox