[gentoo-commits] gentoo-x86 commit in www-apps/twiki: ChangeLog twiki-4.2.2.ebuild

[gentoo-commits] gentoo-x86 commit in www-apps/twiki: ChangeLog twiki-4.2.2.ebuild

[Gunnar Wrobel (wrobel)]

wrobel      08/09/10 08:15:49

  Modified:             ChangeLog
  Added:                twiki-4.2.2.ebuild
  Log:
  Added twiki-4.2.2 (#234602).
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.44                 www-apps/twiki/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/twiki/ChangeLog?rev=1.44&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/twiki/ChangeLog?rev=1.44&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/twiki/ChangeLog?r1=1.43&r2=1.44

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-apps/twiki/ChangeLog,v
retrieving revision 1.43
retrieving revision 1.44
diff -u -r1.43 -r1.44
--- ChangeLog	24 Feb 2008 00:00:38 -0000	1.43
+++ ChangeLog	10 Sep 2008 08:15:49 -0000	1.44
@@ -1,6 +1,11 @@
 # ChangeLog for www-apps/twiki
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-apps/twiki/ChangeLog,v 1.43 2008/02/24 00:00:38 hollow Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-apps/twiki/ChangeLog,v 1.44 2008/09/10 08:15:49 wrobel Exp $
+
+*twiki-4.2.2 (10 Sep 2008)
+
+  10 Sep 2008; wrobel@gentoo.org +twiki-4.2.2.ebuild:
+  Added twiki-4.2.2 (#234602).
 
 *twiki-4.2.0 (24 Feb 2008)
 



1.1                  www-apps/twiki/twiki-4.2.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/twiki/twiki-4.2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-apps/twiki/twiki-4.2.2.ebuild?rev=1.1&content-type=text/plain

Index: twiki-4.2.2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/twiki/twiki-4.2.2.ebuild,v 1.1 2008/09/10 08:15:49 wrobel Exp $

WEBAPP_NO_AUTO_INSTALL="yes"

inherit webapp

MY_PN="TWiki"

DESCRIPTION="A Web Based Collaboration Platform"
HOMEPAGE="http://twiki.org/"
SRC_URI="mirror://sourceforge/${PN}/${MY_PN}-${PV}.tgz"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE=""

S="${WORKDIR}"

RDEPEND=">=app-text/rcs-5.7
	sys-apps/diffutils
	>=dev-lang/perl-5.8
	dev-perl/Algorithm-Diff
	dev-perl/CGI-Session
	dev-perl/Digest-SHA1
	dev-perl/HTML-Parser
	dev-perl/locale-maketext-lexicon
	dev-perl/Text-Diff
	dev-perl/URI
	virtual/cron
	>=virtual/perl-CGI-3.20
	virtual/perl-digest-base
	virtual/perl-File-Spec
	virtual/perl-libnet
	virtual/perl-Time-Local"

need_httpd_cgi

src_install() {
	webapp_src_preinst

	dodoc AUTHORS COPYRIGHT readme.txt
	dohtml T*.html INSTALL.html
	rm -f readme.txt T*.html INSTALL.html

	mv bin/LocalLib.cfg{.txt,}

	insinto "${MY_HTDOCSDIR}"
	doins -r .

	for f in $(find data pub); do
		webapp_serverowned "${MY_HTDOCSDIR}"/${f}
	done

	for f in bin/setlib.cfg bin/LocalLib.cfg; do
		webapp_configfile "${MY_HTDOCSDIR}"/${f}
	done

	webapp_hook_script "${FILESDIR}"/reconfig
	webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
	webapp_postupgrade_txt en "${FILESDIR}"/postupgrade-en.txt

	webapp_src_install
}

pkg_postinst() {
	ewarn
	ewarn "If you are upgrading from an older version of TWiki, back up your"
	ewarn "data/ and pub/ directories and any local changes before upgrading!"
	ewarn
	ewarn "You are _strongly_ encouraged to to read the upgrade guide:"
	ewarn "http://twiki.org/cgi-bin/view/TWiki/TWikiDocumentation"
	ewarn
	webapp_pkg_postinst
}