* [gentoo-commits] gentoo-x86 commit in media-video/vlc: ChangeLog vlc-0.9.0_beta2.ebuild
@ 2008-07-14 12:51 Alexis Ballier (aballier)
0 siblings, 0 replies; 3+ messages in thread
From: Alexis Ballier (aballier) @ 2008-07-14 12:51 UTC (permalink / raw
To: gentoo-commits
aballier 08/07/14 12:51:10
Modified: ChangeLog
Added: vlc-0.9.0_beta2.ebuild
Log:
bump to test2
(Portage version: 2.2_rc1/cvs/Linux 2.6.25.7 x86_64)
Revision Changes Path
1.357 media-video/vlc/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/vlc/ChangeLog?rev=1.357&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/vlc/ChangeLog?rev=1.357&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/vlc/ChangeLog?r1=1.356&r2=1.357
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/vlc/ChangeLog,v
retrieving revision 1.356
retrieving revision 1.357
diff -u -r1.356 -r1.357
--- ChangeLog 14 Jul 2008 10:49:24 -0000 1.356
+++ ChangeLog 14 Jul 2008 12:51:09 -0000 1.357
@@ -1,6 +1,11 @@
# ChangeLog for media-video/vlc
# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/ChangeLog,v 1.356 2008/07/14 10:49:24 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/ChangeLog,v 1.357 2008/07/14 12:51:09 aballier Exp $
+
+*vlc-0.9.0_beta2 (14 Jul 2008)
+
+ 14 Jul 2008; Alexis Ballier <aballier@gentoo.org> +vlc-0.9.0_beta2.ebuild:
+ bump to test2
14 Jul 2008; Raúl Porcel <armin76@gentoo.org> vlc-0.8.6i.ebuild:
sparc/x86 stable wrt #230692
1.1 media-video/vlc/vlc-0.9.0_beta2.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/vlc/vlc-0.9.0_beta2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/vlc/vlc-0.9.0_beta2.ebuild?rev=1.1&content-type=text/plain
Index: vlc-0.9.0_beta2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-0.9.0_beta2.ebuild,v 1.1 2008/07/14 12:51:09 aballier Exp $
EAPI="1"
WANT_AUTOMAKE=latest
WANT_AUTOCONF=latest
inherit eutils multilib autotools toolchain-funcs gnome2 nsplugins qt4 flag-o-matic
MY_PV="${PV/_/-}"
MY_PV="${MY_PV/-beta/-test}"
MY_P="${PN}-${MY_PV}"
VLC_SNAPSHOT_TIME="0013"
PATCHLEVEL="58"
M4_TARBALL_VERSION="1"
DESCRIPTION="VLC media player - Video player and streamer"
HOMEPAGE="http://www.videolan.org/vlc/"
if [[ "${P}" == *_alpha* ]]; then # Snapshots taken from nightlies.videolan.org
SRC_URI="http://nightlies.videolan.org/build/source/trunk-${PV/*_alpha/}-${VLC_SNAPSHOT_TIME}/${PN}-snapshot-${PV/*_alpha/}.tar.bz2"
MY_P="${P/_alpha*/}-git"
elif [[ "${P}" == *_p* ]]; then # Snapshots
SRC_URI="mirror://gentoo/${P}.tar.bz2"
MY_P="${P}"
elif [[ "${MY_P}" == "${P}" ]]; then
SRC_URI="http://download.videolan.org/pub/videolan/${PN}/${PV}/${P}.tar.bz2"
else
SRC_URI="http://download.videolan.org/pub/videolan/testing/${MY_P}/${MY_P}.tar.bz2"
fi
SRC_URI="${SRC_URI}
mirror://gentoo/${PN}-patches-${PATCHLEVEL}.tar.bz2
mirror://gentoo/${PN}-m4-${M4_TARBALL_VERSION}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="a52 aac aalib alsa altivec arts atmo avahi bidi cdda cddb cdio dbus dc1394
debug directfb dts dvb dvd esd fbcon fluidsynth +ffmpeg flac ggi gnome gnutls hal httpd
id3tag jack libcaca +libgcrypt libnotify lirc live lua matroska mmx modplug mp3 mpeg
musepack musicbrainz ncurses nsplugin ogg opengl optimisememory oss png pulseaudio pvr +qt4
remoteosd rtsp samba sdl sdl-image seamonkey shout skins speex sse stream svg svga taglib
theora truetype twolame upnp v4l v4l2 vcd vcdx vlm vorbis win32codecs
X x264 xinerama xml xosd xulrunner xv"
RDEPEND="
sys-libs/zlib
media-libs/libdvbpsi
a52? ( >=media-libs/a52dec-0.7.4-r3 )
aalib? ( media-libs/aalib )
aac? ( >=media-libs/faad2-2.6.1 )
alsa? ( media-libs/alsa-lib )
arts? ( kde-base/arts )
avahi? ( >=net-dns/avahi-0.6 )
bidi? ( >=dev-libs/fribidi-0.10.4 )
cdda? ( >=dev-libs/libcdio-0.72
cddb? ( >=media-libs/libcddb-1.2.0 ) )
cdio? ( >=dev-libs/libcdio-0.78.2
>=media-video/vcdimager-0.7.22 )
dbus? ( >=sys-apps/dbus-1.0.2 )
dc1394? ( sys-libs/libraw1394
<media-libs/libdc1394-1.9.99 )
directfb? ( dev-libs/DirectFB )
dts? ( media-libs/libdca )
dvd? ( media-libs/libdvdread
media-libs/libdvdcss
>=media-libs/libdvdnav-0.1.9
media-libs/libdvdplay )
esd? ( media-sound/esound )
ffmpeg? ( >=media-video/ffmpeg-0.4.9_p20070616 )
flac? ( media-libs/libogg
>=media-libs/flac-1.1.2 )
fluidsynth? ( media-sound/fluidsynth )
ggi? ( media-libs/libggi )
gnome? ( gnome-base/gnome-vfs )
gnutls? ( >=net-libs/gnutls-1.3.3 )
hal? ( sys-apps/hal )
id3tag? ( media-libs/libid3tag
sys-libs/zlib )
jack? ( >=media-sound/jack-audio-connection-kit-0.99.0-r1 )
libcaca? ( media-libs/libcaca )
libgcrypt? ( >=dev-libs/libgcrypt-1.2.0 )
libnotify? ( x11-libs/libnotify )
lirc? ( app-misc/lirc )
live? ( >=media-plugins/live-2007.02.20 )
lua? ( >=dev-lang/lua-5.1 )
matroska? (
>=dev-libs/libebml-0.7.6
>=media-libs/libmatroska-0.8.0 )
modplug? ( media-libs/libmodplug )
mp3? ( media-libs/libmad )
mpeg? ( >=media-libs/libmpeg2-0.3.2 )
musepack? ( media-libs/libmpcdec )
musicbrainz? ( =media-libs/musicbrainz-2* )
ncurses? ( sys-libs/ncurses )
nsplugin? (
xulrunner? ( >=net-libs/xulrunner-1.8 )
!xulrunner? ( seamonkey? ( =www-client/seamonkey-1* ) )
!xulrunner? ( !seamonkey? ( =www-client/mozilla-firefox-2* ) )
)
ogg? ( media-libs/libogg )
png? ( media-libs/libpng )
pulseaudio? ( >=media-sound/pulseaudio-0.9.8 )
qt4? ( || ( ( x11-libs/qt-gui x11-libs/qt-core ) >=x11-libs/qt-4.2.0:4 ) )
remoteosd? ( >=dev-libs/libgcrypt-1.2.0 )
samba? ( net-fs/samba )
sdl? ( >=media-libs/libsdl-1.2.8
sdl-image? ( media-libs/sdl-image ) )
shout? ( media-libs/libshout )
skins? ( || ( ( x11-libs/qt-gui x11-libs/qt-core ) >=x11-libs/qt-4.2.0:4 ) )
speex? ( media-libs/speex )
svg? ( >=gnome-base/librsvg-2.9.0 )
svga? ( media-libs/svgalib )
taglib? ( media-libs/taglib )
theora? ( media-libs/libtheora )
truetype? ( media-libs/freetype
media-fonts/ttf-bitstream-vera )
twolame? ( media-sound/twolame )
upnp? ( net-libs/libupnp )
vorbis? ( media-libs/libvorbis )
win32codecs? ( media-libs/win32codecs )
X? (
x11-libs/libX11
x11-libs/libXext
xv? ( x11-libs/libXv )
xinerama? ( x11-libs/libXinerama )
opengl? ( virtual/opengl )
)
x264? ( media-libs/x264 )
xml? ( dev-libs/libxml2 )
xosd? ( x11-libs/xosd )
"
# Disabled features and reasons:
# xvmc? ( x11-libs/libXvMC )
# Will probably compile only on x86
# dirac? ( >=media-video/dirac-0.10.0 )
# Needs testing but can be ok
# zvbi? ( >=media-libs/zvbi-0.2.25 )
# Dep not up to date enough
# kate? ( >=media-libs/libkate-0.1.1 )
# No package yet
DEPEND="${RDEPEND}
dvb? ( sys-kernel/linux-headers )
v4l? ( sys-kernel/linux-headers )
v4l2? ( sys-kernel/linux-headers )
X? ( xinerama? ( x11-proto/xineramaproto ) )
dev-util/pkgconfig"
S="${WORKDIR}/${MY_P}"
# Dispalys a warning if the first use flag is set but not the second
vlc_use_needs() {
use $1 && use !$2 && ewarn "USE=$1 requires $2, $1 will be disabled."
}
# Notify the user that some useflag have been forced on
vlc_use_force() {
use $1 && use !$2 && ewarn "USE=$1 requires $2, $2 will be enabled."
}
# Use when $2 depends strictly on $3
# if use $1 then enable $2 and $3, otherwise disable $2
vlc_use_enable_force() {
if use $1 ; then
echo "--enable-$2 --enable-$3"
else
echo "--disable-$2"
fi
}
# Prints the configure argument for the ffmpeg scaling api to use
vlc_ffmpeg_scaling_api() {
if use ffmpeg ; then
if has_version ">=media-video/ffmpeg-0.4.9_p20070616-r1" ; then
echo "--enable-swscale --disable-imgresample"
else
echo "--disable-swscale --enable-imgresample"
fi
else
echo "--disable-swscale --disable-imgresample"
fi
}
pkg_setup() {
vlc_use_needs skins truetype
vlc_use_force skins qt4
vlc_use_needs cdda cdio
vlc_use_needs vcdx cdio
vlc_use_needs bidi truetype
vlc_use_force remoteosd libgcrypt
}
src_unpack() {
unpack ${A}
cd "${S}"
EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
AT_M4DIR="m4 ${WORKDIR}/${PN}-m4" eautoreconf
}
src_compile () {
# It would fail if -fforce-addr is used due to too few registers...
use x86 && filter-flags -fforce-addr
local XPIDL=""
local MOZILLA_CONFIG=""
if use nsplugin; then
if use xulrunner; then
XPIDL=/usr/$(get_libdir)/xulrunner
MOZILLA_CONFIG=/usr/bin/xulrunner-config
elif use seamonkey; then
XPIDL=/usr/$(get_libdir)/seamonkey
MOZILLA_CONFIG=/usr/$(get_libdir)/seamonkey/seamonkey-config
else
XPIDL=/usr/$(get_libdir)/mozilla-firefox
MOZILLA_CONFIG=/usr/$(get_libdir)/mozilla-firefox/firefox-config
fi
fi
econf \
$(use_enable a52) \
$(use_enable aalib aa) \
$(use_enable aac faad) \
$(use_enable alsa) \
$(use_enable altivec) \
$(use_enable arts) \
--disable-asademux \
$(use_enable atmo) \
$(use_enable avahi bonjour) \
$(use_enable bidi fribidi) \
$(use_enable cdda) $(use_enable cdda cddax)\
$(use_enable cddb libcddb) \
$(use_enable cdio libcdio) \
--disable-csri \
$(use_enable dbus) $(use_enable dbus dbus-control) \
--disable-dirac \
$(use_enable directfb) \
$(use_enable dc1394) \
$(use_enable debug) \
$(use_enable dts dca) \
--disable-dv \
$(use_enable dvb) \
$(use_enable dvd dvdread) $(use_enable dvd dvdnav) \
$(use_enable esd) \
$(use_enable fbcon fb) \
$(use_enable ffmpeg avcodec) $(use_enable ffmpeg avformat) $(vlc_ffmpeg_scaling_api) $(use_enable ffmpeg postproc) \
$(use_enable flac) \
$(use_enable fluidsynth) \
--disable-galaktos \
$(use_enable ggi) \
$(use_enable gnome gnomevfs) \
$(use_enable gnutls) \
$(use_enable hal) \
$(use_enable httpd) \
$(use_enable id3tag) \
$(use_enable jack) \
--disable-kate \
$(use_enable libcaca caca) \
$(use_enable libgcrypt) \
$(use_enable libnotify notify) \
--disable-libproxy \
--disable-libtar \
$(use_enable lirc) \
$(use_enable live live555) \
$(use_enable lua) \
$(use_enable matroska mkv) \
$(use_enable mmx) \
$(use_enable modplug mod) \
$(use_enable mp3 mad) \
$(use_enable mpeg libmpeg2) \
$(use_enable musepack mpc) \
$(use_enable musicbrainz) \
$(use_enable ncurses) \
$(use_enable nsplugin mozilla) XPIDL="${XPIDL}" MOZILLA_CONFIG="${MOZILLA_CONFIG}" \
$(use_enable ogg) \
$(use_enable opengl glx) $(use_enable opengl) \
$(use_enable optimisememory optimize-memory) \
$(use_enable oss) \
$(use_enable png) \
--disable-portaudio \
$(use_enable pulseaudio pulse) \
$(use_enable pvr) \
$(use_enable qt4) \
$(use_enable rtsp realrtsp) \
$(use_enable samba smb) \
--disable-schroedinger \
$(use_enable sdl) \
$(use_enable sdl-image) \
$(use_enable shout) \
$(use_enable skins skins2) \
$(use_enable speex) \
$(use_enable sse) \
$(use_enable stream sout) \
$(use_enable svg) \
$(use_enable svga svgalib) \
$(use_enable taglib) \
$(use_enable theora) \
$(use_enable truetype freetype) \
$(use_enable twolame) \
$(use_enable upnp) \
$(use_enable v4l) \
$(use_enable v4l2) \
$(use_enable vcd) \
$(use_enable vcdx) \
$(use_enable vorbis) \
$(use_enable win32codecs loader) \
$(use_enable X x11) $(use_enable X screen) \
$(use_enable x264) \
$(use_enable xinerama) \
$(use_enable xml libxml2) \
$(use_enable xosd) \
$(use_enable xv xvideo) \
--disable-xvmc \
--disable-zvbi \
--disable-snapshot \
--disable-growl \
--disable-optimizations \
--enable-fast-install \
$(vlc_use_enable_force vlm vlm sout) \
$(vlc_use_enable_force skins skins2 qt4) \
$(vlc_use_enable_force remoteosd remoteosd libgcrypt)
if [[ $(gcc-major-version) == 2 ]]; then
sed -i -e s:"-fomit-frame-pointer":: vlc-config || die "-fomit-frame-pointer patching failed"
fi
emake || die "make of VLC failed"
}
src_install() {
emake DESTDIR="${D}" install || die "make install failed"
dodoc AUTHORS MAINTAINERS HACKING THANKS NEWS README \
doc/fortunes.txt doc/intf-cdda.txt doc/intf-vcd.txt
rm -rf "${D}/usr/share/doc/vlc" \
"${D}"/usr/share/vlc/vlc{16x16,32x32,48x48,128x128}.{png,xpm,ico}
if use nsplugin; then
dodir "/usr/$(get_libdir)/${PLUGINS_DIR}"
mv "${D}"/usr/$(get_libdir)/mozilla/plugins/* \
"${D}/usr/$(get_libdir)/${PLUGINS_DIR}/"
fi
use skins || rm -rf "${D}/usr/share/vlc/skins2"
for res in 16 32 48; do
insinto /usr/share/icons/hicolor/${res}x${res}/apps/
newins "${S}"/share/vlc${res}x${res}.png vlc.png
done
}
--
gentoo-commits@lists.gentoo.org mailing list
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-video/vlc: ChangeLog vlc-0.9.0_beta2.ebuild
@ 2008-07-17 22:27 Alexis Ballier (aballier)
0 siblings, 0 replies; 3+ messages in thread
From: Alexis Ballier (aballier) @ 2008-07-17 22:27 UTC (permalink / raw
To: gentoo-commits
aballier 08/07/17 22:27:15
Modified: ChangeLog vlc-0.9.0_beta2.ebuild
Log:
backport a patch from upstream to fix build without vlm, bug #231918
(Portage version: 2.2_rc1/cvs/Linux 2.6.25.7 x86_64)
Revision Changes Path
1.362 media-video/vlc/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/vlc/ChangeLog?rev=1.362&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/vlc/ChangeLog?rev=1.362&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/vlc/ChangeLog?r1=1.361&r2=1.362
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/vlc/ChangeLog,v
retrieving revision 1.361
retrieving revision 1.362
diff -u -r1.361 -r1.362
--- ChangeLog 17 Jul 2008 08:04:36 -0000 1.361
+++ ChangeLog 17 Jul 2008 22:27:15 -0000 1.362
@@ -1,6 +1,10 @@
# ChangeLog for media-video/vlc
# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/ChangeLog,v 1.361 2008/07/17 08:04:36 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/ChangeLog,v 1.362 2008/07/17 22:27:15 aballier Exp $
+
+ 17 Jul 2008; Alexis Ballier <aballier@gentoo.org> +files/vlm.patch,
+ vlc-0.9.0_beta2.ebuild:
+ backport a patch from upstream to fix build without vlm, bug #231918
17 Jul 2008; Alexis Ballier <aballier@gentoo.org> -vlc-0.8.6h.ebuild,
-vlc-0.9.0_beta1.ebuild:
1.3 media-video/vlc/vlc-0.9.0_beta2.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/vlc/vlc-0.9.0_beta2.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/vlc/vlc-0.9.0_beta2.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/vlc/vlc-0.9.0_beta2.ebuild?r1=1.2&r2=1.3
Index: vlc-0.9.0_beta2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-0.9.0_beta2.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- vlc-0.9.0_beta2.ebuild 17 Jul 2008 07:57:48 -0000 1.2
+++ vlc-0.9.0_beta2.ebuild 17 Jul 2008 22:27:15 -0000 1.3
@@ -1,6 +1,6 @@
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-0.9.0_beta2.ebuild,v 1.2 2008/07/17 07:57:48 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/vlc-0.9.0_beta2.ebuild,v 1.3 2008/07/17 22:27:15 aballier Exp $
EAPI="1"
@@ -199,6 +199,7 @@
unpack ${A}
cd "${S}"
+ epatch "${FILESDIR}/vlm.patch"
EPATCH_SUFFIX="patch" epatch "${WORKDIR}/patches"
AT_M4DIR="m4 ${WORKDIR}/${PN}-m4" eautoreconf
}
--
gentoo-commits@lists.gentoo.org mailing list
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in media-video/vlc: ChangeLog vlc-0.9.0_beta2.ebuild
@ 2008-08-05 19:49 Alexis Ballier (aballier)
0 siblings, 0 replies; 3+ messages in thread
From: Alexis Ballier (aballier) @ 2008-08-05 19:49 UTC (permalink / raw
To: gentoo-commits
aballier 08/08/05 19:49:58
Modified: ChangeLog
Removed: vlc-0.9.0_beta2.ebuild
Log:
remove unused version
(Portage version: 2.2_rc6/cvs/Linux 2.6.25.7 x86_64)
Revision Changes Path
1.368 media-video/vlc/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/vlc/ChangeLog?rev=1.368&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/vlc/ChangeLog?rev=1.368&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/vlc/ChangeLog?r1=1.367&r2=1.368
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/vlc/ChangeLog,v
retrieving revision 1.367
retrieving revision 1.368
diff -u -r1.367 -r1.368
--- ChangeLog 5 Aug 2008 19:41:05 -0000 1.367
+++ ChangeLog 5 Aug 2008 19:49:58 -0000 1.368
@@ -1,6 +1,10 @@
# ChangeLog for media-video/vlc
# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/ChangeLog,v 1.367 2008/08/05 19:41:05 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/vlc/ChangeLog,v 1.368 2008/08/05 19:49:58 aballier Exp $
+
+ 05 Aug 2008; Alexis Ballier <aballier@gentoo.org> -files/vlm.patch,
+ -vlc-0.9.0_beta2.ebuild:
+ remove unused version
05 Aug 2008; Alexis Ballier <aballier@gentoo.org> vlc-0.9.0_beta3.ebuild:
depend on new enough version of media-plugins/live, thanks to R Bar-On
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2008-08-05 19:50 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2008-08-05 19:49 [gentoo-commits] gentoo-x86 commit in media-video/vlc: ChangeLog vlc-0.9.0_beta2.ebuild Alexis Ballier (aballier)
-- strict thread matches above, loose matches on Subject: below --
2008-07-17 22:27 Alexis Ballier (aballier)
2008-07-14 12:51 Alexis Ballier (aballier)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox