[gentoo-commits] gentoo-x86 commit in net-dialup/rp-pppoe: ChangeLog rp-pppoe-3.10-r1.ebuild rp-pppoe-3.10.ebuild

[gentoo-commits] gentoo-x86 commit in net-dialup/rp-pppoe: ChangeLog rp-pppoe-3.10-r1.ebuild rp-pppoe-3.10.ebuild

[Alin Nastac (mrness)]

mrness      08/08/23 03:52:46

  Modified:             ChangeLog
  Added:                rp-pppoe-3.10-r1.ebuild
  Removed:              rp-pppoe-3.10.ebuild
  Log:
  Append $ETH to $PLUGIN_OPTS (#235369).
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.100                net-dialup/rp-pppoe/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-dialup/rp-pppoe/ChangeLog?rev=1.100&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-dialup/rp-pppoe/ChangeLog?rev=1.100&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-dialup/rp-pppoe/ChangeLog?r1=1.99&r2=1.100

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dialup/rp-pppoe/ChangeLog,v
retrieving revision 1.99
retrieving revision 1.100
diff -u -r1.99 -r1.100
--- ChangeLog	22 Aug 2008 21:45:31 -0000	1.99
+++ ChangeLog	23 Aug 2008 03:52:46 -0000	1.100
@@ -1,6 +1,13 @@
 # ChangeLog for net-dialup/rp-pppoe
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dialup/rp-pppoe/ChangeLog,v 1.99 2008/08/22 21:45:31 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dialup/rp-pppoe/ChangeLog,v 1.100 2008/08/23 03:52:46 mrness Exp $
+
+*rp-pppoe-3.10-r1 (23 Aug 2008)
+
+  23 Aug 2008; Alin Năstac <mrness@gentoo.org>
+  files/rp-pppoe-3.10-plugin-options.patch, -rp-pppoe-3.10.ebuild,
+  +rp-pppoe-3.10-r1.ebuild:
+  Append $ETH to $PLUGIN_OPTS (#235369).
 
   22 Aug 2008; Markus Meier <maekke@gentoo.org> rp-pppoe-3.8-r2.ebuild:
   amd64 stable, bug #227197



1.1                  net-dialup/rp-pppoe/rp-pppoe-3.10-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-dialup/rp-pppoe/rp-pppoe-3.10-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-dialup/rp-pppoe/rp-pppoe-3.10-r1.ebuild?rev=1.1&content-type=text/plain

Index: rp-pppoe-3.10-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dialup/rp-pppoe/rp-pppoe-3.10-r1.ebuild,v 1.1 2008/08/23 03:52:46 mrness Exp $

WANT_AUTOCONF="latest"
WANT_AUTOMAKE="latest"

inherit eutils flag-o-matic autotools

DESCRIPTION="A user-mode PPPoE client and server suite for Linux"
HOMEPAGE="http://www.roaringpenguin.com/pppoe/"
SRC_URI="http://www.roaringpenguin.com/files/download/${P}.tar.gz
	ftp://ftp.samba.org/pub/ppp/ppp-2.4.4.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="X"

RDEPEND="net-dialup/ppp
	X? ( dev-lang/tk )"
# see bug #230491
DEPEND="|| ( <sys-kernel/linux-headers-2.6.24 >=sys-kernel/linux-headers-2.6.25 )
	${RDEPEND}"

src_unpack() {
	unpack ${A} || die "failed to unpack"

	# Patch to enable integration of pppoe-start and pppoe-stop with
	# baselayout-1.11.x so that the pidfile can be found reliably per interface
	epatch "${FILESDIR}/${P}-gentoo-netscripts.patch"

	epatch "${FILESDIR}/${P}-username-charset.patch" # bug 82410
	epatch "${FILESDIR}/${P}-plugin-options.patch"
	epatch "${FILESDIR}/${P}-autotools.patch"
	epatch "${FILESDIR}/${P}-session-offset.patch" # bug 204476
	epatch "${FILESDIR}/${P}-linux-headers.patch"

	cd "${S}"/src
	eautoreconf
}

src_compile() {
	addpredict /dev/ppp

	cd "${S}/src"
	econf --enable-plugin=../../ppp-2.4.4 || die "econf failed"
	emake || die "emake failed"

	if use X; then
		make -C "${S}/gui" || die "gui make failed"
	fi
}

src_install () {
	cd "${S}/src"
	emake DESTDIR="${D}" docdir=/usr/share/doc/${PF} install \
		|| die "install failed"

	#Don't use compiled rp-pppoe plugin - see pkg_preinst below
	rm "${D}/etc/ppp/plugins/rp-pppoe.so"

	prepalldocs

	if use X; then
		emake -C "${S}/gui" DESTDIR="${D}" datadir=/usr/share/doc/${PF}/ install \
			|| die "gui install failed"
		dosym /usr/share/doc/${PF}/tkpppoe /usr/share/tkpppoe
	fi
}

pkg_preinst() {
	# Use the rp-pppoe plugin that comes with net-dialup/pppd
	local PPPD_VER=`best_version net-dialup/ppp`
	PPPD_VER=${PPPD_VER#*/*-} #reduce it to ${PV}-${PR}
	PPPD_VER=${PPPD_VER%%-*} #reduce it to ${PV}
	if [ -n "${PPPD_VER}" ] && [ -f "${ROOT}/usr/lib/pppd/${PPPD_VER}/rp-pppoe.so" ] ; then
		dosym /usr/lib/pppd/${PPPD_VER}/rp-pppoe.so /etc/ppp/plugins/rp-pppoe.so
	fi
}

pkg_postinst() {
	elog "Use pppoe-setup to configure your dialup connection."
}