[gentoo-commits] gentoo-x86 commit in media-libs/libwmf: ChangeLog libwmf-0.2.8.4-r1.ebuild

[gentoo-commits] gentoo-x86 commit in media-libs/libwmf: ChangeLog libwmf-0.2.8.4-r1.ebuild

[Jeremy Olexa (darkside)]

darkside    08/06/29 04:06:59

  Modified:             ChangeLog
  Added:                libwmf-0.2.8.4-r1.ebuild
  Log:
  Add code to to update /etc/gtk-2.0/gdk-pixbuf.loaders, copied from librsvg ebuild. Bug #221919, thanks to Maciej Grela <thermal@o2.pl> for reporting
  (Portage version: 2.2_rc1/cvs/Linux 2.6.22-gentoo-r2 i686)

Revision  Changes    Path
1.56                 media-libs/libwmf/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libwmf/ChangeLog?rev=1.56&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libwmf/ChangeLog?rev=1.56&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libwmf/ChangeLog?r1=1.55&r2=1.56

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libwmf/ChangeLog,v
retrieving revision 1.55
retrieving revision 1.56
diff -u -r1.55 -r1.56
--- ChangeLog	11 Feb 2008 20:00:04 -0000	1.55
+++ ChangeLog	29 Jun 2008 04:06:58 -0000	1.56
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/libwmf
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libwmf/ChangeLog,v 1.55 2008/02/11 20:00:04 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libwmf/ChangeLog,v 1.56 2008/06/29 04:06:58 darkside Exp $
+
+*libwmf-0.2.8.4-r1 (29 Jun 2008)
+
+  29 Jun 2008; Jeremy Olexa <darkside@gentoo.org> +libwmf-0.2.8.4-r1.ebuild:
+  Add code to to update /etc/gtk-2.0/gdk-pixbuf.loaders, copied from librsvg
+  ebuild. Bug #221919, thanks to Maciej Grela <thermal@o2.pl> for reporting
 
   11 Feb 2008; Raúl Porcel <armin76@gentoo.org> libwmf-0.2.8.4.ebuild:
   Remove jpeg USE-flag since it's not supposed to build without it, bug #146680



1.1                  media-libs/libwmf/libwmf-0.2.8.4-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libwmf/libwmf-0.2.8.4-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libwmf/libwmf-0.2.8.4-r1.ebuild?rev=1.1&content-type=text/plain

Index: libwmf-0.2.8.4-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libwmf/libwmf-0.2.8.4-r1.ebuild,v 1.1 2008/06/29 04:06:58 darkside Exp $

inherit eutils autotools

#The configure script finds the 5.50 ghostscript Fontmap file while run.
#This will probably work, especially since the real one (6.50) in this case
#is empty. However beware in case there is any trouble

DESCRIPTION="library for converting WMF files"
HOMEPAGE="http://wvware.sourceforge.net/"
SRC_URI="mirror://sourceforge/wvware/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="X expat xml debug doc gtk gd"

RDEPEND="virtual/ghostscript
	xml? ( !expat? ( dev-libs/libxml2 ) )
	expat? ( dev-libs/expat )
	gd? ( media-libs/gd )
	>=media-libs/freetype-2.0.1
	sys-libs/zlib
	media-libs/libpng
	media-libs/jpeg
	X? (
		x11-libs/libICE
		x11-libs/libSM
		x11-libs/libX11
	)
	gtk? ( >=x11-libs/gtk+-2.1.2 ) "
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	X? (
		x11-libs/libXt
		x11-libs/libXpm
	)"
# plotutils are not really supported yet, so looks like that's it

src_unpack() {
	unpack ${A}
	cd "${S}"
	if ! use doc ; then
		sed -e 's:doc::' -i Makefile.am
	fi
	if ! use gtk ; then
		sed -e 's:@LIBWMF_GDK_PIXBUF_TRUE@:#:' -i src/Makefile.in
	fi
	epatch "${FILESDIR}"/${P}-intoverflow.patch
	epatch "${FILESDIR}"/${P}-build.patch

	eautoreconf
}

src_compile() {
	if use expat && use xml ; then
		elog "You can specify only one USE flag from expat and xml, to use expat"
		elog "or libxml2, respectively."
		elog
		elog "You have both flags enabled, we will default to expat (like autocheck does)."
		myconf="${myconf} --with-expat --without-libxml2"
	else
		myconf="${myconf} $(use_with expat) $(use_with xml libxml2)"
	fi

	econf \
		$(use_enable debug) \
		$(use_with X x) \
		$(use_enable gd) \
		--with-sys-gd \
		${myconf} \
		--with-gsfontdir=/usr/share/ghostscript/fonts \
		--with-fontdir=/usr/share/libwmf/fonts/ \
		--with-docdir=/usr/share/doc/${PF} \
		|| die "./configure failed"

	emake || die
}

src_install() {
	make install DESTDIR="${D}" || die
	dodoc README AUTHORS CREDITS ChangeLog NEWS TODO
}

set_gtk_confdir() {
	# An arch specific config directory is used on multilib systems
	has_multilib_profile && GTK2_CONFDIR="${ROOT}etc/gtk-2.0/${CHOST}"
	GTK2_CONFDIR="${GTK2_CONFDIR:-/etc/gtk-2.0}"
}

pkg_postinst() {
	set_gtk_confdir
	gdk-pixbuf-query-loaders > "${GTK2_CONFDIR}/gdk-pixbuf.loaders"
}

pkg_postrm() {
	set_gtk_confdir
	gdk-pixbuf-query-loaders > "${GTK2_CONFDIR}/gdk-pixbuf.loaders"
}




-- 
gentoo-commits@lists.gentoo.org mailing list