[gentoo-commits] gentoo-x86 commit in sys-libs/com_err: ChangeLog com_err-1.40.10.ebuild

[gentoo-commits] gentoo-x86 commit in sys-libs/com_err: ChangeLog com_err-1.40.10.ebuild

[Mike Frysinger (vapier)]

vapier      08/06/07 16:30:41

  Modified:             ChangeLog
  Added:                com_err-1.40.10.ebuild
  Log:
  Version bump #225161 by Krzysztof Olędzki.
  (Portage version: 2.2_pre5.spank.spunk)

Revision  Changes    Path
1.68                 sys-libs/com_err/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/com_err/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/com_err/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/com_err/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/com_err/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	26 May 2008 08:34:55 -0000	1.67
+++ ChangeLog	7 Jun 2008 16:30:41 -0000	1.68
@@ -1,6 +1,11 @@
 # ChangeLog for sys-libs/com_err
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/com_err/ChangeLog,v 1.67 2008/05/26 08:34:55 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/com_err/ChangeLog,v 1.68 2008/06/07 16:30:41 vapier Exp $
+
+*com_err-1.40.10 (07 Jun 2008)
+
+  07 Jun 2008; Mike Frysinger <vapier@gentoo.org> +com_err-1.40.10.ebuild:
+  Version bump #225161 by Krzysztof Olędzki.
 
   26 May 2008; Raúl Porcel <armin76@gentoo.org> com_err-1.40.8.ebuild:
   ia64 stable wrt #213588



1.1                  sys-libs/com_err/com_err-1.40.10.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/com_err/com_err-1.40.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/com_err/com_err-1.40.10.ebuild?rev=1.1&content-type=text/plain

Index: com_err-1.40.10.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/com_err/com_err-1.40.10.ebuild,v 1.1 2008/06/07 16:30:41 vapier Exp $

inherit eutils flag-o-matic toolchain-funcs

DESCRIPTION="common error display library"
HOMEPAGE="http://e2fsprogs.sourceforge.net/"
SRC_URI="mirror://sourceforge/e2fsprogs/e2fsprogs-${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="nls"

RDEPEND=""
DEPEND="nls? ( sys-devel/gettext )
	sys-devel/bc"

S=${WORKDIR}/e2fsprogs-${PV}

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-1.39-makefile.patch
}

src_compile() {
	export LDCONFIG=/bin/true
	export CC=$(tc-getCC)
	export STRIP=/bin/true

	# We want to use the "bsd" libraries while building on Darwin, but while
	# building on other Gentoo/*BSD we prefer elf-naming scheme.
	local libtype
	case ${CHOST} in
		*-darwin*) libtype=bsd;;
		*)         libtype=elf;;
	esac

	econf \
		--enable-${libtype}-shlibs \
		--with-ldopts="${LDFLAGS}" \
		$(use_enable !elibc_uclibc tls) \
		$(use_enable nls) \
		|| die
	emake -C lib/et || die
}

src_test() {
	make -C lib/et check || die "make check failed"
}

src_install() {
	export LDCONFIG=/bin/true
	export CC=$(tc-getCC)
	export STRIP=/bin/true

	emake -C lib/et DESTDIR="${D}" install || die
	dosed '/^ET_DIR=/s:=.*:=/usr/share/et:' /usr/bin/compile_et
	dosym et/com_err.h /usr/include/com_err.h

	dolib.a lib/libcom_err.a || die "dolib.a"
	dodir /$(get_libdir)
	mv "${D}"/usr/$(get_libdir)/*$(get_libname)* "${D}"/$(get_libdir)/ || die "move $(get_libname)"
	gen_usr_ldscript libcom_err$(get_libname)
}

pkg_postinst() {
	echo
	ewarn "PLEASE PLEASE take note of this"
	ewarn "Please make *sure* to run revdep-rebuild now."
	ewarn "Certain things on your system may have linked against a different"
	ewarn "version of com_err -- those things need to be recompiled."
	ewarn "Sorry for the inconvenience"
	echo
	epause 10
	ebeep
}



-- 
gentoo-commits@lists.gentoo.org mailing list