[gentoo-commits] gentoo-x86 commit in x11-misc/google-gadgets: ChangeLog google-gadgets-0.10.2-r2.ebuild google-gadgets-0.10.2-r1.ebuild google-gadgets-0.10.2.ebuild

[gentoo-commits] gentoo-x86 commit in x11-misc/google-gadgets: ChangeLog google-gadgets-0.10.2-r2.ebuild google-gadgets-0.10.2-r1.ebuild google-gadgets-0.10.2.ebuild

[Peter Alfredsen (loki_val)]

loki_val    08/09/26 11:30:29

  Modified:             ChangeLog
  Added:                google-gadgets-0.10.2-r2.ebuild
  Removed:              google-gadgets-0.10.2-r1.ebuild
                        google-gadgets-0.10.2.ebuild
  Log:
  Fix for 'undefined symbol: JS_SetOperationCallback', blocking spidermonkey. Shifting to EAPI 2 and losing a lot of cruft. Fix sysdeps.h being installed the wrong place, reported by Sput.
  (Portage version: 2.2_rc10/cvs/Linux 2.6.25.8 i686)

Revision  Changes    Path
1.11                 x11-misc/google-gadgets/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/google-gadgets/ChangeLog?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/google-gadgets/ChangeLog?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/google-gadgets/ChangeLog?r1=1.10&r2=1.11

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/google-gadgets/ChangeLog,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- ChangeLog	24 Sep 2008 15:13:30 -0000	1.10
+++ ChangeLog	26 Sep 2008 11:30:28 -0000	1.11
@@ -1,6 +1,15 @@
 # ChangeLog for x11-misc/google-gadgets
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/google-gadgets/ChangeLog,v 1.10 2008/09/24 15:13:30 loki_val Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/google-gadgets/ChangeLog,v 1.11 2008/09/26 11:30:28 loki_val Exp $
+
+*google-gadgets-0.10.2-r2 (26 Sep 2008)
+
+  26 Sep 2008; Peter Alfredsen <loki_val@gentoo.org>
+  -google-gadgets-0.10.2.ebuild, -google-gadgets-0.10.2-r1.ebuild,
+  +google-gadgets-0.10.2-r2.ebuild:
+  Fix for 'undefined symbol: JS_SetOperationCallback', blocking
+  spidermonkey. Shifting to EAPI 2 and losing a lot of cruft. Fix sysdeps.h
+  being installed the wrong place, reported by Sput.
 
 *google-gadgets-0.10.2-r1 (24 Sep 2008)
 



1.1                  x11-misc/google-gadgets/google-gadgets-0.10.2-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/google-gadgets/google-gadgets-0.10.2-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-misc/google-gadgets/google-gadgets-0.10.2-r2.ebuild?rev=1.1&content-type=text/plain

Index: google-gadgets-0.10.2-r2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/google-gadgets/google-gadgets-0.10.2-r2.ebuild,v 1.1 2008/09/26 11:30:28 loki_val Exp $

EAPI=2

inherit base autotools multilib eutils fdo-mime

MY_PN=${PN}-for-linux
MY_P=${MY_PN}-${PV}
DESCRIPTION="Cool gadgets from Google for your Desktop"
HOMEPAGE="http://code.google.com/p/google-gadgets-for-linux/"
SRC_URI="http://${MY_PN}.googlecode.com/files/${MY_P}.tar.bz2"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+dbus debug +gtk +qt4 +gstreamer"

# Weird things happen when we start mix-n-matching, so for the time being
# I've just locked the deps to the versions I had as of Summer 2008. With any
# luck, they'll be stable when we get to stabling this package.

# FIXME: ggl should be able to compile with xulrunner-1.9, xulrunner-1.8 and
# various combinations of mozilla and spidermonkey. Since its configure script
# is broken, though, I've hacked it to depend only on xulrunner-1.9, to avoid
# mid-air symbol collisions. A giant bonanza of automagic is what it takes to get
# this to work. I say blah. Blocking spidermonkey to avoid incorrect linking.

RDEPEND="x11-libs/libX11
	x11-libs/libXext
	>=dev-libs/libxml2-2.6.32
	sys-libs/zlib
	net-libs/xulrunner:1.9
	!dev-lang/spidermonkey

	dbus? ( sys-apps/dbus )

	gstreamer? (	>=media-libs/gstreamer-0.10.19
			>=media-libs/gst-plugins-base-0.10.19 )

	gtk? (	dbus? ( >=dev-libs/dbus-glib-0.74 )
		>=x11-libs/cairo-1.6.4
		>=x11-libs/gtk+-2.12.10
		>=x11-libs/pango-1.20.3
		gnome-base/librsvg
		>=net-misc/curl-7.18.2[ssl,-nss,-gnutls]
		>=dev-libs/atk-1.22.0 )

	qt4? (	dbus? ( >=x11-libs/qt-dbus-4.4.0 )
		>=x11-libs/qt-core-4.4.0
		>=x11-libs/qt-webkit-4.4.0
		>=x11-libs/qt-xmlpatterns-4.4.0
		>=x11-libs/qt-opengl-4.4.0
		>=x11-libs/qt-script-4.4.0 )"
DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.20"

S="${WORKDIR}/${MY_P}"

RESTRICT="test"

pkg_setup() {

	# If a non-google, non-qt4 and non-gtk host system for google-gadgets is ever developed,
	# I'll consider changing the error below.
	if ! use gtk && ! use qt4
	then
		eerror "You must choose which toolkit to build for. Either qt4 or gtk can be"
		eerror "chosen. For qt4, see also above. To enable \$toolkit, do:"
		eerror "echo \"${CATEGORY}/${PN} \$toolkit\" >> /etc/portage/package.use"
		die "You need to choose a toolkit"
	fi

	if ! use gstreamer
	then
		ewarn "Disabling gstreamer disables the multimedia functions of ${PN}."
		ewarn "This is not recommended. To enable gstreamer, do:"
		ewarn "echo \"${CATEGORY}/${PN} gstreamer\" >> /etc/portage/package.use"
	fi

}

src_unpack() {
	base_src_unpack
	cd "${S}"

	sed -i -r \
		-e '/^GGL_SYSDEPS_INCLUDE_DIR/ c\GGL_SYSDEPS_INCLUDE_DIR=$GGL_INCLUDE_DIR' \
		configure.ac||die "404"
	eautoreconf
}

src_configure() {
	#For the time being, the smjs-script runtime is required for both gtk and qt
	#versions, but the goal is to make the qt4 version depend only on qt-script.
	has_pkg_smjs=no \
	econf	--disable-dependency-tracking \
		--disable-update-desktop-database \
		--disable-update-mime-database \
		--disable-werror \
		--enable-libxml2-xml-parser \
		--enable-smjs-script-runtime \
		--with-gtkmozembed=libxul \
		--with-smjs-cppflags=-I/usr/include/nspr \
		--with-smjs-libdir=/usr/$(get_libdir)/xulrunner-1.9 \
		--with-smjs-incdir=/usr/include/xulrunner-1.9/unstable \
		$(use_enable debug) \
		$(use_enable dbus libggadget-dbus) \
		$(use_enable gstreamer gst-audio-framework) \
		$(use_enable gstreamer gst-mediaplayer-element) \
		$(use_enable gtk gtk-host) \
		$(use_enable gtk libggadget-gtk ) \
		$(use_enable gtk gtkmoz-browser-element) \
		$(use_enable gtk gtk-system-framework) \
		$(use_enable gtk curl_xml_http_request) \
		$(use_enable qt4 qt-host) \
		$(use_enable qt4 libggadget-qt) \
		$(use_enable qt4 qt-system-framework) \
		$(use_enable qt4 qtwebkit-browser-element) \
		$(use_enable qt4 qt-xml-http-request) \
		$(use_enable qt4 qt-script-runtime) \
		|| die "econf failed"
}

src_compile() {
	default_src_compile
	#See https://bugs.gentoo.org/238753
}

src_test() {
	#If someone wants to guarantee that emake will not make
	#tests fail promiscuosly, please do, otherwise we're using make.
	make check &> "${WORKDIR}"/check
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}

curl_die() {
	eerror "net-misc/curl must be built with these use flags: ssl -gnutls -nss"
	eerror "to do so, do:"
	eerror 'echo "net-misc/curl ssl -gnutls -nss" >> /etc/portage/package.use'
	die "Your net-misc/curl was misconfigured."
}