[gentoo-commits] gentoo-x86 commit in sys-libs/timezone-data: ChangeLog timezone-data-2008c.ebuild

["Mike Frysinger (vapier)" <vapier@gentoo.org>]

vapier      08/05/31 10:23:58

  Modified:             ChangeLog
  Added:                timezone-data-2008c.ebuild
  Log:
  Version bump #223827 by Rodrigo Severo.
  (Portage version: 2.2_pre5.spank.spunk)

Revision  Changes    Path
1.128                sys-libs/timezone-data/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/timezone-data/ChangeLog?rev=1.128&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/timezone-data/ChangeLog?rev=1.128&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/timezone-data/ChangeLog?r1=1.127&r2=1.128

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/timezone-data/ChangeLog,v
retrieving revision 1.127
retrieving revision 1.128
diff -u -r1.127 -r1.128
--- ChangeLog	29 May 2008 17:53:50 -0000	1.127
+++ ChangeLog	31 May 2008 10:23:57 -0000	1.128
@@ -1,6 +1,12 @@
 # ChangeLog for sys-libs/timezone-data
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/timezone-data/ChangeLog,v 1.127 2008/05/29 17:53:50 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/timezone-data/ChangeLog,v 1.128 2008/05/31 10:23:57 vapier Exp $
+
+*timezone-data-2008c (31 May 2008)
+
+  31 May 2008; Mike Frysinger <vapier@gentoo.org>
+  +timezone-data-2008c.ebuild:
+  Version bump #223827 by Rodrigo Severo.
 
   29 May 2008; Raúl Porcel <armin76@gentoo.org> timezone-data-2008b.ebuild:
   alpha/ia64/sparc/x86 stable



1.1                  sys-libs/timezone-data/timezone-data-2008c.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/timezone-data/timezone-data-2008c.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/timezone-data/timezone-data-2008c.ebuild?rev=1.1&content-type=text/plain

Index: timezone-data-2008c.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/timezone-data/timezone-data-2008c.ebuild,v 1.1 2008/05/31 10:23:57 vapier Exp $

inherit eutils toolchain-funcs flag-o-matic

code_ver=${PV/c/a}
data_ver=${PV}
DESCRIPTION="Timezone data (/usr/share/zoneinfo) and utilities (tzselect/zic/zdump)"
HOMEPAGE="ftp://elsie.nci.nih.gov/pub/"
SRC_URI="ftp://elsie.nci.nih.gov/pub/tzdata${data_ver}.tar.gz
	ftp://elsie.nci.nih.gov/pub/tzcode${code_ver}.tar.gz
	mirror://gentoo/tzdata${data_ver}.tar.gz
	mirror://gentoo/tzcode${code_ver}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="nls elibc_FreeBSD elibc_glibc"

DEPEND=""

S=${WORKDIR}

src_unpack() {
	unpack ${A}
	epatch "${FILESDIR}"/${PN}-2005n-makefile.patch
	tc-is-cross-compiler && cp -pR "${S}" "${S}"-native
}

src_compile() {
	tc-export CC
	use elibc_FreeBSD && append-flags -DSTD_INSPIRED #138251
	if use nls ; then
		use elibc_glibc || append-ldflags -lintl #154181
		export NLS=1
	else
		export NLS=0
	fi
	emake || die "emake failed"
	if tc-is-cross-compiler ; then
		make -C "${S}"-native CC=$(tc-getBUILD_CC) CFLAGS="${BUILD_CFLAGS}" zic || die
	fi
}

src_install() {
	local zic=""
	tc-is-cross-compiler && zic="zic=${S}-native/zic"
	make install ${zic} DESTDIR="${D}" || die
	rm -rf "${D}"/usr/share/zoneinfo-leaps
	dodoc README Theory
	dohtml *.htm *.jpg
}

pkg_config() {
	# make sure the /etc/localtime file does not get stale #127899
	local tz src

	if [[ -e ${ROOT}/etc/timezone ]] ; then
		src="/etc/timezone"
		tz=$(<"${ROOT}"/etc/timezone)
	else
		src="/etc/conf.d/clock"
		tz=$(unset TIMEZONE ; source "${ROOT}"/etc/conf.d/clock ; echo ${TIMEZONE-FOOKABLOIE})
		[[ -z ${tz} ]] && return 0
		if [[ ${tz} == "FOOKABLOIE" ]] ; then
			elog "You do not have TIMEZONE set in /etc/conf.d/clock."
			if [[ ! -e ${ROOT}/etc/localtime ]] ; then
				cp -f "${ROOT}"/usr/share/zoneinfo/Factory "${ROOT}"/etc/localtime
				elog "Setting /etc/localtime to Factory."
			else
				elog "Skipping auto-update of /etc/localtime."
			fi
			return 0
		fi
	fi

	if [[ ! -e ${ROOT}/usr/share/zoneinfo/${tz} ]] ; then
		elog "You have an invalid TIMEZONE setting in ${src}"
		elog "Your /etc/localtime has been reset to Factory; enjoy!"
		tz="Factory"
	fi
	einfo "Updating /etc/localtime with /usr/share/zoneinfo/${tz}"
	[[ -L ${ROOT}/etc/localtime ]] && rm -f "${ROOT}"/etc/localtime
	cp -f "${ROOT}"/usr/share/zoneinfo/"${tz}" "${ROOT}"/etc/localtime
}

pkg_postinst() {
	pkg_config
}



-- 
gentoo-commits@lists.gentoo.org mailing list