* [gentoo-commits] gentoo-x86 commit in app-misc/ca-certificates: ChangeLog ca-certificates-20080809.ebuild
@ 2008-08-20 20:29 Robin H. Johnson (robbat2)
0 siblings, 0 replies; only message in thread
From: Robin H. Johnson (robbat2) @ 2008-08-20 20:29 UTC (permalink / raw
To: gentoo-commits
robbat2 08/08/20 20:29:04
Modified: ChangeLog
Added: ca-certificates-20080809.ebuild
Log:
Version bump.
(Portage version: 2.2_rc8/cvs/Linux 2.6.27-rc1-10246-gca5de40 x86_64)
Revision Changes Path
1.26 app-misc/ca-certificates/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/ca-certificates/ChangeLog?rev=1.26&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/ca-certificates/ChangeLog?rev=1.26&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/ca-certificates/ChangeLog?r1=1.25&r2=1.26
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/ca-certificates/ChangeLog,v
retrieving revision 1.25
retrieving revision 1.26
diff -p -w -b -B -u -u -r1.25 -r1.26
--- ChangeLog 18 Aug 2008 19:04:16 -0000 1.25
+++ ChangeLog 20 Aug 2008 20:29:03 -0000 1.26
@@ -1,6 +1,12 @@
# ChangeLog for app-misc/ca-certificates
# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/ca-certificates/ChangeLog,v 1.25 2008/08/18 19:04:16 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/ca-certificates/ChangeLog,v 1.26 2008/08/20 20:29:03 robbat2 Exp $
+
+*ca-certificates-20080809 (20 Aug 2008)
+
+ 20 Aug 2008; Robin H. Johnson <robbat2@gentoo.org>
+ +ca-certificates-20080809.ebuild:
+ Version bump.
18 Aug 2008; Brent Baude <ranger@gentoo.org>
ca-certificates-20080514-r2.ebuild:
1.1 app-misc/ca-certificates/ca-certificates-20080809.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/ca-certificates/ca-certificates-20080809.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/ca-certificates/ca-certificates-20080809.ebuild?rev=1.1&content-type=text/plain
Index: ca-certificates-20080809.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/ca-certificates/ca-certificates-20080809.ebuild,v 1.1 2008/08/20 20:29:03 robbat2 Exp $
inherit eutils
DESCRIPTION="Common CA Certificates PEM files"
HOMEPAGE="http://packages.debian.org/sid/ca-certificates"
SRC_URI="mirror://debian/pool/main/c/${PN}/${PN}_${PV}_all.deb"
LICENSE="MPL-1.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE=""
DEPEND="|| ( >=sys-apps/coreutils-6.10-r1 sys-apps/mktemp sys-freebsd/freebsd-ubin )"
RDEPEND="${DEPEND}
dev-libs/openssl
sys-apps/debianutils"
S=${WORKDIR}
src_unpack() {
unpack ${A}
unpack ./data.tar.gz
rm -f control.tar.gz data.tar.gz debian-binary
epatch "${FILESDIR}"/ca-certificates-20080514-warn-on-bad-symlinks.patch
}
pkg_setup() {
# For the conversion to having it in CONFIG_PROTECT_MASK,
# we need to tell users about it once manually first.
[[ -f /etc/env.d/98ca-certificates ]] \
|| ewarn "You should run update-ca-certificates manually after etc-update"
}
src_install() {
cp -pPR * "${D}"/ || die "installing data failed"
(
echo "# Automatically generated by ${CAT}/${PF}"
echo "# $(date -u)"
echo "# Do not edit."
cd "${D}"/usr/share/ca-certificates
find . -name '*.crt' | sort | cut -b3-
) > "${D}"/etc/ca-certificates.conf
mv "${D}"/usr/share/doc/{ca-certificates,${PF}} || die
prepalldocs
dodir /etc/env.d/
echo 'CONFIG_PROTECT_MASK="/etc/ca-certificates.conf"' \
>"${D}/etc/env.d/98ca-certificates"
}
pkg_postinst() {
local badcerts=0
for c in `find -L "${ROOT}"/etc/ssl/certs/ -type l`; do
ewarn "Broken symlink for a certificate at $c"
badcerts=1
done
if [[ $badcerts -eq 1 ]]; then
ewarn "You MUST remove the above broken symlinks"
ewarn "Otherwise any SSL validation that use the directory may fail!"
fi
[[ ${ROOT} != "/" ]] && return 0
# However it's too overzealous when the user has custom certs in place.
# --fresh is to clean up dangling symlinks
update-ca-certificates
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2008-08-20 20:29 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2008-08-20 20:29 [gentoo-commits] gentoo-x86 commit in app-misc/ca-certificates: ChangeLog ca-certificates-20080809.ebuild Robin H. Johnson (robbat2)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox