[gentoo-commits] gentoo-x86 commit in media-sound/beast: ChangeLog beast-0.7.1-r1.ebuild

["Gilles Dartiguelongue (eva)" <eva@gentoo.org>]

eva         08/06/01 21:21:48

  Modified:             ChangeLog
  Added:                beast-0.7.1-r1.ebuild
  Log:
  Fix compilation with newer glib, bug #223291.
  (Portage version: 2.1.5.2)

Revision  Changes    Path
1.31                 media-sound/beast/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/beast/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/beast/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/beast/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/beast/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	19 Jun 2007 18:14:17 -0000	1.30
+++ ChangeLog	1 Jun 2008 21:21:47 -0000	1.31
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/beast
-# Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/beast/ChangeLog,v 1.30 2007/06/19 18:14:17 aballier Exp $
+# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/beast/ChangeLog,v 1.31 2008/06/01 21:21:47 eva Exp $
+
+*beast-0.7.1-r1 (01 Jun 2008)
+
+  01 Jun 2008; Gilles Dartiguelongue <eva@gentoo.org>
+  +files/beast-0.7.1-configure.patch, +files/beast-0.7.1-glib.patch,
+  files/beast-0.7.1-noinstalltest.patch, +beast-0.7.1-r1.ebuild:
+  Fix compilation with newer glib, bug #223291.
 
   19 Jun 2007; Alexis Ballier <aballier@gentoo.org> -beast-0.6.4.ebuild,
   -beast-0.6.5.ebuild, -beast-0.6.6.ebuild:



1.1                  media-sound/beast/beast-0.7.1-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/beast/beast-0.7.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-sound/beast/beast-0.7.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: beast-0.7.1-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/beast/beast-0.7.1-r1.ebuild,v 1.1 2008/06/01 21:21:47 eva Exp $

inherit autotools eutils flag-o-matic fdo-mime

IUSE="debug mad static"

DESCRIPTION="BEAST - the Bedevilled Sound Engine"
HOMEPAGE="http://beast.gtk.org"
SRC_URI="ftp://beast.gtk.org/pub/beast/v${PV%.[0-9]}/${P}.tar.bz2
	mirror://gentoo/${P}-guile-1.8.diff.bz2"

LICENSE="GPL-2 LGPL-2.1"
KEYWORDS="~amd64 ~ppc ~x86"
SLOT="0"

RDEPEND=">=dev-libs/glib-2.0
	>=x11-libs/gtk+-2.4.11
	>=sys-libs/zlib-1.1.3
	dev-scheme/guile
	>=media-libs/libart_lgpl-2.3.8
	>=gnome-base/libgnomecanvas-2.0
	>=media-libs/libogg-1.0
	>=media-libs/libvorbis-1.0
	mad? ( media-sound/madplay )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	dev-lang/perl
	media-libs/ladspa-cmt
	media-libs/ladspa-sdk
	>=dev-util/intltool-0.35"

pkg_setup() {
	if has_version =dev-scheme/guile-1.8*; then
		local flags="deprecated"
		built_with_use dev-scheme/guile ${flags} \
		|| die "guile must be built with \"${flags}\" use flags"
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${WORKDIR}/${P}-guile-1.8.diff"
	epatch "${FILESDIR}/${P}-noinstalltest.patch"
	epatch "${FILESDIR}/${P}-signalheader.patch"

	# Remove G_DISABLE_DEPRECATED, bug #223291
	epatch "${FILESDIR}/${P}-glib.patch"

	epatch "${FILESDIR}/${P}-configure.patch"

	eautoreconf
	intltoolize --force || die "intltoolize failed"
}

src_compile() {
	# avoid suid related security issues.
	append-ldflags $(bindnow-flags)

	#for some weird reasons there is no doxer in this release
	econf $(use_enable debug) \
		$(use_enable static) \
		|| die "configure failed"
	emake || die "make failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "make install failed"
	# dont install new mime files !
	for i in subclasses XMLnamespaces aliases globs magic mime.cache\
		audio/x-bsewave.xml audio/x-bse.xml; do
		rm -f "${D}/usr/share/mime/${i}"
	done

	dodoc AUTHORS ChangeLog NEWS README TODO
}

pkg_postinst() {
	fdo-mime_mime_database_update
}



-- 
gentoo-commits@lists.gentoo.org mailing list