[gentoo-commits] gentoo-x86 commit in net-proxy/squidguard: ChangeLog squidguard-1.3-r2.ebuild

[gentoo-commits] gentoo-x86 commit in net-proxy/squidguard: ChangeLog squidguard-1.3-r2.ebuild

[Alin Nastac (mrness)]

mrness      08/07/08 21:16:23

  Modified:             ChangeLog
  Added:                squidguard-1.3-r2.ebuild
  Log:
  Fix regex support, thanks to Yar Odin <yarodin@gmail.com> (#230922).
  (Portage version: 2.1.4.4, RepoMan options: --force)

Revision  Changes    Path
1.25                 net-proxy/squidguard/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/squidguard/ChangeLog?rev=1.25&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/squidguard/ChangeLog?rev=1.25&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/squidguard/ChangeLog?r1=1.24&r2=1.25

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-proxy/squidguard/ChangeLog,v
retrieving revision 1.24
retrieving revision 1.25
diff -u -r1.24 -r1.25
--- ChangeLog	23 Jun 2008 19:43:30 -0000	1.24
+++ ChangeLog	8 Jul 2008 21:16:23 -0000	1.25
@@ -1,6 +1,12 @@
 # ChangeLog for net-proxy/squidguard
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/squidguard/ChangeLog,v 1.24 2008/06/23 19:43:30 dertobi123 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/squidguard/ChangeLog,v 1.25 2008/07/08 21:16:23 mrness Exp $
+
+*squidguard-1.3-r2 (08 Jul 2008)
+
+  08 Jul 2008; Alin Năstac <mrness@gentoo.org>
+  +files/squidguard-1.3-bison.patch, +squidguard-1.3-r2.ebuild:
+  Fix regex support, thanks to Yar Odin <yarodin@gmail.com> (#230922).
 
   23 Jun 2008; Tobias Scherbaum <dertobi123@gentoo.org>
   squidguard-1.3-r1.ebuild:



1.1                  net-proxy/squidguard/squidguard-1.3-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/squidguard/squidguard-1.3-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-proxy/squidguard/squidguard-1.3-r2.ebuild?rev=1.1&content-type=text/plain

Index: squidguard-1.3-r2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-proxy/squidguard/squidguard-1.3-r2.ebuild,v 1.1 2008/07/08 21:16:23 mrness Exp $

WANT_AUTOMAKE=none

inherit eutils autotools

DESCRIPTION="Combined filter, redirector and access controller plugin for Squid."
HOMEPAGE="http://www.squidguard.org"
SRC_URI="http://www.squidguard.org/Downloads/squidGuard-${PV}.tar.gz
	http://www.squidguard.org/Downloads/Patches/${PV}/squidGuard-${PV}-patch-20080613.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc ppc64 x86"
IUSE="ldap"

RDEPEND="net-proxy/squid
	>=sys-libs/db-2
	ldap? ( net-nds/openldap )"
DEPEND="${RDEPEND}
	sys-devel/bison
	sys-devel/flex"

S="${WORKDIR}/squidGuard-${PV}"

RESTRICT="test" # tests are currently broken

src_unpack() {
	unpack ${A}

	cd "${S}"
	cp ../squidGuard-${PV}-patch-20080613/src/sgDiv.c.in src/ || die "failed to replace sgDiv.c.in"
	epatch "${FILESDIR}/${P}-gentoo.patch"
	epatch "${FILESDIR}/${P}-autoheader.patch"
	epatch "${FILESDIR}/${P}-bison.patch"
	eautoreconf
}

src_compile() {
	econf \
		$(use_with ldap) \
		--with-sg-config=/etc/squidGuard/squidGuard.conf \
		--with-sg-logdir=/var/log/squidGuard \
		|| die "configure has failed"

	emake || die "make has failed"
}

src_install() {
	emake prefix="/usr" INSTDIR="${D}" install || die "emake install has failed"

	keepdir /var/log/squidGuard
	fowners squid:squid /var/log/squidGuard

	insinto /etc/squidGuard/sample
	doins "${FILESDIR}"/squidGuard.conf.*
	insinto /etc/squidGuard/sample/db
	doins "${FILESDIR}"/blockedsites

	dodoc ANNOUNCE CHANGELOG README
	dohtml doc/*.html
	docinto text
	dodoc doc/*.txt
}

pkg_postinst() {
	einfo "To enable squidGuard, add the following lines to /etc/squid/squid.conf:"
	einfo "    url_rewrite_program /usr/bin/squidGuard"
	einfo "    url_rewrite_children 10"
	einfo ""
	einfo "Remember to edit /etc/squidGuard/squidGuard.conf first!"
	einfo "Examples can be found in /etc/squidGuard/sample/"
}



-- 
gentoo-commits@lists.gentoo.org mailing list