[gentoo-commits] gentoo-x86 commit in kde-base/kde-l10n: ChangeLog kde-l10n-4.0.5.ebuild

[gentoo-commits] gentoo-x86 commit in kde-base/kde-l10n: ChangeLog kde-l10n-4.0.5.ebuild

[Tobias Heinlein (keytoaster)]

keytoaster    08/06/05 21:16:24

  Modified:             ChangeLog
  Added:                kde-l10n-4.0.5.ebuild
  Log:
  Added the KDE 4.0.5 version of kde-l10n.
  (Portage version: 2.2_pre7/cvs/Linux 2.6.25-gentoo-r4 AMD Athlon(tm) 64 X2 Dual Core Processor 4200+)

Revision  Changes    Path
1.9                  kde-base/kde-l10n/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kde-l10n/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kde-l10n/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kde-l10n/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	15 May 2008 22:58:52 -0000	1.8
+++ ChangeLog	5 Jun 2008 21:16:23 -0000	1.9
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/kde-l10n
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/ChangeLog,v 1.8 2008/05/15 22:58:52 ingmar Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/ChangeLog,v 1.9 2008/06/05 21:16:23 keytoaster Exp $
+
+*kde-l10n-4.0.5 (05 Jun 2008)
+
+  05 Jun 2008; Tobias Heinlein <keytoaster@gentoo.org>
+  +kde-l10n-4.0.5.ebuild:
+  Added the KDE 4.0.5 version of kde-l10n.
 
 *kde-l10n-4.0.4 (15 May 2008)
 



1.1                  kde-base/kde-l10n/kde-l10n-4.0.5.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kde-l10n/kde-l10n-4.0.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/kde-base/kde-l10n/kde-l10n-4.0.5.ebuild?rev=1.1&content-type=text/plain

Index: kde-l10n-4.0.5.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/kde-l10n-4.0.5.ebuild,v 1.1 2008/06/05 21:16:23 keytoaster Exp $

EAPI="1"

inherit kde4-base

DESCRIPTION="KDE internationalization package"
HOMEPAGE="http://www.kde.org/"
LICENSE="GPL-2"

KEYWORDS="~amd64 ~x86"
IUSE=""

DEPEND=">=sys-devel/gettext-0.15"
RDEPEND=""

LANGS="ar be bg ca cs csb da de el en_GB eo es et eu fa fi fr fy ga gl hi hu
is it ja kk km ko lv mk nb nds ne nl nn pa pl pt pt_BR ru se sl sv th tr uk wa
zh_CN zh_TW"

URI_BASE="${SRC_URI/-${PV}.tar.bz2/}"
SRC_URI=""

for X in ${LANGS} ; do
	IUSE="${IUSE} linguas_${X}"
	SRC_URI="${SRC_URI} linguas_${X}? ( ${URI_BASE}/${PN}-${X}-${PV}.tar.bz2 )"
done

S="${WORKDIR}"

src_unpack() {
	if [[ -z ${A} ]]; then
		echo
		ewarn "You either have the LINGUAS variable unset, or it only"
		ewarn "contains languages not supported by ${P}."
		ewarn "You won't have any additional language support."
		echo
		ewarn "${P} supports these language codes:"
		ewarn "${LANGS}"
		echo
	fi

	[[ -n ${A} ]] && unpack ${A}
	cd "${S}"

	# Create a top-level CMakeLists.txt to include the selected LINGUAS as sub-directories of ${S}
	for dir in * ; do
		[[ -d ${dir} ]] && echo "add_subdirectory( ${dir} )" >> "${S}"/CMakeLists.txt
	done
}

src_compile() {
	if [[ -n ${A} ]]; then
		kde4-base_src_compile
	fi
}

src_install() {
	if [[ -n ${A} ]]; then
		kde4-base_src_install
	fi
}



-- 
gentoo-commits@lists.gentoo.org mailing list