[gentoo-commits] gentoo-x86 commit in games-strategy/ufo-ai: metadata.xml ChangeLog ufo-ai-2.2.1.ebuild

["Alfredo Tupone (tupone)" <tupone@gentoo.org>]

tupone      08/10/04 19:46:06

  Modified:             metadata.xml ChangeLog
  Added:                ufo-ai-2.2.1.ebuild
  Log:
  Version bump to 2.2.1 Bug #206145 by Jaak Ristioja
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.2                  games-strategy/ufo-ai/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/ufo-ai/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/ufo-ai/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/ufo-ai/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/ufo-ai/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	11 Mar 2004 02:26:22 -0000	1.1
+++ metadata.xml	4 Oct 2008 19:46:06 -0000	1.2
@@ -2,4 +2,7 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 <herd>games</herd>
+<use>
+    <flag name='editor'>Build map editor</flag>
+</use>
 </pkgmetadata>



1.20                 games-strategy/ufo-ai/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/ufo-ai/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/ufo-ai/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/ufo-ai/ChangeLog?r1=1.19&r2=1.20

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/ufo-ai/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog	24 Aug 2008 14:56:35 -0000	1.19
+++ ChangeLog	4 Oct 2008 19:46:06 -0000	1.20
@@ -1,6 +1,12 @@
 # ChangeLog for games-strategy/ufo-ai
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/ufo-ai/ChangeLog,v 1.19 2008/08/24 14:56:35 tupone Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/ufo-ai/ChangeLog,v 1.20 2008/10/04 19:46:06 tupone Exp $
+
+*ufo-ai-2.2.1 (04 Oct 2008)
+
+  04 Oct 2008; <tupone@gentoo.org> +files/ufo-ai-2.2.1-gentoo.patch,
+  +ufo-ai-2.2.1.ebuild:
+  Version bump to 2.2.1 Bug #206145 by Jaak Ristioja
 
   24 Aug 2008; Tupone Alfredo <tupone@gentoo.org>
   +files/ufo-ai-2.1.1-dprintf.patch, ufo-ai-2.1.1-r1.ebuild:



1.1                  games-strategy/ufo-ai/ufo-ai-2.2.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/ufo-ai/ufo-ai-2.2.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/ufo-ai/ufo-ai-2.2.1.ebuild?rev=1.1&content-type=text/plain

Index: ufo-ai-2.2.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/ufo-ai/ufo-ai-2.2.1.ebuild,v 1.1 2008/10/04 19:46:06 tupone Exp $

inherit eutils autotools games

MY_P="${P/o-a/oa}"

DESCRIPTION="UFO: Alien Invasion - X-COM inspired strategy game"
HOMEPAGE="http://ufoai.sourceforge.net/"
SRC_URI="mirror://sourceforge/ufoai/${MY_P}-source.tar.bz2
	mirror://sourceforge/ufoai/${MY_P}-data.tar"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="dedicated doc editor mmx"

# Dependencies and more instructions can be found here:
# http://ufoai.ninex.info/wiki/index.php/Compile_for_Linux
RDEPEND="!dedicated? (
		virtual/opengl
		virtual/glu
		media-libs/libsdl
		media-libs/sdl-ttf
		media-libs/sdl-mixer
		media-libs/jpeg
		media-libs/libpng
		media-libs/libogg
		media-libs/libvorbis
		x11-proto/xf86vidmodeproto
	)
	editor? ( media-libs/jpeg )
	net-misc/curl
	sys-devel/gettext"

DEPEND="${RDEPEND}
	doc? ( virtual/latex-base )"

S=${WORKDIR}/${MY_P}-source

src_unpack() {
	unpack ${A}
	cd "${S}"
	# move data from packages to source dir
	mv "${WORKDIR}/base" "${S}"

	# Set basedir & fixes bug in finding text files - it should use fs_basedir
	epatch "${FILESDIR}"/${P}-gentoo.patch

	sed -i \
		-e "s:@GENTOO_DATADIR@:${GAMES_DATADIR}/${PN}:" \
		src/common/files.c \
		src/tools/gtkradiant/games/ufoai.game \
		src/client/cl_main.c \
		src/client/cl_language.c \
		|| die "sed failed"
}

src_compile() {
	egamesconf \
		$(use_enable mmx) \
		--enable-release \
		$(use_enable editor ufo2map) \
		--enable-dedicated \
		$(use_enable !dedicated client) \
		--with-shaders

	emake lang || die "emake langs failed"

	if use doc ; then
		emake pdf-manual || die "emake pdf-manual failed (USE=doc)"
	fi

	emake || die "emake failed"
}

src_install() {
	# server
	dogamesbin ufoded || die "Failed installing server"
	newicon src/ports/linux/installer/data/ufo.xpm ${PN}.xpm \
		|| die "Failed installing icon"
	make_desktop_entry ${PN}-ded "UFO: Alien Invasion Server" ${PN}.xpm
	if ! use dedicated ; then
		# client
		newgamesbin ufo ${PN} || die "Failed installing client"
		make_desktop_entry ${PN} "UFO: Alien Invasion" ${PN}.xpm
	fi

	if use editor ; then
		dogamesbin ufo2map || die "Failed installing editor"
	fi

	insinto "${GAMES_DATADIR}"/${PN}
	doins -r base || die "doins -r failed"
	if use doc ; then
		dodoc src/docs/tex/ufo-manual_EN.pdf || die "Failed installing manual"
	fi

	prepgamesdirs
}