* [gentoo-commits] gentoo-x86 commit in www-client/opera: ChangeLog opera-9.51_pre2050.ebuild
@ 2008-06-23 0:48 Jeroen Roovers (jer)
0 siblings, 0 replies; only message in thread
From: Jeroen Roovers (jer) @ 2008-06-23 0:48 UTC (permalink / raw
To: gentoo-commits
jer 08/06/23 00:48:36
Modified: ChangeLog
Added: opera-9.51_pre2050.ebuild
Log:
Version bump <http://my.opera.com/desktopteam/blog/2008/06/20/towards-9-51>. Should fix bug #222975.
(Portage version: 2.2_rc1/cvs/Linux 2.6.24-gentoo-r2-JeR i686)
Revision Changes Path
1.247 www-client/opera/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/opera/ChangeLog?rev=1.247&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/opera/ChangeLog?rev=1.247&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/opera/ChangeLog?r1=1.246&r2=1.247
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/opera/ChangeLog,v
retrieving revision 1.246
retrieving revision 1.247
diff -u -r1.246 -r1.247
--- ChangeLog 17 Jun 2008 15:27:43 -0000 1.246
+++ ChangeLog 23 Jun 2008 00:48:35 -0000 1.247
@@ -1,6 +1,12 @@
# ChangeLog for www-client/opera
# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/opera/ChangeLog,v 1.246 2008/06/17 15:27:43 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/opera/ChangeLog,v 1.247 2008/06/23 00:48:35 jer Exp $
+
+*opera-9.51_pre2050 (23 Jun 2008)
+
+ 23 Jun 2008; Jeroen Roovers <jer@gentoo.org> +opera-9.51_pre2050.ebuild:
+ Version bump <http://my.opera.com/desktopteam/blog/2008/06/20/towards-9-51>.
+ Should fix bug #222975.
17 Jun 2008; Jeroen Roovers <jer@gentoo.org> opera-9.27.ebuild:
Drop all keywords except sparc (bug #226079).
1.1 www-client/opera/opera-9.51_pre2050.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/opera/opera-9.51_pre2050.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/www-client/opera/opera-9.51_pre2050.ebuild?rev=1.1&content-type=text/plain
Index: opera-9.51_pre2050.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/opera/opera-9.51_pre2050.ebuild,v 1.1 2008/06/23 00:48:35 jer Exp $
GCONF_DEBUG="no"
inherit eutils gnome2
DESCRIPTION="A standards-compliant graphical Web browser"
HOMEPAGE="http://www.opera.com/"
SLOT="0"
LICENSE="OPERA-9.0"
KEYWORDS="~ppc ~x86 ~x86-fbsd"
RESTRICT="mirror strip test"
IUSE="elibc_FreeBSD gnome qt-static qt3-static spell"
MY_LINGUAS="be bg cs da de el en en-GB es-ES es-LA fi fr fr-CA fy hi
hr hu it ja ka ko lt mk nb nl nn pl pt pt-BR ru sv tr zh-CN zh-TW"
for MY_LINGUA in ${MY_LINGUAS}; do
IUSE="${IUSE} linguas_${MY_LINGUA/-/_}"
done
O_VER="opera-9.51"
O_SUFF="2050"
O_URI="http://snapshot.opera.com/unix/snapshot-${O_SUFF}/"
# +qt-static +qt3-static = static-qt3
# +qt-static -qt3-static = qt4
# -qt-static -qt3-static = shared-qt3
# -qt-static +qt3-static = static-qt3
SRC_URI="
ppc? ( ${O_URI}ppc-linux/${O_VER}-${O_SUFF}.gcc4-shared-qt3.ppc.tar.bz2 )
x86-fbsd? ( ${O_URI}intel-freebsd/${O_VER}-${O_SUFF}.freebsd5-shared-qt3.i386.tar.bz2 )
qt-static? (
qt3-static? (
x86? ( ${O_URI}intel-linux/${O_VER}-${O_SUFF}.gcc4-static-qt3.i386.tar.bz2 )
)
!qt3-static? (
x86? ( ${O_URI}intel-linux/${O_VER}-${O_SUFF}.gcc4-qt4.i386.tar.bz2 )
)
)
!qt-static? (
qt3-static? (
x86? ( ${O_URI}intel-linux/${O_VER}-${O_SUFF}.gcc4-static-qt3.i386.tar.bz2 )
)
!qt3-static? (
x86? ( ${O_URI}intel-linux/${O_VER}-${O_SUFF}.gcc4-shared-qt3.i386.tar.bz2 )
)
)
"
DEPEND=">=sys-apps/sed-4"
RDEPEND="media-libs/libexif
media-libs/jpeg
>=media-libs/fontconfig-2.1.94-r1
x11-libs/libXrandr
x11-libs/libXp
x11-libs/libXmu
x11-libs/libXi
x11-libs/libXft
x11-libs/libXext
x11-libs/libXcursor
x11-libs/libX11
x11-libs/libSM
x11-libs/libICE
!qt-static? ( =x11-libs/qt-3* )
!qt3-static? ( =x11-libs/qt-3* )
ppc? ( =x11-libs/qt-3* )
spell? ( app-text/aspell )
x86-fbsd? ( =x11-libs/qt-3* =virtual/libstdc++-3* )"
# +qt-static +qt3-static = static-qt3
# +qt-static -qt3-static = qt4
# -qt-static -qt3-static = shared-qt3
# -qt-static +qt3-static = static-qt3
pkg_setup() {
use ppc && S="${WORKDIR}/${O_VER}-${O_SUFF}.gcc4-shared-qt3.ppc"
use x86-fbsd && S="${WORKDIR}/${O_VER}-${O_SUFF}-freebsd5-shared-qt3.i386"
if use x86; then
if use qt-static; then
if use qt3-static; then
S="${WORKDIR}/${O_VER}-${O_SUFF}.gcc4-static-qt3.i386"
else
S="${WORKDIR}/${O_VER}-${O_SUFF}.gcc4-qt4.i386"
fi
else
if use qt3-static; then
S="${WORKDIR}/${O_VER}-${O_SUFF}.gcc4-static-qt3.i386"
else
S="${WORKDIR}/${O_VER}-${O_SUFF}.gcc4-shared-qt3.i386"
fi
fi
fi
}
src_unpack() {
unpack ${A}
cd "${S}"
epatch "${FILESDIR}/${PN}-9.00-install.patch"
# bug #181300:
use elibc_FreeBSD || epatch "${FILESDIR}/${PN}-9.50-pluginpath.patch"
use elibc_FreeBSD && epatch "${FILESDIR}/${PN}-9.50-pluginpath-fbsd.patch"
cp install.sh{,.orig}
sed -i -e "s:config_dir=\"/etc\":config_dir=\"${D}/etc/\":g" \
-e "s:/usr/share/applnk:${D}/usr/share/applnk:g" \
-e "s:/usr/share/pixmaps:${D}/usr/share/pixmaps:g" \
-e "s:/usr/share/icons:${D}/usr/share/icons:g" \
-e "s:/etc/X11:${D}/etc/X11:g" \
-e "s:/usr/share/gnome:${D}/usr/share/gnome:g" \
-e "s:/opt/gnome/share:${D}/opt/gnome/share:g" \
-e 's:#\(OPERA_FORCE_JAVA_ENABLED=\):\1:' \
-e 's:#\(export LD_PRELOAD OPERA_FORCE_JAVA_ENABLED\):\1:' \
-e 's:read str_answer:return 0:' \
-e "s:/opt/kde:${D}/usr/kde:" \
-e "s:\(str_localdirplugin=\).*$:\1/opt/opera/lib/opera/plugins:" \
install.sh || die "sed failed"
}
src_compile() {
# This workaround is sadly needed because gnome2.eclass doesn't check
# whether a configure script or Makefile exists.
true
}
src_install() {
# Prepare installation directories for Opera's installer script.
dodir /etc
# Opera's native installer.
./install.sh --prefix="${D}"/opt/opera || die "install.sh failed"
einfo "It is safe to ignore warnings about failed checksums"
einfo "and about files that would be ignored ..."
einfo "Completing the installation where install.sh abandoned us ..."
# java workaround
sed -i -e 's:LD_PRELOAD="${OPERA_JAVA_DIR}/libawt.so":LD_PRELOAD="$LD_PRELOAD"\:"${OPERA_JAVA_DIR}/libawt.so":' "${D}"/opt/opera/bin/opera
dosed /opt/opera/bin/opera
dosed /opt/opera/share/opera/java/opera.policy
# Install the icons
insinto /usr/share/pixmaps
doins usr/share/pixmaps/opera.xpm
local res
for res in 16x16 22x22 32x32 48x48 ; do
insinto /usr/share/icons/hicolor/${res}/apps
doins usr/share/icons/hicolor/${res}/apps/opera.png
done
# Install the menu entry
make_desktop_entry opera Opera /usr/share/pixmaps/opera.xpm 'Network;WebBrowser;Email;FileTransfer;IRCClient'
# Install a symlink /usr/bin/opera
dodir /usr/bin
dosym /opt/opera/bin/opera /usr/bin/opera
# fix plugin path
echo "Plugin Path=/opt/opera/lib/opera/plugins" >> "${D}"/etc/opera6rc
# enable spellcheck
if use spell; then
if use qt-static; then
DIR=${P}.1
else
use sparc && DIR=${P}.2 || DIR=${P}.5
fi
echo "Spell Check Engine=/opt/opera/lib/opera/${DIR}/spellcheck.so" >> "${D}"/opt/opera/share/opera/ini/spellcheck.ini
fi
dodir /etc/revdep-rebuild
echo 'SEARCH_DIRS_MASK="/opt/opera/lib/opera/plugins"' > "${D}"/etc/revdep-rebuild/90opera
# Change libz.so.3 to libz.so.1 for gentoo/freebsd
if use elibc_FreeBSD; then
scanelf -qR -N libz.so.3 -F "#N" "${D}"/opt/${PN}/ | \
while read i; do
if [[ $(strings "$i" | fgrep -c libz.so.3) -ne 1 ]];
then
export SANITY_CHECK_LIBZ_FAILED=1
break
fi
sed -i -e 's/libz\.so\.3/libz.so.1/g' "$i"
done
[[ "$SANITY_CHECK_LIBZ_FAILED" = "1" ]] && die "failed to change libz.so.3 to libz.so.1"
fi
# Add the Opera man dir to MANPATH:
insinto /etc/env.d
echo 'MANPATH="/opt/opera/share/man"' >> "${D}"/etc/env.d/90opera
# Remove unwanted LINGUAS:
local LINGUA
local LNGDIR="${D}/opt/opera/share/opera/locale"
einfo "Keeping these locales: ${LINGUAS}."
for LINGUA in ${MY_LINGUAS}; do
if ! use linguas_${LINGUA/-/_}; then
LINGUA=$(find "${LNGDIR}" -maxdepth 1 -type d -iname ${LINGUA/_/-})
rm -r "${LINGUA}"
fi
done
}
pkg_postinst() {
use gnome && gnome2_pkg_postinst
elog "To change the UI language, choose [Tools] -> [Preferences], open the"
elog "[General] tab, click on [Details...] then [Choose...] and point the"
elog "file chooser at /opt/opera/share/opera/locale/, then enter the"
elog "directory for the language you want and [Open] the .lng file."
elog
elog "To use the spellchecker (USE=spell) for non-English simply do"
elog "$ emerge app-dicts/aspell-[your language]."
if use elibc_FreeBSD; then
elog
elog "To improve shared memory usage please set:"
elog "$ sysctl kern.ipc.shm_allow_removed=1"
fi
elog "The Opera betas may still have issues with plugins, notably"
elog "net-www/netscape-flash. See also https://bugs.gentoo.org/198162"
}
pkg_postrm() {
use gnome && gnome2_pkg_postrm
}
--
gentoo-commits@lists.gentoo.org mailing list
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2008-06-23 0:48 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2008-06-23 0:48 [gentoo-commits] gentoo-x86 commit in www-client/opera: ChangeLog opera-9.51_pre2050.ebuild Jeroen Roovers (jer)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox