[gentoo-commits] gentoo-x86 commit in app-laptop/hdapsd: ChangeLog hdapsd-20060409-r3.ebuild hdapsd-20060409-r2.ebuild

[gentoo-commits] gentoo-x86 commit in app-laptop/hdapsd: ChangeLog hdapsd-20060409-r3.ebuild hdapsd-20060409-r2.ebuild

[Peter Weller (welp)]

welp        08/10/20 08:45:26

  Modified:             ChangeLog
  Added:                hdapsd-20060409-r3.ebuild
  Removed:              hdapsd-20060409-r2.ebuild
  Log:
  Fix typo in initscript; Bug 196052
  (Portage version: 2.2_rc12/cvs/Linux 2.6.27-gentoomarx x86_64)

Revision  Changes    Path
1.10                 app-laptop/hdapsd/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-laptop/hdapsd/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-laptop/hdapsd/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-laptop/hdapsd/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-laptop/hdapsd/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	30 Mar 2008 22:29:51 -0000	1.9
+++ ChangeLog	20 Oct 2008 08:45:26 -0000	1.10
@@ -1,6 +1,12 @@
 # ChangeLog for app-laptop/hdapsd
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-laptop/hdapsd/ChangeLog,v 1.9 2008/03/30 22:29:51 welp Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-laptop/hdapsd/ChangeLog,v 1.10 2008/10/20 08:45:26 welp Exp $
+
+*hdapsd-20060409-r3 (20 Oct 2008)
+
+  20 Oct 2008; <welp@gentoo.org> files/hdapsd.init,
+  -hdapsd-20060409-r2.ebuild, +hdapsd-20060409-r3.ebuild:
+  Fix typo in initscript; Bug 196052
 
 *hdapsd-20060409-r2 (30 Mar 2008)
 



1.1                  app-laptop/hdapsd/hdapsd-20060409-r3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-laptop/hdapsd/hdapsd-20060409-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-laptop/hdapsd/hdapsd-20060409-r3.ebuild?rev=1.1&content-type=text/plain

Index: hdapsd-20060409-r3.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-laptop/hdapsd/hdapsd-20060409-r3.ebuild,v 1.1 2008/10/20 08:45:26 welp Exp $

inherit eutils linux-info

PROTECT_VER="2"

DESCRIPTION="IBM ThinkPad Harddrive Active Protection disk head parking daemon"
HOMEPAGE="http://hdaps.sourceforge.net/"
SRC_URI="mirror://gentoo/${P}.c.bz2
	mirror://gentoo/hdaps_protect-patches-${PROTECT_VER}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"

IUSE=""
RDEPEND=""

S="${WORKDIR}"

src_compile() {
	# We require the hdaps module; problem is that it can come from either
	# kernel sources or from the tp_smapi package. This hack is required because
	# the linux-info eclass doesn't export any more suitable config checkers.
	# Here we just skip calling its pkg_setup() in case the module is provided
	# by the package.

	if ! has_version app-laptop/tp_smapi || ! built_with_use app-laptop/tp_smapi hdaps; then
		CONFIG_CHECK="SENSORS_HDAPS"
		ERROR_SENSORS_HDAPS="${P} requires support for HDAPS (CONFIG_SENSORS_HDAPS)"
		linux-info_pkg_setup
	fi

	cd "${WORKDIR}"
	gcc ${CFLAGS} "${P}".c -o hdapsd || die "failed to compile"
}

src_install() {
	dosbin "${WORKDIR}"/hdapsd
	newconfd "${FILESDIR}"/hdapsd.conf hdapsd
	newinitd "${FILESDIR}"/hdapsd.init hdapsd

	# Install our kernel patches
	dodoc *.patch "${FILESDIR}"/hdaps-Z60m.patch
}

# Yes, this sucks as the source location may change, kernel sources may not be
# installed, but we try our best anyway
kernel_patched() {
	get_version

	if grep -qs "blk_protect_register" "${KERNEL_DIR}"/block/ll_rw_blk.c ; then
		einfo "Your kernel has already been patched for blk_freeze"
		return 0
	fi

	return 1
}

pkg_config() {
	kernel_patched && return 0

	local docdir="${ROOT}/usr/share/doc/${PF}/"
	local p="hdaps_protect-${KV_MAJOR}.${KV_MINOR}.${KV_PATCH}.patch.gz"

	# We need to find our FILESDIR as it's now lost
	if [[ ! -e ${docdir}/${p} ]] ; then
		eerror "We don't have a patch for kernel ${KV_MAJOR}.${KV_MINOR}.${KV_PATCH} yet"
		return 1
	fi

	if [[ ! -d ${KERNEL_DIR} ]] ; then
		eerror "Kernel sources not found!"
		return 1
	fi

	cd "${KERNEL_DIR}"
	epatch "${docdir}/${p}"

	# This is just a nice to have for me as I use a Z60m myself
	if ! grep -q "Z60m" "${KERNEL_DIR}"/drivers/hwmon/hdaps.c ; then
		epatch "${docdir}"/hdaps-Z60m.patch.gz
	fi

	echo
	einfo "Now you should rebuild your kernel, its modules"
	einfo "and then install them."
}

pkg_postinst(){
	[[ -n $(ls "${ROOT}"/sys/block/*/queue/protect 2>/dev/null) ]] && return 0

	if ! kernel_patched ; then
		ewarn "Your kernel has NOT been patched for blk_freeze"
		elog "The ebuild can attempt to patch your kernel like so"
		elog "   emerge --config =${PF}"
	fi
}