* [gentoo-commits] gentoo-x86 commit in gnome-base/gnome-applets: ChangeLog gnome-applets-2.24.0.1.ebuild
@ 2008-11-06 23:49 Gilles Dartiguelongue (eva)
0 siblings, 0 replies; only message in thread
From: Gilles Dartiguelongue (eva) @ 2008-11-06 23:49 UTC (permalink / raw
To: gentoo-commits
eva 08/11/06 23:49:39
Modified: ChangeLog
Added: gnome-applets-2.24.0.1.ebuild
Log:
New version for GNOME 2.24. Rework Invest UI, do not poll sound volumes, move away from gnome-vfs and bug fixes.
(Portage version: 2.2_rc12/cvs/Linux 2.6.24-gentoo-r8-mactel x86_64)
Revision Changes Path
1.271 gnome-base/gnome-applets/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-applets/ChangeLog?rev=1.271&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-applets/ChangeLog?rev=1.271&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-applets/ChangeLog?r1=1.270&r2=1.271
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-base/gnome-applets/ChangeLog,v
retrieving revision 1.270
retrieving revision 1.271
diff -u -r1.270 -r1.271
--- ChangeLog 25 Sep 2008 15:28:51 -0000 1.270
+++ ChangeLog 6 Nov 2008 23:49:39 -0000 1.271
@@ -1,6 +1,13 @@
# ChangeLog for gnome-base/gnome-applets
# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-applets/ChangeLog,v 1.270 2008/09/25 15:28:51 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-applets/ChangeLog,v 1.271 2008/11/06 23:49:39 eva Exp $
+
+*gnome-applets-2.24.0.1 (06 Nov 2008)
+
+ 06 Nov 2008; Gilles Dartiguelongue <eva@gentoo.org>
+ +gnome-applets-2.24.0.1.ebuild:
+ New version for GNOME 2.24. Rework Invest UI, do not poll sound volumes,
+ move away from gnome-vfs and bug fixes.
25 Sep 2008; Jeroen Roovers <jer@gentoo.org> gnome-applets-2.22.3.ebuild:
Stable for HPPA (bug #236971).
1.1 gnome-base/gnome-applets/gnome-applets-2.24.0.1.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-applets/gnome-applets-2.24.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/gnome-base/gnome-applets/gnome-applets-2.24.0.1.ebuild?rev=1.1&content-type=text/plain
Index: gnome-applets-2.24.0.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-applets/gnome-applets-2.24.0.1.ebuild,v 1.1 2008/11/06 23:49:39 eva Exp $
inherit gnome2 python
DESCRIPTION="Applets for the GNOME Desktop and Panel"
HOMEPAGE="http://www.gnome.org/"
LICENSE="GPL-2 FDL-1.1 LGPL-2"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc64 ~sparc ~x86"
IUSE="acpi apm doc gnome gstreamer hal ipv6"
# TODO: configure says python stuff is optional
# my secret script says cpufrequtils might be needed in RDEPEND
RDEPEND=">=x11-libs/gtk+-2.13
>=dev-libs/glib-2.18.0
>=gnome-base/libgnome-2.8
>=gnome-base/libgnomeui-2.8
>=gnome-base/gconf-2.8
>=gnome-base/gnome-panel-2.13.4
>=x11-libs/libxklavier-2.91
>=x11-libs/libwnck-2.9.3
>=gnome-base/gnome-desktop-2.11.1
>=x11-libs/libnotify-0.3.2
hal? ( >=sys-apps/hal-0.5.3 )
>=sys-apps/dbus-1.1.2
>=dev-libs/dbus-glib-0.74
>=dev-libs/libxml2-2.5.0
>=x11-themes/gnome-icon-theme-2.15.91
>=dev-libs/libgweather-2.22.1
>=virtual/python-2.4
apm? ( sys-apps/apmd )
x11-libs/libX11
gnome? (
>=gnome-base/libgnomekbd-2.21.4.1
gnome-base/gnome-settings-daemon
>=gnome-extra/gucharmap-1.4
>=gnome-base/libgtop-2.11.92
>=dev-python/pygtk-2.6
>=dev-python/gnome-python-2.10 )
gstreamer? (
>=media-libs/gstreamer-0.10.2
>=media-libs/gst-plugins-base-0.10.14 )"
DEPEND="${RDEPEND}
>=app-text/scrollkeeper-0.1.4
>=app-text/gnome-doc-utils-0.3.2
>=dev-util/pkgconfig-0.19
>=dev-util/intltool-0.35
dev-libs/libxslt
~app-text/docbook-xml-dtd-4.3
doc? (
app-text/docbook-sgml-utils
)"
DOCS="AUTHORS ChangeLog NEWS README"
src_unpack() {
gnome2_src_unpack
# disable pyc compiling
mv py-compile py-compile.orig
ln -s $(type -P true) py-compile
}
pkg_setup() {
G2CONF="${G2CONF}
--disable-scrollkeeper
--disable-schemas-install
--enable-flags
$(use_with hal)
$(use_enable ipv6)
--disable-polkit"
if use gstreamer; then
G2CONF="${G2CONF} --with-gstreamer=0.10"
fi
if ! use ppc && ! use apm && ! use acpi; then
G2CONF="${G2CONF} --disable-battstat"
fi
if use ppc && ! use apm; then
G2CONF="${G2CONF} --disable-battstat"
fi
}
src_install() {
gnome2_src_install
local APPLETS="accessx-status battstat charpick cpufreq drivemount geyes \
gkb-new gswitchit gweather invest-applet mini-commander \
mixer modemlights multiload null_applet stickynotes trashapplet"
# modemlights is out because it needs system-tools-backends-1
for applet in ${APPLETS} ; do
docinto ${applet}
for d in AUTHORS ChangeLog NEWS README README.themes TODO ; do
[ -s ${applet}/${d} ] && dodoc ${applet}/${d}
done
done
}
pkg_postinst() {
gnome2_pkg_postinst
if use acpi && ! use hal ; then
elog "It is highly recommended that you install acpid if you use the"
elog "battstat applet to prevent any issues with other applications "
elog "trying to read acpi information."
fi
# check for new python modules on bumps
python_version
python_mod_optimize /usr/$(get_libdir)/python${PYVER}/site-packages/invest
}
pkg_postrm() {
gnome2_pkg_postrm
python_mod_cleanup /usr/$(get_libdir)/python*/site-packages/invest
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2008-11-06 23:49 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2008-11-06 23:49 [gentoo-commits] gentoo-x86 commit in gnome-base/gnome-applets: ChangeLog gnome-applets-2.24.0.1.ebuild Gilles Dartiguelongue (eva)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox