[gentoo-commits] gentoo-x86 commit in dev-java/jfreechart: ChangeLog jfreechart-1.0.10.ebuild

[gentoo-commits] gentoo-x86 commit in dev-java/jfreechart: ChangeLog jfreechart-1.0.10.ebuild

[Serkan Kaba (serkan)]

serkan      08/06/10 20:49:40

  Modified:             ChangeLog
  Added:                jfreechart-1.0.10.ebuild
  Log:
  Version bump and remove unused patch. Fixes bug #225713. Thanks to Jan Vansteenkiste <Jan@buitendezone.be> for reporting.
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.44                 dev-java/jfreechart/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/jfreechart/ChangeLog?rev=1.44&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/jfreechart/ChangeLog?rev=1.44&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/jfreechart/ChangeLog?r1=1.43&r2=1.44

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/jfreechart/ChangeLog,v
retrieving revision 1.43
retrieving revision 1.44
diff -u -r1.43 -r1.44
--- ChangeLog	4 May 2008 11:40:06 -0000	1.43
+++ ChangeLog	10 Jun 2008 20:49:39 -0000	1.44
@@ -1,6 +1,13 @@
 # ChangeLog for dev-java/jfreechart
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/jfreechart/ChangeLog,v 1.43 2008/05/04 11:40:06 opfer Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/jfreechart/ChangeLog,v 1.44 2008/06/10 20:49:39 serkan Exp $
+
+*jfreechart-1.0.10 (10 Jun 2008)
+
+  10 Jun 2008; Serkan Kaba <serkan@gentoo.org>
+  -files/1.0.8-test-timezone.patch, +jfreechart-1.0.10.ebuild:
+  Version bump and remove unused patch. Fixes bug #225713. Thanks to Jan
+  Vansteenkiste <Jan@buitendezone.be> for reporting.
 
   04 May 2008; Christian Faulhammer <opfer@gentoo.org>
   jfreechart-1.0.9-r1.ebuild:



1.1                  dev-java/jfreechart/jfreechart-1.0.10.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/jfreechart/jfreechart-1.0.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/jfreechart/jfreechart-1.0.10.ebuild?rev=1.1&content-type=text/plain

Index: jfreechart-1.0.10.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/jfreechart/jfreechart-1.0.10.ebuild,v 1.1 2008/06/10 20:49:39 serkan Exp $

EAPI=1
JAVA_PKG_IUSE="doc source"

inherit java-pkg-2 java-ant-2

DESCRIPTION="JFreeChart is a free Java class library for generating charts"
HOMEPAGE="http://www.jfree.org/jfreechart"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="1.0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="test"
COMMON_DEPEND="
	>=dev-java/itext-1.4.6
	dev-java/jcommon:1.0
	java-virtuals/servlet-api:2.3"
DEPEND=">=virtual/jdk-1.4
	${COMMON_DEPEND}
	test? ( dev-java/ant-junit )"
RDEPEND=">=virtual/jdk-1.4
	${COMMON_DEPEND}"

JAVA_PKG_FILTER_COMPILER="jikes"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# We do not fork junit tests because we need to disable X11 support for all tests
	if use test; then
		epatch "${FILESDIR}/${PN}-1.0.4-build.xml.patch"
	fi

	rm -v *.jar lib/*.jar || die
}

src_compile() {
	# Note that compile-experimental depends on compile so it is sufficient to run
	# just compile-experimental
	eant -f ant/build.xml compile-experimental $(use_doc) $(get_jars)
}

src_test() {
	# X11 tests are disabled using java.awt.headless=true
	ANT_TASKS="ant-junit" \
	ANT_OPTS="-Djava.awt.headless=true -Duser.timezone=UTC" \
		eant -f ant/build.xml test $(get_jars)
}

src_install() {
	java-pkg_newjar ${P}.jar ${PN}.jar
	java-pkg_newjar ${P}-experimental.jar ${PN}-experimental.jar
	dodoc README.txt ChangeLog NEWS || die
	use doc && java-pkg_dojavadoc javadoc
	use source && java-pkg_dosrc source/org
}

get_jars() {
	local antflags="
		-Ditext.jar=$(java-pkg_getjar itext iText.jar) \
		-Djcommon.jar=$(java-pkg_getjar jcommon-1.0 jcommon.jar) \
		-Dservlet.jar=$(java-pkg_getjars servlet-api-2.3)"
	use test && antflags="${antflags} \
		-Djunit.jar=$(java-pkg_getjars --build-only junit)"
	echo "${antflags}"
}



-- 
gentoo-commits@lists.gentoo.org mailing list