* [gentoo-commits] gentoo-x86 commit in net-nntp/nzbget: ChangeLog nzbget-0.4.0-r1.ebuild
@ 2008-06-07 21:19 Sven Wegener (swegener)
0 siblings, 0 replies; only message in thread
From: Sven Wegener (swegener) @ 2008-06-07 21:19 UTC (permalink / raw
To: gentoo-commits
swegener 08/06/07 21:19:45
Modified: ChangeLog
Added: nzbget-0.4.0-r1.ebuild
Log:
Add support for a system-wide nzbget daemon, bug #217359. Credit for the idea goes to Chris Carlin.
(Portage version: 2.1.5.4)
Revision Changes Path
1.19 net-nntp/nzbget/ChangeLog
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-nntp/nzbget/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-nntp/nzbget/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-nntp/nzbget/ChangeLog?r1=1.18&r2=1.19
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-nntp/nzbget/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog 7 Jun 2008 20:28:54 -0000 1.18
+++ ChangeLog 7 Jun 2008 21:19:45 -0000 1.19
@@ -1,6 +1,13 @@
# ChangeLog for net-nntp/nzbget
# Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-nntp/nzbget/ChangeLog,v 1.18 2008/06/07 20:28:54 swegener Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-nntp/nzbget/ChangeLog,v 1.19 2008/06/07 21:19:45 swegener Exp $
+
+*nzbget-0.4.0-r1 (07 Jun 2008)
+
+ 07 Jun 2008; Sven Wegener <swegener@gentoo.org> +files/nzbget.confd,
+ +files/nzbget.initd, +nzbget-0.4.0-r1.ebuild:
+ Add support for a system-wide nzbget daemon, bug #217359. Credit for the
+ idea goes to Chris Carlin.
07 Jun 2008; Sven Wegener <swegener@gentoo.org> -files/0.2.3-gcc41.patch,
-files/0.2.3-include-order.patch, -files/0.2.3-double-free.patch,
1.1 net-nntp/nzbget/nzbget-0.4.0-r1.ebuild
file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-nntp/nzbget/nzbget-0.4.0-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-nntp/nzbget/nzbget-0.4.0-r1.ebuild?rev=1.1&content-type=text/plain
Index: nzbget-0.4.0-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-nntp/nzbget/nzbget-0.4.0-r1.ebuild,v 1.1 2008/06/07 21:19:45 swegener Exp $
EAPI="1"
inherit eutils
DESCRIPTION="A command-line based binary newsgrabber supporting .nzb files"
HOMEPAGE="http://nzbget.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~x86"
IUSE="debug ncurses parcheck"
DEPEND="dev-libs/libxml2
parcheck? (
app-arch/libpar2
dev-libs/libsigc++:2
)
ncurses? ( sys-libs/ncurses )"
RDEPEND="${DEPEND}"
src_unpack() {
unpack ${A}
sed -i \
-e 's:^$MAINDIR=.*:$MAINDIR=/var/lib/nzbget:' \
-e 's:^LockFile=.*:LockFile=/var/run/nzbget/nzbget.pid:' \
-e 's:^LogFile=.*:LogFile=/var/log/nzbget/nzbget.log:' \
"${S}"/nzbget.conf.example \
|| die "sed nzbget.conf.example failed"
}
src_compile() {
econf \
$(use_enable debug) \
$(use_enable ncurses curses) \
$(use_enable parcheck) \
|| die "econf failed"
emake || die "emake failed"
}
src_install() {
emake install DESTDIR="${D}" || die "emake install failed"
insinto /etc
newins nzbget.conf.example nzbgetd.conf || die "newins failed"
keepdir /var/lib/nzbget/{dst,nzb,queue,tmp}
keepdir /var/{log,run}/nzbget
newinitd "${FILESDIR}"/nzbget.initd nzbget
newconfd "${FILESDIR}"/nzbget.confd nzbget
dodoc AUTHORS ChangeLog README nzbget.conf.example || die "dodoc failed"
}
pkg_postinst() {
enewgroup nzbget
enewuser nzbget -1 -1 /var/lib/nzbget nzbget
chown nzbget:nzbget "${ROOT}"/var/lib/nzbget/{dst,nzb,queue,tmp}
chmod 750 "${ROOT}"/var/lib/nzbget/{queue,tmp}
chmod 770 "${ROOT}"/var/lib/nzbget/{dst,nzb}
chown nzbget:nzbget "${ROOT}"/var/{log,run}/nzbget
chmod 750 "${ROOT}"/var/{log,run}/nzbget
chown root:nzbget "${ROOT}"/etc/nzbgetd.conf
chmod 640 "${ROOT}"/etc/nzbgetd.conf
elog
elog "Please add users that you want to be able to use the system-wide"
elog "nzbget daemon to the nzbget group. To access the daemon run nzbget"
elog "with the --configfile /etc/nzbgetd.conf option."
elog
}
--
gentoo-commits@lists.gentoo.org mailing list
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2008-06-07 21:19 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2008-06-07 21:19 [gentoo-commits] gentoo-x86 commit in net-nntp/nzbget: ChangeLog nzbget-0.4.0-r1.ebuild Sven Wegener (swegener)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox