* [gentoo-commits] gentoo-x86 commit in net-misc/networkmanager: metadata.xml ChangeLog networkmanager-0.7.0.ebuild
@ 2008-12-04 23:38 Tomas Chvatal (scarabeus)
0 siblings, 0 replies; only message in thread
From: Tomas Chvatal (scarabeus) @ 2008-12-04 23:38 UTC (permalink / raw
To: gentoo-commits
scarabeus 08/12/04 23:38:05
Modified: metadata.xml ChangeLog
Added: networkmanager-0.7.0.ebuild
Log:
Add networkmanager-0.7.0. Thanks to robert.piasek@member.fsf.org for ebuild. Proxy commit for rbu.
(Portage version: 2.2_rc16/cvs/Linux 2.6.27-gentoo x86_64)
Revision Changes Path
1.5 net-misc/networkmanager/metadata.xml
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/metadata.xml?r1=1.4&r2=1.5
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml 25 Dec 2007 14:30:07 -0000 1.4
+++ metadata.xml 4 Dec 2008 23:38:05 -0000 1.5
@@ -10,4 +10,10 @@
<email>rbu@gentoo.org</email>
<name>Robert Buchholz</name>
</maintainer>
+ <use>
+ <flag name="dhclient">Use dhclient from <pkg>net-misc/dhcp</pkg> for getting ip.</flag>
+ <flag name="dhcpcd">Use <pkg>net-misc/dhcpcd</pkg> for getting ip.</flag>
+ <flag name="nss">Use <pkg>dev-libs/nss</pkg> for cryptography.</flag>
+ <flag name="resolvconf">Use <pkg>net-dns/openresolv</pkg> for managing DNS informations</flag>
+ </use>
</pkgmetadata>
1.34 net-misc/networkmanager/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.34&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/ChangeLog?rev=1.34&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/ChangeLog?r1=1.33&r2=1.34
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v
retrieving revision 1.33
retrieving revision 1.34
diff -u -r1.33 -r1.34
--- ChangeLog 17 Aug 2008 16:16:38 -0000 1.33
+++ ChangeLog 4 Dec 2008 23:38:05 -0000 1.34
@@ -1,6 +1,14 @@
# ChangeLog for net-misc/networkmanager
# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.33 2008/08/17 16:16:38 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.34 2008/12/04 23:38:05 scarabeus Exp $
+
+*networkmanager-0.7.0 (04 Dec 2008)
+
+ 04 Dec 2008; Tomas Chvatal <scarabeus@gentoo.org>
+ +files/networkmanager-0.7.0-confchanges.patch,
+ +files/nm-system-settings.conf, metadata.xml,
+ +networkmanager-0.7.0.ebuild:
+ New version. Thanks to robert.piasek@member.fsf.org for ebuild.
17 Aug 2008; Markus Meier <maekke@gentoo.org> networkmanager-0.6.6.ebuild:
x86 stable, bug #228837
1.1 net-misc/networkmanager/networkmanager-0.7.0.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/networkmanager-0.7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-misc/networkmanager/networkmanager-0.7.0.ebuild?rev=1.1&content-type=text/plain
Index: networkmanager-0.7.0.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.7.0.ebuild,v 1.1 2008/12/04 23:38:05 scarabeus Exp $
inherit eutils
# NetworkManager likes itself with capital letters
MY_P=${P/networkmanager/NetworkManager}
DESCRIPTION="Network configuration and management in an easy way. Desktop environment independent."
HOMEPAGE="http://www.gnome.org/projects/NetworkManager/"
SRC_URI="mirror://gnome/sources/NetworkManager/0.7/${MY_P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~arm ~amd64 ~ppc ~x86"
IUSE="doc nss gnutls dhclient dhcpcd resolvconf"
RDEPEND=">=sys-apps/dbus-1.2
>=dev-libs/dbus-glib-0.75
>=sys-apps/hal-0.5.10
>=net-wireless/wireless-tools-28_pre9
>=dev-libs/glib-2.16
>=sys-auth/policykit-0.8
>=dev-libs/libnl-1.1
>=net-wireless/wpa_supplicant-0.5.10
|| ( sys-libs/e2fsprogs-libs <sys-fs/e2fsprogs-1.41.0 )
gnutls? (
nss? ( >=dev-libs/nss-3.11 )
!nss? ( dev-libs/libgcrypt
net-libs/gnutls ) )
!gnutls? ( >=dev-libs/nss-3.11 )
dhclient? (
dhcpcd? ( >=net-misc/dhcpcd-4.0.0_rc3 )
!dhcpcd? ( >=net-misc/dhcp-3.0.0 ) )
!dhclient? ( >=net-misc/dhcpcd-4.0.0_rc3 )
resolvconf? ( net-dns/openresolv )"
DEPEND="${RDEPEND}
dev-util/pkgconfig
dev-util/intltool
net-dialup/ppp
doc? ( >=dev-util/gtk-doc-1.8 )"
S=${WORKDIR}/${MY_P}
pkg_setup() {
if ! built_with_use net-wireless/wpa_supplicant dbus ; then
eerror "Please rebuild net-wireless/wpa_supplicant with the dbus useflag."
die "Fix wpa_supplicant first."
fi
}
src_unpack () {
unpack ${A}
cd "${S}"
# Fix up the dbus conf file to use plugdev group
epatch "${FILESDIR}/${P}-confchanges.patch"
}
src_compile() {
ECONF="--disable-more-warnings \
--localstatedir=/var \
--with-distro=gentoo \
--with-dbus-sys=/etc/dbus-1/system.d
$(use_enable doc gtk-doc)
$(use_with doc docs)
$(use_with resolvconf)"
# default is dhcpcd (if none or both are specified), ISC dchclient otherwise
if use dhclient ; then
if use dhcpcd ; then
ECONF="${ECONF} --with-dhcp-client=dhcpcd"
else
ECONF="${ECONF} --with-dhcp-client=dhclient"
fi
else
ECONF="${ECONF} --with-dhcp-client=dhcpcd"
fi
# default is NSS (if none or both are specified), GnuTLS otherwise
if use gnutls ; then
if use nss ; then
ECONF="${ECONF} --with-crypto=nss"
else
ECONF="${ECONF} --with-crypto=gnutls"
fi
else
ECONF="${ECONF} --with-crypto=nss"
fi
econf ${ECONF}
emake || die "emake failed"
}
src_install() {
emake DESTDIR="${D}" install || die "emake install failed"
# Need to keep the /var/run/NetworkManager directory
keepdir /var/run/NetworkManager
# Need to keep the /etc/NetworkManager/dispatched.d for dispatcher scripts
keepdir /etc/NetworkManager/dispatcher.d
dodoc AUTHORS ChangeLog NEWS README TODO || die "dodoc failed"
# Add keyfile plugin support
keepdir /etc/NetworkManager/system-connections
insinto /etc/NetworkManager
newins "${FILESDIR}/nm-system-settings.conf" nm-system-settings.conf \
|| die "newins failed"
}
pkg_postinst() {
elog "You need to be in the plugdev group in order to use NetworkManager"
elog "Problems with your hostname getting changed?"
elog ""
elog "Add the following to /etc/dhcp/dhclient.conf"
elog 'send host-name "YOURHOSTNAME";'
elog 'supersede host-name "YOURHOSTNAME";'
elog ""
elog "You will need to restart DBUS if this is your first time"
elog "installing NetworkManager."
elog ""
elog "To save system-wide settings as a user, that user needs to have the"
elog "right policykit privileges. You can add them by running:"
elog 'polkit-auth --grant org.freedesktop.network-manager-settings.system.modify "USERNAME"'
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2008-12-04 23:38 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2008-12-04 23:38 [gentoo-commits] gentoo-x86 commit in net-misc/networkmanager: metadata.xml ChangeLog networkmanager-0.7.0.ebuild Tomas Chvatal (scarabeus)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox